Koha/Item.pm

   1 package Koha::Item;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23 use List::MoreUtils qw(any);
  24
  25 use Koha::Database;
  26 use Koha::DateUtils qw( dt_from_string );
  27
  28 use C4::Context;
  29
  30 use Koha::Checkouts;
  31 use Koha::IssuingRules;
  32 use Koha::Item::Transfer::Limits;
  33 use Koha::Item::Transfers;
  34 use Koha::Patrons;
  35 use Koha::Libraries;
  36 use Koha::StockRotationItem;
  37 use Koha::StockRotationRotas;
  38
  39 use base qw(Koha::Object);
  40
  41 =head1 NAME
  42
  43 Koha::Item - Koha Item object class
  44
  45 =head1 API
  46
  47 =head2 Class methods
  48
  49 =cut
  50
  51 =head3 effective_itemtype
  52
  53 Returns the itemtype for the item based on whether item level itemtypes are set or not.
  54
  55 =cut
  56
  57 sub effective_itemtype {
  58     my ( $self ) = @_;
  59
  60     return $self->_result()->effective_itemtype();
  61 }
  62
  63 =head3 home_branch
  64
  65 =cut
  66
  67 sub home_branch {
  68     my ($self) = @_;
  69
  70     $self->{_home_branch} ||= Koha::Libraries->find( $self->homebranch() );
  71
  72     return $self->{_home_branch};
  73 }
  74
  75 =head3 holding_branch
  76
  77 =cut
  78
  79 sub holding_branch {
  80     my ($self) = @_;
  81
  82     $self->{_holding_branch} ||= Koha::Libraries->find( $self->holdingbranch() );
  83
  84     return $self->{_holding_branch};
  85 }
  86
  87 =head3 biblio
  88
  89 my $biblio = $item->biblio;
  90
  91 Return the bibliographic record of this item
  92
  93 =cut
  94
  95 sub biblio {
  96     my ( $self ) = @_;
  97     my $biblio_rs = $self->_result->biblio;
  98     return Koha::Biblio->_new_from_dbic( $biblio_rs );
  99 }
 100
 101 =head3 biblioitem
 102
 103 my $biblioitem = $item->biblioitem;
 104
 105 Return the biblioitem record of this item
 106
 107 =cut
 108
 109 sub biblioitem {
 110     my ( $self ) = @_;
 111     my $biblioitem_rs = $self->_result->biblioitem;
 112     return Koha::Biblioitem->_new_from_dbic( $biblioitem_rs );
 113 }
 114
 115 =head3 checkout
 116
 117 my $checkout = $item->checkout;
 118
 119 Return the checkout for this item
 120
 121 =cut
 122
 123 sub checkout {
 124     my ( $self ) = @_;
 125     my $checkout_rs = $self->_result->issue;
 126     return unless $checkout_rs;
 127     return Koha::Checkout->_new_from_dbic( $checkout_rs );
 128 }
 129
 130 =head3 holds
 131
 132 my $holds = $item->holds();
 133 my $holds = $item->holds($params);
 134 my $holds = $item->holds({ found => 'W'});
 135
 136 Return holds attached to an item, optionally accept a hashref of params to pass to search
 137
 138 =cut
 139
 140 sub holds {
 141     my ( $self,$params ) = @_;
 142     my $transfer_rs = $self->_result->reserves->search($params);
 143     return unless $transfer_rs->count;
 144     return Koha::Holds->_new_from_dbic( $transfer_rs );
 145 }
 146
 147 =head3 get_transfer
 148
 149 my $transfer = $item->get_transfer;
 150
 151 Return the transfer if the item is in transit or undef
 152
 153 =cut
 154
 155 sub get_transfer {
 156     my ( $self ) = @_;
 157     my $transfer_rs = $self->_result->branchtransfers->search({ datearrived => undef })->first;
 158     return unless $transfer_rs;
 159     return Koha::Item::Transfer->_new_from_dbic( $transfer_rs );
 160 }
 161
 162 =head3 last_returned_by
 163
 164 Gets and sets the last borrower to return an item.
 165
 166 Accepts and returns Koha::Patron objects
 167
 168 $item->last_returned_by( $borrowernumber );
 169
 170 $last_returned_by = $item->last_returned_by();
 171
 172 =cut
 173
 174 sub last_returned_by {
 175     my ( $self, $borrower ) = @_;
 176
 177     my $items_last_returned_by_rs = Koha::Database->new()->schema()->resultset('ItemsLastBorrower');
 178
 179     if ($borrower) {
 180         return $items_last_returned_by_rs->update_or_create(
 181             { borrowernumber => $borrower->borrowernumber, itemnumber => $self->id } );
 182     }
 183     else {
 184         unless ( $self->{_last_returned_by} ) {
 185             my $result = $items_last_returned_by_rs->single( { itemnumber => $self->id } );
 186             if ($result) {
 187                 $self->{_last_returned_by} = Koha::Patrons->find( $result->get_column('borrowernumber') );
 188             }
 189         }
 190
 191         return $self->{_last_returned_by};
 192     }
 193 }
 194
 195 =head3 can_article_request
 196
 197 my $bool = $item->can_article_request( $borrower )
 198
 199 Returns true if item can be specifically requested
 200
 201 $borrower must be a Koha::Patron object
 202
 203 =cut
 204
 205 sub can_article_request {
 206     my ( $self, $borrower ) = @_;
 207
 208     my $rule = $self->article_request_type($borrower);
 209
 210     return 1 if $rule && $rule ne 'no' && $rule ne 'bib_only';
 211     return q{};
 212 }
 213
 214 =head3 hidden_in_opac
 215
 216 my $bool = $item->hidden_in_opac({ [ rules => $rules ] })
 217
 218 Returns true if item fields match the hidding criteria defined in $rules.
 219 Returns false otherwise.
 220
 221 Takes HASHref that can have the following parameters:
 222     OPTIONAL PARAMETERS:
 223     $rules : { <field> => [ value_1, ... ], ... }
 224
 225 Note: $rules inherits its structure from the parsed YAML from reading
 226 the I<OpacHiddenItems> system preference.
 227
 228 =cut
 229
 230 sub hidden_in_opac {
 231     my ( $self, $params ) = @_;
 232
 233     my $rules = $params->{rules} // {};
 234
 235     return 1
 236         if C4::Context->preference('hidelostitems') and
 237            $self->itemlost > 0;
 238
 239     my $hidden_in_opac = 0;
 240
 241     foreach my $field ( keys %{$rules} ) {
 242
 243         if ( any { $self->$field eq $_ } @{ $rules->{$field} } ) {
 244             $hidden_in_opac = 1;
 245             last;
 246         }
 247     }
 248
 249     return $hidden_in_opac;
 250 }
 251
 252 =head3 can_be_transferred
 253
 254 $item->can_be_transferred({ to => $to_library, from => $from_library })
 255 Checks if an item can be transferred to given library.
 256
 257 This feature is controlled by two system preferences:
 258 UseBranchTransferLimits to enable / disable the feature
 259 BranchTransferLimitsType to use either an itemnumber or ccode as an identifier
 260                          for setting the limitations
 261
 262 Takes HASHref that can have the following parameters:
 263     MANDATORY PARAMETERS:
 264     $to   : Koha::Library
 265     OPTIONAL PARAMETERS:
 266     $from : Koha::Library  # if not given, item holdingbranch
 267                            # will be used instead
 268
 269 Returns 1 if item can be transferred to $to_library, otherwise 0.
 270
 271 To find out whether at least one item of a Koha::Biblio can be transferred, please
 272 see Koha::Biblio->can_be_transferred() instead of using this method for
 273 multiple items of the same biblio.
 274
 275 =cut
 276
 277 sub can_be_transferred {
 278     my ($self, $params) = @_;
 279
 280     my $to   = $params->{to};
 281     my $from = $params->{from};
 282
 283     $to   = $to->branchcode;
 284     $from = defined $from ? $from->branchcode : $self->holdingbranch;
 285
 286     return 1 if $from eq $to; # Transfer to current branch is allowed
 287     return 1 unless C4::Context->preference('UseBranchTransferLimits');
 288
 289     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 290     return Koha::Item::Transfer::Limits->search({
 291         toBranch => $to,
 292         fromBranch => $from,
 293         $limittype => $limittype eq 'itemtype'
 294                         ? $self->effective_itemtype : $self->ccode
 295     })->count ? 0 : 1;
 296 }
 297
 298 =head3 article_request_type
 299
 300 my $type = $item->article_request_type( $borrower )
 301
 302 returns 'yes', 'no', 'bib_only', or 'item_only'
 303
 304 $borrower must be a Koha::Patron object
 305
 306 =cut
 307
 308 sub article_request_type {
 309     my ( $self, $borrower ) = @_;
 310
 311     my $branch_control = C4::Context->preference('HomeOrHoldingBranch');
 312     my $branchcode =
 313         $branch_control eq 'homebranch'    ? $self->homebranch
 314       : $branch_control eq 'holdingbranch' ? $self->holdingbranch
 315       :                                      undef;
 316     my $borrowertype = $borrower->categorycode;
 317     my $itemtype = $self->effective_itemtype();
 318     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule({ categorycode => $borrowertype, itemtype => $itemtype, branchcode => $branchcode });
 319
 320     return q{} unless $issuing_rule;
 321     return $issuing_rule->article_requests || q{}
 322 }
 323
 324 =head3 current_holds
 325
 326 =cut
 327
 328 sub current_holds {
 329     my ( $self ) = @_;
 330     my $attributes = { order_by => 'priority' };
 331     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 332     my $params = {
 333         itemnumber => $self->itemnumber,
 334         suspend => 0,
 335         -or => [
 336             reservedate => { '<=' => $dtf->format_date(dt_from_string) },
 337             waitingdate => { '!=' => undef },
 338         ],
 339     };
 340     my $hold_rs = $self->_result->reserves->search( $params, $attributes );
 341     return Koha::Holds->_new_from_dbic($hold_rs);
 342 }
 343
 344 =head3 stockrotationitem
 345
 346   my $sritem = Koha::Item->stockrotationitem;
 347
 348 Returns the stock rotation item associated with the current item.
 349
 350 =cut
 351
 352 sub stockrotationitem {
 353     my ( $self ) = @_;
 354     my $rs = $self->_result->stockrotationitem;
 355     return 0 if !$rs;
 356     return Koha::StockRotationItem->_new_from_dbic( $rs );
 357 }
 358
 359 =head3 add_to_rota
 360
 361   my $item = $item->add_to_rota($rota_id);
 362
 363 Add this item to the rota identified by $ROTA_ID, which means associating it
 364 with the first stage of that rota.  Should this item already be associated
 365 with a rota, then we will move it to the new rota.
 366
 367 =cut
 368
 369 sub add_to_rota {
 370     my ( $self, $rota_id ) = @_;
 371     Koha::StockRotationRotas->find($rota_id)->add_item($self->itemnumber);
 372     return $self;
 373 }
 374
 375 =head3 has_pending_hold
 376
 377   my $is_pending_hold = $item->has_pending_hold();
 378
 379 This method checks the tmp_holdsqueue to see if this item has been selected for a hold, but not filled yet and returns true or false
 380
 381 =cut
 382
 383 sub has_pending_hold {
 384     my ( $self ) = @_;
 385     my $pending_hold = $self->_result->tmp_holdsqueues;
 386     return !C4::Context->preference('AllowItemsOnHoldCheckout') && $pending_hold->count ? 1: 0;
 387 }
 388
 389 =head3 as_marc_field
 390
 391     my $mss   = C4::Biblio::GetMarcSubfieldStructure( '', { unsafe => 1 } );
 392     my $field = $item->as_marc_field({ [ mss => $mss ] });
 393
 394 This method returns a MARC::Field object representing the Koha::Item object
 395 with the current mappings configuration.
 396
 397 =cut
 398
 399 sub as_marc_field {
 400     my ( $self, $params ) = @_;
 401
 402     my $mss = $params->{mss} // C4::Biblio::GetMarcSubfieldStructure( '', { unsafe => 1 } );
 403     my $item_tag = $mss->{'items.itemnumber'}[0]->{tagfield};
 404
 405     my @subfields;
 406
 407     my @columns = $self->_result->result_source->columns;
 408
 409     foreach my $item_field ( @columns ) {
 410         my $mapping = $mss->{ "items.$item_field"}[0];
 411         my $tagfield    = $mapping->{tagfield};
 412         my $tagsubfield = $mapping->{tagsubfield};
 413         next if !$tagfield; # TODO: Should we raise an exception instead?
 414                             # Feels like safe fallback is better
 415
 416         push @subfields, $tagsubfield => $self->$item_field;
 417     }
 418
 419     my $unlinked_item_subfields = C4::Items::_parse_unlinked_item_subfields_from_xml($self->more_subfields_xml);
 420     push( @subfields, @{$unlinked_item_subfields} )
 421         if defined $unlinked_item_subfields and $#$unlinked_item_subfields > -1;
 422
 423     my $field;
 424
 425     $field = MARC::Field->new(
 426         "$item_tag", ' ', ' ', @subfields
 427     ) if @subfields;
 428
 429     return $field;
 430 }
 431
 432 =head2 Internal methods
 433
 434 =head3 _type
 435
 436 =cut
 437
 438 sub _type {
 439     return 'Item';
 440 }
 441
 442 =head1 AUTHOR
 443
 444 Kyle M Hall <kyle@bywatersolutions.com>
 445
 446 =cut
 447
 448 1;