Koha/Patrons.pm

   1 package Koha::Patrons;
   2
   3 # Copyright 2014 ByWater Solutions
   4 # Copyright 2016 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24
  25 use Koha::Database;
  26 use Koha::DateUtils;
  27
  28 use Koha::ArticleRequests;
  29 use Koha::ArticleRequest::Status;
  30 use Koha::Patron;
  31
  32 use base qw(Koha::Objects);
  33
  34 =head1 NAME
  35
  36 Koha::Patron - Koha Patron Object class
  37
  38 =head1 API
  39
  40 =head2 Class Methods
  41
  42 =cut
  43
  44 =head3 search_housebound_choosers
  45
  46 Returns all Patrons which are Housebound choosers.
  47
  48 =cut
  49
  50 sub search_housebound_choosers {
  51     my ( $self ) = @_;
  52     my $cho = $self->_resultset
  53         ->search_related('housebound_role', {
  54             housebound_chooser => 1,
  55         })->search_related('borrowernumber');
  56     return Koha::Patrons->_new_from_dbic($cho);
  57 }
  58
  59 =head3 search_housebound_deliverers
  60
  61 Returns all Patrons which are Housebound deliverers.
  62
  63 =cut
  64
  65 sub search_housebound_deliverers {
  66     my ( $self ) = @_;
  67     my $del = $self->_resultset
  68         ->search_related('housebound_role', {
  69             housebound_deliverer => 1,
  70         })->search_related('borrowernumber');
  71     return Koha::Patrons->_new_from_dbic($del);
  72 }
  73
  74 =head3 search_upcoming_membership_expires
  75
  76 my $patrons = Koha::Patrons->search_upcoming_membership_expires();
  77
  78 The 'before' and 'after' represent the number of days before/after the date
  79 that is set by the preference MembershipExpiryDaysNotice.
  80 If the pref is 14, before 2 and after 3 then you will get all expires
  81 from 12 to 17 days.
  82
  83 =cut
  84
  85 sub search_upcoming_membership_expires {
  86     my ( $self, $params ) = @_;
  87     my $before = $params->{before} || 0;
  88     my $after  = $params->{after} || 0;
  89     delete $params->{before};
  90     delete $params->{after};
  91
  92     my $days = C4::Context->preference("MembershipExpiryDaysNotice") || 0;
  93     my $date_before = dt_from_string->add( days => $days - $before );
  94     my $date_after = dt_from_string->add( days => $days + $after );
  95     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
  96
  97     $params->{dateexpiry} = {
  98         ">=" => $dtf->format_date( $date_before ),
  99         "<=" => $dtf->format_date( $date_after ),
 100     };
 101     return $self->SUPER::search(
 102         $params, { join => ['branchcode', 'categorycode'] }
 103     );
 104 }
 105
 106 =head3 guarantor
 107
 108 Returns a Koha::Patron object for this borrower's guarantor
 109
 110 =cut
 111
 112 sub guarantor {
 113     my ( $self ) = @_;
 114
 115     return Koha::Patrons->find( $self->guarantorid() );
 116 }
 117
 118 =head3 search_patrons_to_anonymise
 119
 120     my $patrons = Koha::Patrons->search_patrons_to_anonymise( { before => $older_than_date, [ library => $library ] } );
 121
 122 This method returns all patrons who has an issue history older than a given date.
 123
 124 =cut
 125
 126 sub search_patrons_to_anonymise {
 127     my ( $class, $params ) = @_;
 128     my $older_than_date = $params->{before};
 129     my $library         = $params->{library};
 130     $older_than_date = $older_than_date ? dt_from_string($older_than_date) : dt_from_string;
 131     $library ||=
 132       ( C4::Context->preference('IndependentBranches') && C4::Context->userenv && !C4::Context->IsSuperLibrarian() && C4::Context->userenv->{branch} )
 133       ? C4::Context->userenv->{branch}
 134       : undef;
 135
 136     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 137     my $rs = $class->_resultset->search(
 138         {   returndate                  => { '<'   =>  $dtf->format_datetime($older_than_date), },
 139             'old_issues.borrowernumber' => { 'not' => undef },
 140             privacy                     => { '<>'  => 0 },                  # Keep forever
 141             ( $library ? ( 'old_issues.branchcode' => $library ) : () ),
 142         },
 143         {   join     => ["old_issues"],
 144             group_by => 'borrowernumber'
 145         }
 146     );
 147     return Koha::Patrons->_new_from_dbic($rs);
 148 }
 149
 150 =head3 anonymise_issue_history
 151
 152     Koha::Patrons->search->anonymise_issue_history( { [ before => $older_than_date ] } );
 153
 154 Anonymise issue history (old_issues) for all patrons older than the given date (optional).
 155 To make sure all the conditions are met, the caller has the responsibility to
 156 call search_patrons_to_anonymise to filter the Koha::Patrons set
 157
 158 =cut
 159
 160 sub anonymise_issue_history {
 161     my ( $self, $params ) = @_;
 162
 163     my $older_than_date = $params->{before};
 164
 165     $older_than_date = dt_from_string $older_than_date if $older_than_date;
 166
 167     # The default of 0 does not work due to foreign key constraints
 168     # The anonymisation should not fail quietly if AnonymousPatron is not a valid entry
 169     # Set it to undef (NULL)
 170     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 171     my $nb_rows = 0;
 172     while ( my $patron = $self->next ) {
 173         my $old_issues_to_anonymise = $patron->old_checkouts->search(
 174         {
 175             (
 176                 $older_than_date
 177                 ? ( returndate =>
 178                       { '<' => $dtf->format_datetime($older_than_date) } )
 179                 : ()
 180             )
 181         }
 182         );
 183         my $anonymous_patron = C4::Context->preference('AnonymousPatron') || undef;
 184         $nb_rows += $old_issues_to_anonymise->update( { 'old_issues.borrowernumber' => $anonymous_patron } );
 185     }
 186     return $nb_rows;
 187 }
 188
 189 =head3 type
 190
 191 =cut
 192
 193 sub _type {
 194     return 'Borrower';
 195 }
 196
 197 sub object_class {
 198     return 'Koha::Patron';
 199 }
 200
 201 =head1 AUTHOR
 202
 203 Kyle M Hall <kyle@bywatersolutions.com>
 204
 205 =cut
 206
 207 1;