Koha/Patrons/Import.pm

   1 package Koha::Patrons::Import;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 3 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19 use Moo;
  20 use namespace::clean;
  21
  22 use Carp;
  23 use Text::CSV;
  24
  25 use C4::Members;
  26 use C4::Members::Attributes qw(:all);
  27 use C4::Members::AttributeTypes;
  28
  29 use Koha::Libraries;
  30 use Koha::Patrons;
  31 use Koha::Patron::Categories;
  32 use Koha::Patron::Debarments;
  33 use Koha::DateUtils;
  34
  35 =head1 NAME
  36
  37 Koha::Patrons::Import - Perl Module containing import_patrons method exported from import_borrowers script.
  38
  39 =head1 SYNOPSIS
  40
  41 use Koha::Patrons::Import;
  42
  43 =head1 DESCRIPTION
  44
  45 This module contains one method for importing patrons in bulk.
  46
  47 =head1 FUNCTIONS
  48
  49 =head2 import_patrons
  50
  51  my $return = Koha::Patrons::Import::import_patrons($params);
  52
  53 Applies various checks and imports patrons in bulk from a csv file.
  54
  55 Further pod documentation needed here.
  56
  57 =cut
  58
  59 has 'today_iso' => ( is => 'ro', lazy => 1,
  60     default => sub { output_pref( { dt => dt_from_string(), dateonly => 1, dateformat => 'iso' } ); }, );
  61
  62 has 'text_csv' => ( is => 'rw', lazy => 1,
  63     default => sub { Text::CSV->new( { binary => 1, } ); },  );
  64
  65 sub import_patrons {
  66     my ($self, $params) = @_;
  67
  68     my $handle = $params->{file};
  69     unless( $handle ) { carp('No file handle passed in!'); return; }
  70
  71     my $matchpoint           = $params->{matchpoint};
  72     my $defaults             = $params->{defaults};
  73     my $ext_preserve         = $params->{preserve_extended_attributes};
  74     my $overwrite_cardnumber = $params->{overwrite_cardnumber};
  75     my $extended             = C4::Context->preference('ExtendedPatronAttributes');
  76     my $set_messaging_prefs  = C4::Context->preference('EnhancedMessagingPreferences');
  77
  78     my @columnkeys = $self->set_column_keys($extended);
  79     my @feedback;
  80     my @errors;
  81
  82     my $imported    = 0;
  83     my $alreadyindb = 0;
  84     my $overwritten = 0;
  85     my $invalid     = 0;
  86     my @imported_borrowers;
  87     my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
  88
  89     # Use header line to construct key to column map
  90     my %csvkeycol;
  91     my $borrowerline = <$handle>;
  92     my @csvcolumns   = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
  93     push(@feedback, { feedback => 1, name => 'headerrow', value => join( ', ', @csvcolumns ) });
  94
  95     my @criticals = qw( surname );    # there probably should be others - rm branchcode && categorycode
  96   LINE: while ( my $borrowerline = <$handle> ) {
  97         my $line_number = $.;
  98         my %borrower;
  99         my @missing_criticals;
 100
 101         my $status  = $self->text_csv->parse($borrowerline);
 102         my @columns = $self->text_csv->fields();
 103         if ( !$status ) {
 104             push @missing_criticals, { badparse => 1, line => $line_number, lineraw => $borrowerline };
 105         }
 106         elsif ( @columns == @columnkeys ) {
 107             @borrower{@columnkeys} = @columns;
 108
 109             # MJR: try to fill blanks gracefully by using default values
 110             foreach my $key (@columnkeys) {
 111                 if ( $borrower{$key} !~ /\S/ ) {
 112                     $borrower{$key} = $defaults->{$key};
 113                 }
 114             }
 115         }
 116         else {
 117             # MJR: try to recover gracefully by using default values
 118             foreach my $key (@columnkeys) {
 119                 if ( defined( $csvkeycol{$key} ) and $columns[ $csvkeycol{$key} ] =~ /\S/ ) {
 120                     $borrower{$key} = $columns[ $csvkeycol{$key} ];
 121                 }
 122                 elsif ( $defaults->{$key} ) {
 123                     $borrower{$key} = $defaults->{$key};
 124                 }
 125                 elsif ( scalar grep { $key eq $_ } @criticals ) {
 126
 127                     # a critical field is undefined
 128                     push @missing_criticals, { key => $key, line => $., lineraw => $borrowerline };
 129                 }
 130                 else {
 131                     $borrower{$key} = '';
 132                 }
 133             }
 134         }
 135
 136         $borrower{cardnumber} = undef if $borrower{cardnumber} eq "";
 137
 138         # Check if borrower category code exists and if it matches to a known category. Pushing error to missing_criticals otherwise.
 139         $self->check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 140
 141         # Check if branch code exists and if it matches to a branch name. Pushing error to missing_criticals otherwise.
 142         $self->check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 143
 144         # Popular spreadsheet applications make it difficult to force date outputs to be zero-padded, but we require it.
 145         $self->format_dates({borrower => \%borrower, lineraw => $borrowerline, line => $line_number, missing_criticals => \@missing_criticals, });
 146
 147         if (@missing_criticals) {
 148             foreach (@missing_criticals) {
 149                 $_->{borrowernumber} = $borrower{borrowernumber} || 'UNDEF';
 150                 $_->{surname}        = $borrower{surname}        || 'UNDEF';
 151             }
 152             $invalid++;
 153             ( 25 > scalar @errors ) and push @errors, { missing_criticals => \@missing_criticals };
 154
 155             # The first 25 errors are enough.  Keeping track of 30,000+ would destroy performance.
 156             next LINE;
 157         }
 158
 159         # Set patron attributes if extended.
 160         my $patron_attributes = $self->set_patron_attributes($extended, $borrower{patron_attributes}, \@feedback);
 161         if( $extended ) { delete $borrower{patron_attributes}; } # Not really a field in borrowers.
 162
 163         # Default date enrolled and date expiry if not already set.
 164         $borrower{dateenrolled} = $self->today_iso() unless $borrower{dateenrolled};
 165         $borrower{dateexpiry} = Koha::Patron::Categories->find( $borrower{categorycode} )->get_expiry_date( $borrower{dateenrolled} ) unless $borrower{dateexpiry};
 166
 167         my $borrowernumber;
 168         my ( $member, $patron );
 169         if ( defined($matchpoint) && ( $matchpoint eq 'cardnumber' ) && ( $borrower{'cardnumber'} ) ) {
 170             $patron = Koha::Patrons->find( { cardnumber => $borrower{'cardnumber'} } );
 171         }
 172         elsif ( defined($matchpoint) && ($matchpoint eq 'userid') && ($borrower{'userid'}) ) {
 173             $patron = Koha::Patrons->find( { userid => $borrower{userid} } );
 174         }
 175         elsif ($extended) {
 176             if ( defined($matchpoint_attr_type) ) {
 177                 foreach my $attr (@$patron_attributes) {
 178                     if ( $attr->{code} eq $matchpoint and $attr->{value} ne '' ) {
 179                         my @borrowernumbers = $matchpoint_attr_type->get_patrons( $attr->{value} );
 180                         $borrowernumber = $borrowernumbers[0] if scalar(@borrowernumbers) == 1;
 181                         $patron = Koha::Patrons->find( $borrowernumber );
 182                         last;
 183                     }
 184                 }
 185             }
 186         }
 187
 188         if ($patron) {
 189             $member = $patron->unblessed;
 190             $borrowernumber = $member->{'borrowernumber'};
 191         } else {
 192             $member = {};
 193         }
 194
 195         if ( C4::Members::checkcardnumber( $borrower{cardnumber}, $borrowernumber ) ) {
 196             push @errors,
 197               {
 198                 invalid_cardnumber => 1,
 199                 borrowernumber     => $borrowernumber,
 200                 cardnumber         => $borrower{cardnumber}
 201               };
 202             $invalid++;
 203             next;
 204         }
 205
 206
 207         # Check if the userid provided does not exist yet
 208         if (    defined($matchpoint)
 209             and $matchpoint ne 'userid'
 210             and exists $borrower{userid}
 211             and $borrower{userid}
 212             and not ( $borrowernumber ? $patron->userid( $borrower{userid} )->has_valid_userid : Koha::Patron->new( { userid => $borrower{userid} } )->has_valid_userid )
 213         ) {
 214             push @errors, { duplicate_userid => 1, userid => $borrower{userid} };
 215             $invalid++;
 216             next LINE;
 217         }
 218
 219         if ($borrowernumber) {
 220
 221             # borrower exists
 222             unless ($overwrite_cardnumber) {
 223                 $alreadyindb++;
 224                 push(
 225                     @feedback,
 226                     {
 227                         already_in_db => 1,
 228                         value         => $borrower{'surname'} . ' / ' . $borrowernumber
 229                     }
 230                 );
 231                 next LINE;
 232             }
 233             $borrower{'borrowernumber'} = $borrowernumber;
 234             for my $col ( keys %borrower ) {
 235
 236                 # use values from extant patron unless our csv file includes this column or we provided a default.
 237                 # FIXME : You cannot update a field with a  perl-evaluated false value using the defaults.
 238
 239                 # The password is always encrypted, skip it!
 240                 next if $col eq 'password';
 241
 242                 unless ( exists( $csvkeycol{$col} ) || $defaults->{$col} ) {
 243                     $borrower{$col} = $member->{$col} if ( $member->{$col} );
 244                 }
 245             }
 246
 247             my $patron = Koha::Patrons->find( $borrowernumber );
 248             eval { $patron->set(\%borrower)->store };
 249             if ( $@ ) {
 250                 $invalid++;
 251
 252                 push(
 253                     @errors,
 254                     {
 255                         # TODO We can raise a better error
 256                         name  => 'lastinvalid',
 257                         value => $borrower{'surname'} . ' / ' . $borrowernumber
 258                     }
 259                 );
 260                 next LINE;
 261             }
 262             # Don't add a new restriction if the existing 'combined' restriction matches this one
 263             if ( $borrower{debarred} && ( ( $borrower{debarred} ne $member->{debarred} ) || ( $borrower{debarredcomment} ne $member->{debarredcomment} ) ) ) {
 264
 265                 # Check to see if this debarment already exists
 266                 my $debarrments = GetDebarments(
 267                     {
 268                         borrowernumber => $borrowernumber,
 269                         expiration     => $borrower{debarred},
 270                         comment        => $borrower{debarredcomment}
 271                     }
 272                 );
 273
 274                 # If it doesn't, then add it!
 275                 unless (@$debarrments) {
 276                     AddDebarment(
 277                         {
 278                             borrowernumber => $borrowernumber,
 279                             expiration     => $borrower{debarred},
 280                             comment        => $borrower{debarredcomment}
 281                         }
 282                     );
 283                 }
 284             }
 285             if ($extended) {
 286                 if ($ext_preserve) {
 287                     my $old_attributes = GetBorrowerAttributes($borrowernumber);
 288                     $patron_attributes = extended_attributes_merge( $old_attributes, $patron_attributes );
 289                 }
 290                 push @errors, { unknown_error => 1 }
 291                   unless SetBorrowerAttributes( $borrower{'borrowernumber'}, $patron_attributes, 'no_branch_limit' );
 292             }
 293             $overwritten++;
 294             push(
 295                 @feedback,
 296                 {
 297                     feedback => 1,
 298                     name     => 'lastoverwritten',
 299                     value    => $borrower{'surname'} . ' / ' . $borrowernumber
 300                 }
 301             );
 302         }
 303         else {
 304             my $patron = eval {
 305                 Koha::Patron->new(\%borrower)->store;
 306             };
 307             unless ( $@ ) {
 308
 309                 if ( $patron->is_debarred ) {
 310                     AddDebarment(
 311                         {
 312                             borrowernumber => $patron->borrowernumber,
 313                             expiration     => $patron->debarred,
 314                             comment        => $patron->debarredcomment,
 315                         }
 316                     );
 317                 }
 318
 319                 if ($extended) {
 320                     SetBorrowerAttributes( $patron->borrowernumber, $patron_attributes );
 321                 }
 322
 323                 if ($set_messaging_prefs) {
 324                     C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 325                         {
 326                             borrowernumber => $patron->borrowernumber,
 327                             categorycode   => $patron->categorycode,
 328                         }
 329                     );
 330                 }
 331
 332                 $imported++;
 333                 push @imported_borrowers, $patron->borrowernumber; #for patronlist
 334                 push(
 335                     @feedback,
 336                     {
 337                         feedback => 1,
 338                         name     => 'lastimported',
 339                         value    => $patron->surname . ' / ' . $patron->borrowernumber,
 340                     }
 341                 );
 342             }
 343             else {
 344                 $invalid++;
 345                 push @errors, { unknown_error => 1 };
 346                 push(
 347                     @errors,
 348                     {
 349                         name  => 'lastinvalid',
 350                         value => $borrower{'surname'} . ' / Create patron',
 351                     }
 352                 );
 353             }
 354         }
 355     }
 356
 357     return {
 358         feedback      => \@feedback,
 359         errors        => \@errors,
 360         imported      => $imported,
 361         overwritten   => $overwritten,
 362         already_in_db => $alreadyindb,
 363         invalid       => $invalid,
 364         imported_borrowers => \@imported_borrowers,
 365     };
 366 }
 367
 368 =head2 prepare_columns
 369
 370  my @csvcolumns = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
 371
 372 Returns an array of all column key and populates a hash of colunm key positions.
 373
 374 =cut
 375
 376 sub prepare_columns {
 377     my ($self, $params) = @_;
 378
 379     my $status = $self->text_csv->parse($params->{headerrow});
 380     unless( $status ) {
 381         push( @{$params->{errors}}, { badheader => 1, line => 1, lineraw => $params->{headerrow} });
 382         return;
 383     }
 384
 385     my @csvcolumns = $self->text_csv->fields();
 386     my $col = 0;
 387     foreach my $keycol (@csvcolumns) {
 388         # columnkeys don't contain whitespace, but some stupid tools add it
 389         $keycol =~ s/ +//g;
 390         $keycol =~ s/^\N{BOM}//; # Strip BOM if exists, otherwise it will be part of first column key
 391         $params->{keycol}->{$keycol} = $col++;
 392     }
 393
 394     return @csvcolumns;
 395 }
 396
 397 =head2 set_attribute_types
 398
 399  my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
 400
 401 Returns an attribute type based on matchpoint parameter.
 402
 403 =cut
 404
 405 sub set_attribute_types {
 406     my ($self, $params) = @_;
 407
 408     my $attribute_types;
 409     if( $params->{extended} ) {
 410         $attribute_types = C4::Members::AttributeTypes->fetch($params->{matchpoint});
 411     }
 412
 413     return $attribute_types;
 414 }
 415
 416 =head2 set_column_keys
 417
 418  my @columnkeys = set_column_keys($extended);
 419
 420 Returns an array of borrowers' table columns.
 421
 422 =cut
 423
 424 sub set_column_keys {
 425     my ($self, $extended) = @_;
 426
 427     my @columnkeys = map { $_ ne 'borrowernumber' ? $_ : () } Koha::Patrons->columns();
 428     push( @columnkeys, 'patron_attributes' ) if $extended;
 429
 430     return @columnkeys;
 431 }
 432
 433 =head2 set_patron_attributes
 434
 435  my $patron_attributes = set_patron_attributes($extended, $borrower{patron_attributes}, $feedback);
 436
 437 Returns a reference to array of hashrefs data structure as expected by SetBorrowerAttributes.
 438
 439 =cut
 440
 441 sub set_patron_attributes {
 442     my ($self, $extended, $patron_attributes, $feedback) = @_;
 443
 444     unless( $extended ) { return; }
 445     unless( defined($patron_attributes) ) { return; }
 446
 447     # Fixup double quotes in case we are passed smart quotes
 448     $patron_attributes =~ s/\xe2\x80\x9c/"/g;
 449     $patron_attributes =~ s/\xe2\x80\x9d/"/g;
 450
 451     push (@$feedback, { feedback => 1, name => 'attribute string', value => $patron_attributes });
 452
 453     my $result = extended_attributes_code_value_arrayref($patron_attributes);
 454
 455     return $result;
 456 }
 457
 458 =head2 check_branch_code
 459
 460  check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 461
 462 Pushes a 'missing_criticals' error entry if no branch code or branch code does not map to a branch name.
 463
 464 =cut
 465
 466 sub check_branch_code {
 467     my ($self, $branchcode, $borrowerline, $line_number, $missing_criticals) = @_;
 468
 469     # No branch code
 470     unless( $branchcode ) {
 471         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => $borrowerline, });
 472         return;
 473     }
 474
 475     # look for branch code
 476     my $library = Koha::Libraries->find( $branchcode );
 477     unless( $library ) {
 478         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => $borrowerline,
 479                                      value => $branchcode, branch_map => 1, });
 480     }
 481 }
 482
 483 =head2 check_borrower_category
 484
 485  check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 486
 487 Pushes a 'missing_criticals' error entry if no category code or category code does not map to a known category.
 488
 489 =cut
 490
 491 sub check_borrower_category {
 492     my ($self, $categorycode, $borrowerline, $line_number, $missing_criticals) = @_;
 493
 494     # No branch code
 495     unless( $categorycode ) {
 496         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => $borrowerline, });
 497         return;
 498     }
 499
 500     # Looking for borrower category
 501     my $category = Koha::Patron::Categories->find($categorycode);
 502     unless( $category ) {
 503         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => $borrowerline,
 504                                      value => $categorycode, category_map => 1, });
 505     }
 506 }
 507
 508 =head2 format_dates
 509
 510  format_dates({borrower => \%borrower, lineraw => $lineraw, line => $line_number, missing_criticals => \@missing_criticals, });
 511
 512 Pushes a 'missing_criticals' error entry for each of the 3 date types dateofbirth, dateenrolled and dateexpiry if it can not
 513 be formatted to the chosen date format. Populates the correctly formatted date otherwise.
 514
 515 =cut
 516
 517 sub format_dates {
 518     my ($self, $params) = @_;
 519
 520     foreach my $date_type (qw(dateofbirth dateenrolled dateexpiry date_renewed)) {
 521         my $tempdate = $params->{borrower}->{$date_type} or next();
 522         my $formatted_date = eval { output_pref( { dt => dt_from_string( $tempdate ), dateonly => 1, dateformat => 'iso' } ); };
 523
 524         if ($formatted_date) {
 525             $params->{borrower}->{$date_type} = $formatted_date;
 526         } else {
 527             $params->{borrower}->{$date_type} = '';
 528             push (@{$params->{missing_criticals}}, { key => $date_type, line => $params->{line}, lineraw => $params->{lineraw}, bad_date => 1 });
 529         }
 530     }
 531 }
 532
 533 1;
 534
 535 =head1 AUTHOR
 536
 537 Koha Team
 538
 539 =cut