acqui/booksellers.pl

   1 #!/usr/bin/perl
   2
   3 #script to show suppliers and orders
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # Copyright 2008-2009 BibLibre SARL
   7 # Copyright 2010 PTFS Europe
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with Koha; if not, write to the Free Software Foundation, Inc.,
  22 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  23
  24 =head1 NAME
  25
  26 booksellers.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script displays the list of suppliers & baskets like C<$supplier> given on input arg.
  31 thus, this page brings differents features like to display supplier's details,
  32 to add an order for a specific supplier or to just add a new supplier.
  33
  34 =head1 CGI PARAMETERS
  35
  36 =over 4
  37
  38 =item supplier
  39
  40 C<$supplier> is the string with which we search for a supplier
  41
  42 =back
  43
  44 =over 4
  45
  46 =item id or booksellerid
  47
  48 The id of the supplier whose baskets we will display
  49
  50 =back
  51
  52 =cut
  53
  54 use strict;
  55 use warnings;
  56 use C4::Auth;
  57 use C4::Biblio;
  58 use C4::Budgets;
  59 use C4::Output;
  60 use CGI qw ( -utf8 );
  61
  62 use C4::Acquisition qw/ GetBasketsInfosByBookseller CanUserManageBasket /;
  63 use C4::Members qw/GetMember/;
  64 use C4::Context;
  65
  66 use Koha::Acquisition::Bookseller;
  67
  68 my $query = CGI->new;
  69 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  70     {   template_name   => 'acqui/booksellers.tt',
  71         query           => $query,
  72         type            => 'intranet',
  73         authnotrequired => 0,
  74         flagsrequired   => { acquisition => '*' },
  75         debug           => 1,
  76     }
  77 );
  78
  79 #parameters
  80 my $supplier = $query->param('supplier');
  81 my $booksellerid = $query->param('booksellerid');
  82 my $allbaskets= $query->param('allbaskets')||0;
  83 my @suppliers;
  84
  85 if ($booksellerid) {
  86     push @suppliers, Koha::Acquisition::Bookseller->fetch({ id => $booksellerid });
  87 } else {
  88     @suppliers = Koha::Acquisition::Bookseller->search({ name => $supplier });
  89 }
  90
  91 my $supplier_count = @suppliers;
  92 if ( $supplier_count == 1 ) {
  93     $template->param(
  94         supplier_name => $suppliers[0]->{'name'},
  95         booksellerid  => $suppliers[0]->{'id'},
  96         basketcount   => $suppliers[0]->{'basketcount'}
  97     );
  98 }
  99
 100 my $uid;
 101 if ($loggedinuser) {
 102     $uid = GetMember( borrowernumber => $loggedinuser )->{userid};
 103 }
 104
 105 my $userenv = C4::Context::userenv;
 106 my $viewbaskets = C4::Context->preference('AcqViewBaskets');
 107
 108 my $userbranch = $userenv->{branch};
 109
 110 my $budgets = GetBudgetHierarchy;
 111 my $has_budgets = 0;
 112 foreach my $r (@{$budgets}) {
 113     if (!defined $r->{budget_amount} || $r->{budget_amount} == 0) {
 114         next;
 115     }
 116     next unless (CanUserUseBudget($loggedinuser, $r, $userflags));
 117
 118     $has_budgets = 1;
 119     last;
 120 }
 121
 122 #build result page
 123 my $loop_suppliers = [];
 124
 125 for my $vendor (@suppliers) {
 126     my $baskets = GetBasketsInfosByBookseller( $vendor->{id}, $allbaskets );
 127
 128     my $loop_basket = [];
 129
 130     for my $basket ( @{$baskets} ) {
 131         if (CanUserManageBasket($loggedinuser, $basket, $userflags)) {
 132             my $member = GetMember( borrowernumber => $basket->{authorisedby} );
 133             foreach (qw(total_items total_biblios expected_items)) {
 134                 $basket->{$_} ||= 0;
 135             }
 136             if($member) {
 137                 $basket->{authorisedby_firstname} = $member->{firstname};
 138                 $basket->{authorisedby_surname} = $member->{surname};
 139             }
 140             if ($basket->{basketgroupid}) {
 141                 my $basketgroup = C4::Acquisition::GetBasketgroup($basket->{basketgroupid});
 142                 if ($basketgroup) {
 143                     $basket->{basketgroup} = $basketgroup;
 144                 }
 145             }
 146             push @{$loop_basket}, $basket;
 147         }
 148     }
 149
 150     push @{$loop_suppliers},
 151       { loop_basket => $loop_basket,
 152         booksellerid  => $vendor->{id},
 153         name        => $vendor->{name},
 154         active      => $vendor->{active},
 155       };
 156
 157 }
 158 $template->param(
 159     loop_suppliers => $loop_suppliers,
 160     supplier       => ( $booksellerid || $supplier ),
 161     count          => $supplier_count,
 162     has_budgets          => $has_budgets,
 163 );
 164 $template->{VARS}->{'allbaskets'} = $allbaskets;
 165
 166 output_html_with_http_headers $query, $cookie, $template->output;