admin/categories.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2002 Paul Poulain
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24 use C4::Context;
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Form::MessagingPreferences;
  28 use Koha::Patrons;
  29 use Koha::Database;
  30 use Koha::DateUtils;
  31 use Koha::Patron::Categories;
  32 use Koha::Libraries;
  33
  34 my $input         = new CGI;
  35 my $searchfield   = $input->param('description') // q||;
  36 my $categorycode  = $input->param('categorycode');
  37 my $op            = $input->param('op') // 'list';
  38 my @messages;
  39
  40 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  41     {
  42         template_name   => "admin/categories.tt",
  43         query           => $input,
  44         type            => "intranet",
  45         authnotrequired => 0,
  46         flagsrequired   => { parameters => 'manage_patron_categories' },
  47         debug           => 1,
  48     }
  49 );
  50
  51 if ( $op eq 'add_form' ) {
  52     my ( $category, $selected_branches );
  53     if ($categorycode) {
  54         $category          = Koha::Patron::Categories->find($categorycode);
  55         $selected_branches = $category->branch_limitations;
  56     }
  57
  58     my $branches = Koha::Libraries->search( {}, { order_by => ['branchname'] } )->unblessed;
  59     my @branches_loop;
  60     foreach my $branch ( @$branches ) {
  61         my $selected = ( grep { $_ eq $branch->{branchcode} } @$selected_branches ) ? 1 : 0;
  62         push @branches_loop,
  63           { branchcode => $branch->{branchcode},
  64             branchname => $branch->{branchname},
  65             selected   => $selected,
  66           };
  67     }
  68
  69     $template->param(
  70         category => $category,
  71         branches_loop       => \@branches_loop,
  72     );
  73
  74     if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
  75         C4::Form::MessagingPreferences::set_form_values(
  76             { categorycode => $categorycode }, $template );
  77     }
  78 }
  79 elsif ( $op eq 'add_validate' ) {
  80
  81     my $categorycode = $input->param('categorycode');
  82     my $description = $input->param('description');
  83     my $enrolmentperiod = $input->param('enrolmentperiod');
  84     my $enrolmentperioddate = $input->param('enrolmentperioddate') || undef;
  85     my $upperagelimit = $input->param('upperagelimit');
  86     my $dateofbirthrequired = $input->param('dateofbirthrequired');
  87     my $enrolmentfee = $input->param('enrolmentfee');
  88     my $reservefee = $input->param('reservefee');
  89     my $hidelostitems = $input->param('hidelostitems');
  90     my $overduenoticerequired = $input->param('overduenoticerequired');
  91     my $category_type = $input->param('category_type');
  92     my $BlockExpiredPatronOpacActions = $input->param('BlockExpiredPatronOpacActions');
  93     my $checkPrevCheckout = $input->param('checkprevcheckout');
  94     my $default_privacy = $input->param('default_privacy');
  95     my $can_reset_password = $input->param('can_reset_password');
  96     my @branches = grep { $_ ne q{} } $input->multi_param('branches');
  97
  98     my $is_a_modif = $input->param("is_a_modif");
  99
 100     if ($enrolmentperioddate) {
 101         $enrolmentperioddate = output_pref(
 102             {
 103                 dt         => dt_from_string($enrolmentperioddate),
 104                 dateformat => 'iso',
 105                 dateonly   => 1,
 106             }
 107         );
 108     }
 109
 110     if ($is_a_modif) {
 111         my $category = Koha::Patron::Categories->find( $categorycode );
 112         $category->categorycode($categorycode);
 113         $category->description($description);
 114         $category->enrolmentperiod($enrolmentperiod);
 115         $category->enrolmentperioddate($enrolmentperioddate);
 116         $category->upperagelimit($upperagelimit);
 117         $category->dateofbirthrequired($dateofbirthrequired);
 118         $category->enrolmentfee($enrolmentfee);
 119         $category->reservefee($reservefee);
 120         $category->hidelostitems($hidelostitems);
 121         $category->overduenoticerequired($overduenoticerequired);
 122         $category->category_type($category_type);
 123         $category->BlockExpiredPatronOpacActions($BlockExpiredPatronOpacActions);
 124         $category->checkprevcheckout($checkPrevCheckout);
 125         $category->default_privacy($default_privacy);
 126         $category->can_reset_password($can_reset_password);
 127         eval {
 128             $category->store;
 129             $category->replace_branch_limitations( \@branches );
 130         };
 131         if ( $@ ) {
 132             push @messages, {type => 'error', code => 'error_on_update' };
 133         } else {
 134             push @messages, { type => 'message', code => 'success_on_update' };
 135         }
 136     }
 137     else {
 138         my $category = Koha::Patron::Category->new({
 139             categorycode => $categorycode,
 140             description => $description,
 141             enrolmentperiod => $enrolmentperiod,
 142             enrolmentperioddate => $enrolmentperioddate,
 143             upperagelimit => $upperagelimit,
 144             dateofbirthrequired => $dateofbirthrequired,
 145             enrolmentfee => $enrolmentfee,
 146             reservefee => $reservefee,
 147             hidelostitems => $hidelostitems,
 148             overduenoticerequired => $overduenoticerequired,
 149             category_type => $category_type,
 150             BlockExpiredPatronOpacActions => $BlockExpiredPatronOpacActions,
 151             checkprevcheckout => $checkPrevCheckout,
 152             default_privacy => $default_privacy,
 153             can_reset_password => $can_reset_password,
 154         });
 155         eval {
 156             $category->store;
 157             $category->replace_branch_limitations( \@branches );
 158         };
 159
 160         if ( $@ ) {
 161             push @messages, { type => 'error', code => 'error_on_insert' };
 162         } else {
 163             push @messages, { type => 'message', code => 'success_on_insert' };
 164         }
 165     }
 166
 167     if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
 168         C4::Form::MessagingPreferences::handle_form_action( $input,
 169             { categorycode => scalar $input->param('categorycode') }, $template );
 170     }
 171
 172     $searchfield = q||;
 173     $op = 'list';
 174 }
 175 elsif ( $op eq 'delete_confirm' ) {
 176
 177     my $count = Koha::Patrons->search({
 178         categorycode => $categorycode
 179     })->count;
 180
 181     my $category = Koha::Patron::Categories->find($categorycode);
 182
 183     $template->param(
 184         category => $category,
 185         patrons_in_category => $count,
 186     );
 187
 188 }
 189 elsif ( $op eq 'delete_confirmed' ) {
 190     my $categorycode = uc( $input->param('categorycode') );
 191
 192     my $category = Koha::Patron::Categories->find( $categorycode );
 193     my $deleted = eval { $category->delete; };
 194
 195     if ( $@ or not $deleted ) {
 196         push @messages, {type => 'error', code => 'error_on_delete' };
 197     } else {
 198         push @messages, { type => 'message', code => 'success_on_delete' };
 199     }
 200
 201     $op = 'list';
 202 }
 203
 204 if ( $op eq 'list' ) {
 205     my $categories = Koha::Patron::Categories->search(
 206         {
 207             description => { -like => "$searchfield%" }
 208         },
 209         {
 210             order_by => ['category_type', 'description', 'categorycode' ]
 211         }
 212     );
 213
 214     $template->param(
 215         categories => $categories,
 216     )
 217 }
 218
 219 $template->param(
 220     categorycode => $categorycode,
 221     searchfield  => $searchfield,
 222     messages     => \@messages,
 223     op => $op,
 224 );
 225
 226 output_html_with_http_headers $input, $cookie, $template->output;
 227
 228 exit 0;