catalogue/detail.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17
  18
  19 use strict;
  20 use warnings;
  21
  22 use CGI;
  23 use C4::Auth;
  24 use C4::Dates qw/format_date/;
  25 use C4::Koha;
  26 use C4::Serials;    #uses getsubscriptionfrom biblionumber
  27 use C4::Output;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Circulation;
  31 use C4::Branch;
  32 use C4::Reserves;
  33 use C4::Members; # to use GetMember
  34 use C4::Serials;
  35 use C4::XISBN qw(get_xisbns get_biblionumber_from_isbn);
  36 use C4::External::Amazon;
  37 use C4::Search;         # enabled_staff_search_views
  38 use C4::Tags qw(get_tags);
  39 use C4::VirtualShelves;
  40 use C4::XSLT;
  41 use C4::Images;
  42 use Koha::DateUtils;
  43
  44 # use Smart::Comments;
  45
  46 my $query = CGI->new();
  47
  48 my $analyze = $query->param('analyze');
  49
  50 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  51     {
  52     template_name   =>  'catalogue/detail.tmpl',
  53         query           => $query,
  54         type            => "intranet",
  55         authnotrequired => 0,
  56         flagsrequired   => { catalogue => 1 },
  57     }
  58 );
  59
  60 my $biblionumber = $query->param('biblionumber');
  61 my $record       = GetMarcBiblio($biblionumber);
  62
  63 if ( not defined $record ) {
  64     # biblionumber invalid -> report and exit
  65     $template->param( unknownbiblionumber => 1,
  66                       biblionumber => $biblionumber );
  67     output_html_with_http_headers $query, $cookie, $template->output;
  68     exit;
  69 }
  70
  71 if($query->cookie("holdfor")){
  72     my $holdfor_patron = GetMember('borrowernumber' => $query->cookie("holdfor"));
  73     $template->param(
  74         holdfor => $query->cookie("holdfor"),
  75         holdfor_surname => $holdfor_patron->{'surname'},
  76         holdfor_firstname => $holdfor_patron->{'firstname'},
  77         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
  78     );
  79 }
  80
  81 my $fw           = GetFrameworkCode($biblionumber);
  82 my $showallitems = $query->param('showallitems');
  83 my $marcflavour  = C4::Context->preference("marcflavour");
  84
  85 # XSLT processing of some stuff
  86 if (C4::Context->preference("XSLTDetailsDisplay") ) {
  87     $template->param('XSLTDetailsDisplay' =>'1',
  88         'XSLTBloc' => XSLTParse4Display($biblionumber, $record, "XSLTDetailsDisplay") );
  89 }
  90
  91 $template->param( 'SpineLabelShowPrintOnBibDetails' => C4::Context->preference("SpineLabelShowPrintOnBibDetails") );
  92 $template->param( ocoins => GetCOinSBiblio($record) );
  93
  94 # some useful variables for enhanced content;
  95 # in each case, we're grabbing the first value we find in
  96 # the record and normalizing it
  97 my $upc = GetNormalizedUPC($record,$marcflavour);
  98 my $ean = GetNormalizedEAN($record,$marcflavour);
  99 my $oclc = GetNormalizedOCLCNumber($record,$marcflavour);
 100 my $isbn = GetNormalizedISBN(undef,$record,$marcflavour);
 101
 102 $template->param(
 103     normalized_upc => $upc,
 104     normalized_ean => $ean,
 105     normalized_oclc => $oclc,
 106     normalized_isbn => $isbn,
 107 );
 108
 109 my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
 110 my $marcisbnsarray   = GetMarcISBN( $record, $marcflavour );
 111 my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
 112 my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
 113 my $marcseriesarray  = GetMarcSeries($record,$marcflavour);
 114 my $marcurlsarray    = GetMarcUrls    ($record,$marcflavour);
 115 my $marchostsarray  = GetMarcHosts($record,$marcflavour);
 116 my $subtitle         = GetRecordValue('subtitle', $record, $fw);
 117
 118 # Get Branches, Itemtypes and Locations
 119 my $branches = GetBranches();
 120 my $itemtypes = GetItemTypes();
 121 my $dbh = C4::Context->dbh;
 122
 123 my @all_items = GetItemsInfo( $biblionumber );
 124 my @items;
 125 for my $itm (@all_items) {
 126     push @items, $itm unless ( $itm->{itemlost} && GetHideLostItemsPreference($borrowernumber) && !$showallitems);
 127 }
 128
 129 # flag indicating existence of at least one item linked via a host record
 130 my $hostrecords;
 131 # adding items linked via host biblios
 132 my @hostitems = GetHostItemsInfo($record);
 133 if (@hostitems){
 134         $hostrecords =1;
 135         push (@items,@hostitems);
 136 }
 137
 138 my $dat = &GetBiblioData($biblionumber);
 139
 140 # get count of holds
 141 my ( $holdcount, $holds ) = GetReservesFromBiblionumber($biblionumber,1);
 142
 143 #coping with subscriptions
 144 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 145 my @subscriptions       = GetSubscriptions( $dat->{title}, $dat->{issn}, undef, $biblionumber );
 146 my @subs;
 147
 148 foreach my $subscription (@subscriptions) {
 149     my %cell;
 150         my $serials_to_display;
 151     $cell{subscriptionid}    = $subscription->{subscriptionid};
 152     $cell{subscriptionnotes} = $subscription->{internalnotes};
 153     $cell{missinglist}       = $subscription->{missinglist};
 154     $cell{librariannote}     = $subscription->{librariannote};
 155     $cell{branchcode}        = $subscription->{branchcode};
 156     $cell{branchname}        = GetBranchName($subscription->{branchcode});
 157     $cell{hasalert}          = $subscription->{hasalert};
 158     $cell{callnumber}        = $subscription->{callnumber};
 159     $cell{closed}            = $subscription->{closed};
 160     #get the three latest serials.
 161         $serials_to_display = $subscription->{staffdisplaycount};
 162         $serials_to_display = C4::Context->preference('StaffSerialIssueDisplayCount') unless $serials_to_display;
 163         $cell{staffdisplaycount} = $serials_to_display;
 164     $cell{latestserials} =
 165       GetLatestSerials( $subscription->{subscriptionid}, $serials_to_display );
 166     push @subs, \%cell;
 167 }
 168
 169 if ( defined $dat->{'itemtype'} ) {
 170     $dat->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $dat->{itemtype} }{imageurl} );
 171 }
 172
 173 $dat->{'count'} = scalar @all_items + @hostitems;
 174 $dat->{'showncount'} = scalar @items + @hostitems;
 175 $dat->{'hiddencount'} = scalar @all_items + @hostitems - scalar @items;
 176
 177 my $shelflocations = GetKohaAuthorisedValues('items.location', $fw);
 178 my $collections    = GetKohaAuthorisedValues('items.ccode'   , $fw);
 179 my $copynumbers    = GetKohaAuthorisedValues('items.copynumber', $fw);
 180 my (@itemloop, %itemfields);
 181 my $norequests = 1;
 182 my $authvalcode_items_itemlost = GetAuthValCode('items.itemlost',$fw);
 183 my $authvalcode_items_damaged  = GetAuthValCode('items.damaged', $fw);
 184
 185 my $analytics_flag;
 186 my $materials_flag; # set this if the items have anything in the materials field
 187 foreach my $item (@items) {
 188
 189     $item->{homebranch}        = GetBranchName($item->{homebranch});
 190
 191     # can place holds defaults to yes
 192     $norequests = 0 unless ( ( $item->{'notforloan'} > 0 ) || ( $item->{'itemnotforloan'} > 0 ) );
 193
 194     # format some item fields for display
 195     if ( defined $item->{'publictype'} ) {
 196         $item->{ $item->{'publictype'} } = 1;
 197     }
 198     $item->{imageurl} = defined $item->{itype} ? getitemtypeimagelocation('intranet', $itemtypes->{ $item->{itype} }{imageurl})
 199                                                : '';
 200
 201         foreach (qw(datelastseen onloan)) {
 202                 $item->{$_} = format_date($item->{$_});
 203     }
 204     $item->{datedue} = format_sqldatetime($item->{datedue});
 205     # item damaged, lost, withdrawn loops
 206     $item->{itemlostloop} = GetAuthorisedValues($authvalcode_items_itemlost, $item->{itemlost}) if $authvalcode_items_itemlost;
 207     if ($item->{damaged}) {
 208         $item->{itemdamagedloop} = GetAuthorisedValues($authvalcode_items_damaged, $item->{damaged}) if $authvalcode_items_damaged;
 209     }
 210     #get shelf location and collection code description if they are authorised value.
 211     # same thing for copy number
 212     my $shelfcode = $item->{'location'};
 213     $item->{'location'} = $shelflocations->{$shelfcode} if ( defined( $shelfcode ) && defined($shelflocations) && exists( $shelflocations->{$shelfcode} ) );
 214     my $ccode = $item->{'ccode'};
 215     $item->{'ccode'} = $collections->{$ccode} if ( defined( $ccode ) && defined($collections) && exists( $collections->{$ccode} ) );
 216     my $copynumber = $item->{'copynumber'};
 217     $item->{'copynumber'} = $copynumbers->{$copynumber} if ( defined($copynumber) && defined($copynumbers) && exists( $copynumbers->{$copynumber} ) );
 218     foreach (qw(ccode enumchron copynumber itemnotes uri)) {
 219         $itemfields{$_} = 1 if ( $item->{$_} );
 220     }
 221
 222     # checking for holds
 223     my ($reservedate,$reservedfor,$expectedAt) = GetReservesFromItemnumber($item->{itemnumber});
 224     my $ItemBorrowerReserveInfo = GetMemberDetails( $reservedfor, 0);
 225
 226     if (C4::Context->preference('HidePatronName')){
 227         $item->{'hidepatronname'} = 1;
 228     }
 229
 230     if ( defined $reservedate ) {
 231         $item->{backgroundcolor} = 'reserved';
 232         $item->{reservedate}     = format_date($reservedate);
 233         $item->{ReservedForBorrowernumber}     = $reservedfor;
 234         $item->{ReservedForSurname}     = $ItemBorrowerReserveInfo->{'surname'};
 235         $item->{ReservedForFirstname}   = $ItemBorrowerReserveInfo->{'firstname'};
 236         $item->{ExpectedAtLibrary}      = $branches->{$expectedAt}{branchname};
 237         $item->{Reservedcardnumber}             = $ItemBorrowerReserveInfo->{'cardnumber'};
 238     }
 239
 240         # Check the transit status
 241     my ( $transfertwhen, $transfertfrom, $transfertto ) = GetTransfers($item->{itemnumber});
 242     if ( defined( $transfertwhen ) && ( $transfertwhen ne '' ) ) {
 243         $item->{transfertwhen} = format_date($transfertwhen);
 244         $item->{transfertfrom} = $branches->{$transfertfrom}{branchname};
 245         $item->{transfertto}   = $branches->{$transfertto}{branchname};
 246         $item->{nocancel} = 1;
 247     }
 248
 249     # FIXME: move this to a pm, check waiting status for holds
 250     my $sth2 = $dbh->prepare("SELECT * FROM reserves WHERE borrowernumber=? AND itemnumber=? AND found='W'");
 251     $sth2->execute($item->{ReservedForBorrowernumber},$item->{itemnumber});
 252     while (my $wait_hashref = $sth2->fetchrow_hashref) {
 253         $item->{waitingdate} = format_date($wait_hashref->{waitingdate});
 254     }
 255
 256     # item has a host number if its biblio number does not match the current bib
 257     if ($item->{biblionumber} ne $biblionumber){
 258         $item->{hostbiblionumber} = $item->{biblionumber};
 259         $item->{hosttitle} = GetBiblioData($item->{biblionumber})->{title};
 260     }
 261
 262         #count if item is used in analytical bibliorecords
 263         my $countanalytics= GetAnalyticsCount($item->{itemnumber});
 264         if ($countanalytics > 0){
 265                 $analytics_flag=1;
 266                 $item->{countanalytics} = $countanalytics;
 267         }
 268     if (defined($item->{'materials'}) && $item->{'materials'} =~ /\S/){
 269         $materials_flag = 1;
 270     }
 271     push @itemloop, $item;
 272 }
 273
 274 $template->param( norequests => $norequests );
 275 $template->param(
 276         MARCNOTES   => $marcnotesarray,
 277         MARCSUBJCTS => $marcsubjctsarray,
 278         MARCAUTHORS => $marcauthorsarray,
 279         MARCSERIES  => $marcseriesarray,
 280         MARCURLS => $marcurlsarray,
 281     MARCISBNS => $marcisbnsarray,
 282         MARCHOSTS => $marchostsarray,
 283         subtitle    => $subtitle,
 284         itemdata_ccode      => $itemfields{ccode},
 285         itemdata_enumchron  => $itemfields{enumchron},
 286         itemdata_uri        => $itemfields{uri},
 287         itemdata_copynumber => $itemfields{copynumber},
 288         volinfo                         => $itemfields{enumchron},
 289     itemdata_itemnotes  => $itemfields{itemnotes},
 290         z3950_search_params     => C4::Search::z3950_search_args($dat),
 291     holdcount           => $holdcount,
 292         hostrecords         => $hostrecords,
 293         analytics_flag  => $analytics_flag,
 294         C4::Search::enabled_staff_search_views,
 295         materials       => $materials_flag,
 296 );
 297
 298 if (C4::Context->preference("AlternateHoldingsField") && scalar @items == 0) {
 299     my $fieldspec = C4::Context->preference("AlternateHoldingsField");
 300     my $subfields = substr $fieldspec, 3;
 301     my $holdingsep = C4::Context->preference("AlternateHoldingsSeparator") || ' ';
 302     my @alternateholdingsinfo = ();
 303     my @holdingsfields = $record->field(substr $fieldspec, 0, 3);
 304
 305     for my $field (@holdingsfields) {
 306         my %holding = ( holding => '' );
 307         my $havesubfield = 0;
 308         for my $subfield ($field->subfields()) {
 309             if ((index $subfields, $$subfield[0]) >= 0) {
 310                 $holding{'holding'} .= $holdingsep if (length $holding{'holding'} > 0);
 311                 $holding{'holding'} .= $$subfield[1];
 312                 $havesubfield++;
 313             }
 314         }
 315         if ($havesubfield) {
 316             push(@alternateholdingsinfo, \%holding);
 317         }
 318     }
 319
 320     $template->param(
 321         ALTERNATEHOLDINGS   => \@alternateholdingsinfo,
 322         );
 323 }
 324
 325 my @results = ( $dat, );
 326 foreach ( keys %{$dat} ) {
 327     $template->param( "$_" => defined $dat->{$_} ? $dat->{$_} : '' );
 328 }
 329
 330 # does not work: my %views_enabled = map { $_ => 1 } $template->query(loop => 'EnableViews');
 331 # method query not found?!?!
 332 $template->param( AmazonTld => get_amazon_tld() ) if ( C4::Context->preference("AmazonCoverImages"));
 333 $template->param(
 334     itemloop        => \@itemloop,
 335     biblionumber        => $biblionumber,
 336     ($analyze? 'analyze':'detailview') =>1,
 337     subscriptions       => \@subs,
 338     subscriptionsnumber => $subscriptionsnumber,
 339     subscriptiontitle   => $dat->{title},
 340 );
 341
 342 # $debug and $template->param(debug_display => 1);
 343
 344 # Lists
 345
 346 if (C4::Context->preference("virtualshelves") ) {
 347    $template->param( 'GetShelves' => GetBibliosShelves( $biblionumber ) );
 348 }
 349
 350 # XISBN Stuff
 351 if (C4::Context->preference("FRBRizeEditions")==1) {
 352     eval {
 353         $template->param(
 354             XISBNS => get_xisbns($isbn)
 355         );
 356     };
 357     if ($@) { warn "XISBN Failed $@"; }
 358 }
 359
 360 if ( C4::Context->preference("LocalCoverImages") == 1 ) {
 361     my @images = ListImagesForBiblio($biblionumber);
 362     $template->{VARS}->{localimages} = \@images;
 363 }
 364
 365 # Get OPAC URL
 366 if (C4::Context->preference('OPACBaseURL')){
 367      $template->param( OpacUrl => C4::Context->preference('OPACBaseURL') );
 368 }
 369
 370 # Displaying tags
 371
 372 my $tag_quantity;
 373 if (C4::Context->preference('TagsEnabled') and $tag_quantity = C4::Context->preference('TagsShowOnDetail')) {
 374     $template->param(
 375         TagsEnabled => 1,
 376         TagsShowOnDetail => $tag_quantity
 377     );
 378     $template->param(TagLoop => get_tags({biblionumber=>$biblionumber, approved=>1,
 379                                 'sort'=>'-weight', limit=>$tag_quantity}));
 380 }
 381
 382 output_html_with_http_headers $query, $cookie, $template->output;