members/moremember.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 moremember.pl
  24
  25  script to do a borrower enquiry/bring up borrower details etc
  26  Displays all the details about a borrower
  27  written 20/12/99 by chris@katipo.co.nz
  28  last modified 21/1/2000 by chris@katipo.co.nz
  29  modified 31/1/2001 by chris@katipo.co.nz
  30    to not allow items on request to be renewed
  31
  32  needs html removed and to use the C4::Output more, but its tricky
  33
  34 =cut
  35
  36 use strict;
  37 #use warnings; FIXME - Bug 2505
  38 use CGI qw ( -utf8 );
  39 use C4::Context;
  40 use C4::Auth;
  41 use C4::Output;
  42 use C4::Members;
  43 use C4::Members::Attributes;
  44 use C4::Members::AttributeTypes;
  45 use C4::Reserves;
  46 use C4::Circulation;
  47 use C4::Koha;
  48 use C4::Letters;
  49 use C4::Biblio;
  50 use C4::Branch; # GetBranchName
  51 use C4::Form::MessagingPreferences;
  52 use List::MoreUtils qw/uniq/;
  53 use C4::Members::Attributes qw(GetBorrowerAttributes);
  54 use Koha::Patron::Debarments qw(GetDebarments IsDebarred);
  55 use Koha::Patron::Images;
  56 use Module::Load;
  57 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
  58     load Koha::NorwegianPatronDB, qw( NLGetSyncDataFromBorrowernumber );
  59 }
  60 #use Smart::Comments;
  61 #use Data::Dumper;
  62 use DateTime;
  63 use Koha::DateUtils;
  64 use Koha::Database;
  65
  66 use vars qw($debug);
  67
  68 BEGIN {
  69         $debug = $ENV{DEBUG} || 0;
  70 }
  71
  72 my $dbh = C4::Context->dbh;
  73
  74 my $input = CGI->new;
  75 $debug or $debug = $input->param('debug') || 0;
  76 my $print = $input->param('print');
  77
  78 my $template_name;
  79 my $quickslip = 0;
  80
  81 my $flagsrequired;
  82 if (defined $print and $print eq "page") {
  83     $template_name = "members/moremember-print.tt";
  84     # circ staff who process checkouts but can't edit
  85     # patrons still need to be able to access print view
  86     $flagsrequired = { circulate => "circulate_remaining_permissions" };
  87 } elsif (defined $print and $print eq "slip") {
  88     $template_name = "members/moremember-receipt.tt";
  89     # circ staff who process checkouts but can't edit
  90     # patrons still need to be able to print receipts
  91     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  92 } elsif (defined $print and $print eq "qslip") {
  93     $template_name = "members/moremember-receipt.tt";
  94     $quickslip = 1;
  95     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  96 } elsif (defined $print and $print eq "brief") {
  97     $template_name = "members/moremember-brief.tt";
  98     $flagsrequired = { borrowers => 1 };
  99 } else {
 100     $template_name = "members/moremember.tt";
 101     $flagsrequired = { borrowers => 1 };
 102 }
 103
 104 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 105     {
 106         template_name   => $template_name,
 107         query           => $input,
 108         type            => "intranet",
 109         authnotrequired => 0,
 110         flagsrequired   => $flagsrequired,
 111         debug           => 1,
 112     }
 113 );
 114 my $borrowernumber = $input->param('borrowernumber');
 115 my $error = $input->param('error');
 116 $template->param( error => $error ) if ( $error );
 117
 118 my ( $od, $issue, $fines ) = GetMemberIssuesAndFines($borrowernumber);
 119 $template->param( issuecount => $issue );
 120
 121 my $data = GetMember( 'borrowernumber' => $borrowernumber );
 122
 123 if ( not defined $data ) {
 124     $template->param (unknowuser => 1);
 125         output_html_with_http_headers $input, $cookie, $template->output;
 126     exit;
 127 }
 128
 129 my $category_type = $data->{'category_type'};
 130
 131 $debug and printf STDERR "dates (enrolled,expiry,birthdate) raw: (%s, %s, %s)\n", map {$data->{$_}} qw(dateenrolled dateexpiry dateofbirth);
 132 foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 133     my $userdate = $data->{$_};
 134     unless ($userdate) {
 135         $debug and warn sprintf "Empty \$data{%12s}", $_;
 136         $data->{$_} = '';
 137         next;
 138     }
 139     $template->param( $_ => dt_from_string( $userdate ) );
 140 }
 141 $data->{'IS_ADULT'} = ( $data->{'categorycode'} ne 'I' );
 142
 143 for (qw(gonenoaddress lost borrowernotes)) {
 144          $data->{$_} and $template->param(flagged => 1) and last;
 145 }
 146
 147 if ( IsDebarred($borrowernumber) ) {
 148     $template->param( 'userdebarred' => 1, 'flagged' => 1 );
 149     my $debar = $data->{'debarred'};
 150     if ( $debar ne "9999-12-31" ) {
 151         $template->param( 'userdebarreddate' => output_pref( { dt => dt_from_string( $debar ), dateonly => 1 } ) );
 152         $template->param( 'debarredcomment'  => $data->{debarredcomment} );
 153     }
 154 }
 155
 156 $data->{ "sex_".$data->{'sex'}."_p" } = 1 if defined $data->{sex};
 157
 158 if ( $category_type eq 'C') {
 159    my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 160    my $cnt = scalar(@$catcodes);
 161
 162    $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 163    $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 164 }
 165
 166 my $patron = Koha::Patrons->find($data->{borrowernumber});
 167 my @guarantees = $patron->guarantees;
 168 if ( @guarantees ) {
 169     $template->param( guarantees => \@guarantees );
 170 }
 171 elsif ( $patron->guarantorid ) {
 172     $template->param( guarantor => $patron->guarantor );
 173 }
 174
 175 $template->param( adultborrower => 1 ) if ( $category_type eq 'A' || $category_type eq 'I' );
 176
 177 my %bor;
 178 $bor{'borrowernumber'} = $borrowernumber;
 179
 180 # Converts the branchcode to the branch name
 181 my $samebranch;
 182 if ( C4::Context->preference("IndependentBranches") ) {
 183     my $userenv = C4::Context->userenv;
 184     if ( C4::Context->IsSuperLibrarian() ) {
 185         $samebranch = 1;
 186     }
 187     else {
 188         $samebranch = ( $data->{'branchcode'} eq $userenv->{branch} );
 189     }
 190 }
 191 else {
 192     $samebranch = 1;
 193 }
 194 my $library = Koha::Libraries->find( $data->{branchcode})->unblessed;
 195 @{$data}{keys %$library} = values %$library; # merge in all branch columns
 196
 197 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 198 my $lib1 = &GetSortDetails( "Bsort1", $data->{'sort1'} );
 199 my $lib2 = &GetSortDetails( "Bsort2", $data->{'sort2'} );
 200 $template->param( lib1 => $lib1 ) if ($lib1);
 201 $template->param( lib2 => $lib2 ) if ($lib2);
 202
 203 # If printing a page, send the account informations to the template
 204 if ($print eq "page") {
 205     foreach my $accountline (@$accts) {
 206         $accountline->{amount} = sprintf '%.2f', $accountline->{amount};
 207         $accountline->{amountoutstanding} = sprintf '%.2f', $accountline->{amountoutstanding};
 208
 209         if ($accountline->{accounttype} ne 'F' && $accountline->{accounttype} ne 'FU'){
 210             $accountline->{printtitle} = 1;
 211         }
 212     }
 213     $template->param( accounts => $accts );
 214 }
 215
 216 # Show OPAC privacy preference is system preference is set
 217 if ( C4::Context->preference('OPACPrivacy') ) {
 218     $template->param( OPACPrivacy => 1);
 219     $template->param( "privacy".$data->{'privacy'} => 1);
 220 }
 221
 222 my @relatives = GetMemberRelatives($borrowernumber);
 223 my $relatives_issues_count =
 224   Koha::Database->new()->schema()->resultset('Issue')
 225   ->count( { borrowernumber => \@relatives } );
 226
 227 my $today       = DateTime->now( time_zone => C4::Context->tz);
 228 $today->truncate(to => 'day');
 229 my $overdues_exist = 0;
 230 my $totalprice = 0;
 231
 232 # Calculate and display patron's age
 233 my $dateofbirth = $data->{ 'dateofbirth' };
 234 my $age = GetAge($dateofbirth);
 235 $template->param( age => $age );
 236
 237 ### ###############################################################################
 238 # BUILD HTML
 239 # show all reserves of this borrower, and the position of the reservation ....
 240 if ($borrowernumber) {
 241     $template->param(
 242         holds_count => Koha::Database->new()->schema()->resultset('Reserve')
 243           ->count( { borrowernumber => $borrowernumber } ) );
 244 }
 245
 246 # current alert subscriptions
 247 my $alerts = getalert($borrowernumber);
 248 foreach (@$alerts) {
 249     $_->{ $_->{type} } = 1;
 250     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 251 }
 252
 253 # Add sync data to the user data
 254 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
 255     my $sync = NLGetSyncDataFromBorrowernumber( $borrowernumber );
 256     if ( $sync ) {
 257         $data->{'sync'}       = $sync->sync;
 258         $data->{'syncstatus'} = $sync->syncstatus;
 259         $data->{'lastsync'}   = $sync->lastsync;
 260     }
 261 }
 262
 263 # check to see if patron's image exists in the database
 264 # basically this gives us a template var to condition the display of
 265 # patronimage related interface on
 266 my $patron_image = Koha::Patron::Images->find($data->{borrowernumber});
 267 $template->param( picture => 1 ) if $patron_image;
 268
 269 my $branch=C4::Context->userenv->{'branch'};
 270
 271 $template->param(%$data);
 272
 273 if (C4::Context->preference('ExtendedPatronAttributes')) {
 274     my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
 275     my @classes = uniq( map {$_->{class}} @$attributes );
 276     @classes = sort @classes;
 277
 278     my @attributes_loop;
 279     for my $class (@classes) {
 280         my @items;
 281         for my $attr (@$attributes) {
 282             push @items, $attr if $attr->{class} eq $class
 283         }
 284         my $lib = GetAuthorisedValueByCode( 'PA_CLASS', $class ) || $class;
 285         push @attributes_loop, {
 286             class => $class,
 287             items => \@items,
 288             lib   => $lib,
 289         };
 290     }
 291
 292     $template->param(
 293         ExtendedPatronAttributes => 1,
 294         attributes_loop => \@attributes_loop
 295     );
 296
 297     my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 298     if (scalar(@types) == 0) {
 299         $template->param(no_patron_attribute_types => 1);
 300     }
 301 }
 302
 303 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 304     C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 305     $template->param(messaging_form_inactive => 1);
 306     $template->param(SMSSendDriver => C4::Context->preference("SMSSendDriver"));
 307     $template->param(SMSnumber     => defined $data->{'smsalertnumber'} ? $data->{'smsalertnumber'} : $data->{'mobile'});
 308     $template->param(TalkingTechItivaPhone => C4::Context->preference("TalkingTechItivaPhoneNotification"));
 309 }
 310
 311 # in template <TMPL_IF name="I"> => instutitional (A for Adult, C for children)
 312 $template->param( $data->{'categorycode'} => 1 );
 313 $template->param(
 314     detailview => 1,
 315     borrowernumber  => $borrowernumber,
 316     othernames      => $data->{'othernames'},
 317     categoryname    => $data->{'description'},
 318     was_renewed     => $input->param('was_renewed') ? 1 : 0,
 319     branch          => $branch,
 320     todaysdate      => output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }),
 321     totalprice      => sprintf("%.2f", $totalprice),
 322     totaldue        => sprintf("%.2f", $total),
 323     totaldue_raw    => $total,
 324     overdues_exist  => $overdues_exist,
 325     StaffMember     => ($category_type eq 'S'),
 326     is_child        => ($category_type eq 'C'),
 327     samebranch      => $samebranch,
 328     quickslip       => $quickslip,
 329     privacy_guarantor_checkouts => $data->{'privacy_guarantor_checkouts'},
 330     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 331     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 332     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 333     RoutingSerials => C4::Context->preference('RoutingSerials'),
 334     debarments => GetDebarments({ borrowernumber => $borrowernumber }),
 335     PatronsPerPage => C4::Context->preference("PatronsPerPage") || 20,
 336     relatives_issues_count => $relatives_issues_count,
 337     relatives_borrowernumbers => \@relatives,
 338 );
 339
 340 output_html_with_http_headers $input, $cookie, $template->output;