members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Auth;
  29 use C4::Context;
  30 use C4::Members;
  31 use C4::Members::Statistics;
  32 use C4::Members::Attributes qw(GetBorrowerAttributes);
  33 use C4::Output;
  34 use Koha::Patrons;
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => "members/statistics.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrowers => 'edit_borrowers' },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $borrowernumber = $input->param('borrowernumber');
  49
  50 my $logged_in_user = Koha::Patrons->find( $loggedinuser ) or die "Not logged in";
  51 my $patron         = Koha::Patrons->find( $borrowernumber );
  52 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  53
  54 my $category = $patron->category;
  55
  56 # Construct column names
  57 my $fields = C4::Members::Statistics::get_fields();
  58 our @statistic_column_names = split '\|', $fields;
  59 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  60 our @column_names = ( @statistic_column_names, @value_column_names );
  61
  62 # Get statistics
  63 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  64 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  65 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  66 my $r = merge (
  67     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  68 );
  69
  70 add_actual_state( $r );
  71 my ( $total, $datas ) = build_array( $r );
  72
  73 # Gettings sums
  74 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  75 my $count_total_issues = $total->{count_total_issues_today} || 0;
  76 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  77 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  78
  79 if (C4::Context->preference('ExtendedPatronAttributes')) {
  80     my $attributes = GetBorrowerAttributes($borrowernumber);
  81     $template->param(
  82         ExtendedPatronAttributes => 1,
  83         extendedattributes => $attributes
  84     );
  85 }
  86
  87 $template->param( picture => 1 ) if $patron->image;
  88
  89 $template->param( adultborrower => 1 ) if ( $category->category_type eq 'A' || $category->category_type eq 'I' );
  90
  91 $template->param(
  92     patron             => $patron,
  93     statisticsview     => 1,
  94     datas              => $datas,
  95     column_names       => \@statistic_column_names,
  96     count_total_issues => $count_total_issues,
  97     count_total_issues_returned => $count_total_issues_returned,
  98     count_total_precedent_state => $count_total_precedent_state,
  99     count_total_actual_state => $count_total_actual_state,
 100 );
 101
 102 output_html_with_http_headers $input, $cookie, $template->output;
 103
 104
 105 =head1 FUNCTIONS
 106
 107 =head2 add_actual_state
 108
 109   Add a 'count_actual_state' key in all hashes
 110   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 111
 112 =cut
 113
 114 sub add_actual_state {
 115     my ( $array ) = @_;
 116     for my $hash ( @$array ) {
 117         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 118     }
 119 }
 120
 121 =head2 build_array
 122
 123   Build a new array containing values of hashes.
 124   It used by template whitch display silly values.
 125   ex:
 126     $array = [
 127       {
 128         'count_total_issues_returned_today' => 1,
 129         'ccode' => 'ccode',
 130         'count_actual_state' => 1,
 131         'count_precedent_state' => 1,
 132         'homebranch' => 'homebranch',
 133         'count_total_issues_today' => 1,
 134         'itype' => 'itype'
 135       }
 136     ];
 137   and returns:
 138     [
 139       [
 140         'homebranch',
 141         'itype',
 142         'ccode',
 143         1,
 144         1,
 145         1,
 146         1
 147       ]
 148     ];
 149
 150 =cut
 151
 152 sub build_array {
 153     my ( $array ) = @_;
 154     my ( @r, $total );
 155     for my $hash ( @$array) {
 156         my @line;
 157         for my $cn ( ( @column_names, 'count_actual_state') ) {
 158             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 159                 $hash->{$cn} //= 0;
 160                 if ( exists $total->{$cn} ) {
 161                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 162                 } else {
 163                     $total->{$cn} = $hash->{$cn};
 164                 }
 165             }
 166             push @line, $hash->{$cn};
 167         }
 168         push @r, \@line;
 169     }
 170     return ( $total, \@r );
 171 }
 172
 173 =head2 merge
 174
 175   Merge hashes with the same statistic column names into one
 176   param: array, a arrayref of arrayrefs
 177   ex:
 178   @array = (
 179      {
 180        'ccode' => 'ccode',
 181        'count_precedent_state' => '1',
 182        'homebranch' => 'homebranch',
 183        'itype' => 'itype'
 184      },
 185      {
 186        'count_total_issues_returned_today' => '1',
 187        'ccode' => 'ccode',
 188        'homebranch' => 'homebranch',
 189        'itype' => 'itype'
 190      }
 191    );
 192    and returns:
 193    [
 194      {
 195        'count_total_issues_returned_today' => '1',
 196        'ccode' => 'ccode',
 197        'count_precedent_state' => '1',
 198        'homebranch' => 'homebranch',
 199        'itype' => 'itype'
 200      }
 201    ];
 202
 203 =cut
 204
 205 sub merge {
 206     my @array = @_;
 207     my @r;
 208     for my $h ( @array ) {
 209         my $exists = 0;
 210         for my $ch ( @r ) {
 211             $exists = 1;
 212             for my $cn ( @statistic_column_names ) {
 213                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 214                     $exists = 0;
 215                     last;
 216                 }
 217             }
 218             if ($exists){
 219                 for my $cn ( @value_column_names ) {
 220                     next if not exists $h->{$cn};
 221                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 222                 }
 223                 last;
 224             }
 225         }
 226
 227         if ( not $exists ) {push @r, $h;}
 228     }
 229     return \@r;
 230 }