misc/cronjobs/cleanup_database.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 PTFS, Inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use constant DEFAULT_ZEBRAQ_PURGEDAYS             => 30;
  23 use constant DEFAULT_MAIL_PURGEDAYS               => 30;
  24 use constant DEFAULT_IMPORT_PURGEDAYS             => 60;
  25 use constant DEFAULT_LOGS_PURGEDAYS               => 180;
  26 use constant DEFAULT_SEARCHHISTORY_PURGEDAYS      => 30;
  27 use constant DEFAULT_SHARE_INVITATION_EXPIRY_DAYS => 14;
  28 use constant DEFAULT_DEBARMENTS_PURGEDAYS         => 30;
  29
  30 BEGIN {
  31     # find Koha's Perl modules
  32     # test carefully before changing this
  33     use FindBin;
  34     eval { require "$FindBin::Bin/../kohalib.pl" };
  35 }
  36
  37 use Koha::Script -cron;
  38 use C4::Context;
  39 use C4::Search;
  40 use C4::Search::History;
  41 use Getopt::Long;
  42 use C4::Log;
  43 use C4::Accounts;
  44 use Koha::UploadedFiles;
  45
  46 sub usage {
  47     print STDERR <<USAGE;
  48 Usage: $0 [-h|--help] [--sessions] [--sessdays DAYS] [-v|--verbose] [--zebraqueue DAYS] [-m|--mail] [--merged] [--import DAYS] [--logs DAYS] [--searchhistory DAYS] [--restrictions DAYS] [--all-restrictions] [--fees DAYS] [--temp-uploads] [--temp-uploads-days DAYS] [--uploads-missing 0|1 ]
  49
  50    -h --help          prints this help message, and exits, ignoring all
  51                       other options
  52    --sessions         purge the sessions table.  If you use this while users
  53                       are logged into Koha, they will have to reconnect.
  54    --sessdays DAYS    purge only sessions older than DAYS days.
  55    -v --verbose       will cause the script to give you a bit more information
  56                       about the run.
  57    --zebraqueue DAYS  purge completed zebraqueue entries older than DAYS days.
  58                       Defaults to 30 days if no days specified.
  59    -m --mail DAYS     purge items from the mail queue that are older than DAYS days.
  60                       Defaults to 30 days if no days specified.
  61    --merged           purged completed entries from need_merge_authorities.
  62    --import DAYS      purge records from import tables older than DAYS days.
  63                       Defaults to 60 days if no days specified.
  64    --z3950            purge records from import tables that are the result
  65                       of Z39.50 searches
  66    --fees DAYS        purge entries accountlines older than DAYS days, where
  67                       amountoutstanding is 0 or NULL.
  68                       In the case of --fees, DAYS must be greater than
  69                       or equal to 1.
  70    --logs DAYS        purge entries from action_logs older than DAYS days.
  71                       Defaults to 180 days if no days specified.
  72    --searchhistory DAYS  purge entries from search_history older than DAYS days.
  73                          Defaults to 30 days if no days specified
  74    --list-invites  DAYS  purge (unaccepted) list share invites older than DAYS
  75                          days.  Defaults to 14 days if no days specified.
  76    --restrictions DAYS   purge patrons restrictions expired since more than DAYS days.
  77                          Defaults to 30 days if no days specified.
  78     --all-restrictions   purge all expired patrons restrictions.
  79    --del-exp-selfreg  Delete expired self registration accounts
  80    --del-unv-selfreg  DAYS  Delete unverified self registrations older than DAYS
  81    --unique-holidays DAYS  Delete all unique holidays older than DAYS
  82    --temp-uploads     Delete temporary uploads.
  83    --temp-uploads-days DAYS Override the corresponding preference value.
  84    --uploads-missing FLAG Delete upload records for missing files when FLAG is true, count them otherwise
  85    --oauth-tokens     Delete expired OAuth2 tokens
  86 USAGE
  87     exit $_[0];
  88 }
  89
  90 my $help;
  91 my $sessions;
  92 my $sess_days;
  93 my $verbose;
  94 my $zebraqueue_days;
  95 my $mail;
  96 my $purge_merged;
  97 my $pImport;
  98 my $pLogs;
  99 my $pSearchhistory;
 100 my $pZ3950;
 101 my $pListShareInvites;
 102 my $pDebarments;
 103 my $allDebarments;
 104 my $pExpSelfReg;
 105 my $pUnvSelfReg;
 106 my $fees_days;
 107 my $special_holidays_days;
 108 my $temp_uploads;
 109 my $temp_uploads_days;
 110 my $uploads_missing;
 111 my $oauth_tokens;
 112
 113 GetOptions(
 114     'h|help'            => \$help,
 115     'sessions'          => \$sessions,
 116     'sessdays:i'        => \$sess_days,
 117     'v|verbose'         => \$verbose,
 118     'm|mail:i'          => \$mail,
 119     'zebraqueue:i'      => \$zebraqueue_days,
 120     'merged'            => \$purge_merged,
 121     'import:i'          => \$pImport,
 122     'z3950'             => \$pZ3950,
 123     'logs:i'            => \$pLogs,
 124     'fees:i'            => \$fees_days,
 125     'searchhistory:i'   => \$pSearchhistory,
 126     'list-invites:i'    => \$pListShareInvites,
 127     'restrictions:i'    => \$pDebarments,
 128     'all-restrictions'  => \$allDebarments,
 129     'del-exp-selfreg'   => \$pExpSelfReg,
 130     'del-unv-selfreg'   => \$pUnvSelfReg,
 131     'unique-holidays:i' => \$special_holidays_days,
 132     'temp-uploads'      => \$temp_uploads,
 133     'temp-uploads-days:i' => \$temp_uploads_days,
 134     'uploads-missing:i' => \$uploads_missing,
 135     'oauth-tokens'      => \$oauth_tokens,
 136 ) || usage(1);
 137
 138 # Use default values
 139 $sessions          = 1                                    if $sess_days                  && $sess_days > 0;
 140 $pImport           = DEFAULT_IMPORT_PURGEDAYS             if defined($pImport)           && $pImport == 0;
 141 $pLogs             = DEFAULT_LOGS_PURGEDAYS               if defined($pLogs)             && $pLogs == 0;
 142 $zebraqueue_days   = DEFAULT_ZEBRAQ_PURGEDAYS             if defined($zebraqueue_days)   && $zebraqueue_days == 0;
 143 $mail              = DEFAULT_MAIL_PURGEDAYS               if defined($mail)              && $mail == 0;
 144 $pSearchhistory    = DEFAULT_SEARCHHISTORY_PURGEDAYS      if defined($pSearchhistory)    && $pSearchhistory == 0;
 145 $pListShareInvites = DEFAULT_SHARE_INVITATION_EXPIRY_DAYS if defined($pListShareInvites) && $pListShareInvites == 0;
 146 $pDebarments       = DEFAULT_DEBARMENTS_PURGEDAYS         if defined($pDebarments)       && $pDebarments == 0;
 147
 148 if ($help) {
 149     usage(0);
 150 }
 151
 152 unless ( $sessions
 153     || $zebraqueue_days
 154     || $mail
 155     || $purge_merged
 156     || $pImport
 157     || $pLogs
 158     || $fees_days
 159     || $pSearchhistory
 160     || $pZ3950
 161     || $pListShareInvites
 162     || $pDebarments
 163     || $allDebarments
 164     || $pExpSelfReg
 165     || $pUnvSelfReg
 166     || $special_holidays_days
 167     || $temp_uploads
 168     || defined $uploads_missing
 169     || $oauth_tokens
 170 ) {
 171     print "You did not specify any cleanup work for the script to do.\n\n";
 172     usage(1);
 173 }
 174
 175 if ($pDebarments && $allDebarments) {
 176     print "You can not specify both --restrictions and --all-restrictions.\n\n";
 177     usage(1);
 178 }
 179
 180 cronlogaction();
 181
 182 my $dbh = C4::Context->dbh();
 183 my $sth;
 184 my $sth2;
 185 my $count;
 186
 187 if ( $sessions && !$sess_days ) {
 188     if ($verbose) {
 189         print "Session purge triggered.\n";
 190         $sth = $dbh->prepare(q{ SELECT COUNT(*) FROM sessions });
 191         $sth->execute() or die $dbh->errstr;
 192         my @count_arr = $sth->fetchrow_array;
 193         print "$count_arr[0] entries will be deleted.\n";
 194     }
 195     $sth = $dbh->prepare(q{ TRUNCATE sessions });
 196     $sth->execute() or die $dbh->errstr;
 197     if ($verbose) {
 198         print "Done with session purge.\n";
 199     }
 200 }
 201 elsif ( $sessions && $sess_days > 0 ) {
 202     print "Session purge triggered with days>$sess_days.\n" if $verbose;
 203     RemoveOldSessions();
 204     print "Done with session purge with days>$sess_days.\n" if $verbose;
 205 }
 206
 207 if ($zebraqueue_days) {
 208     $count = 0;
 209     print "Zebraqueue purge triggered for $zebraqueue_days days.\n" if $verbose;
 210     $sth = $dbh->prepare(
 211         q{
 212             SELECT id,biblio_auth_number,server,time
 213             FROM zebraqueue
 214             WHERE done=1 AND time < date_sub(curdate(), INTERVAL ? DAY)
 215         }
 216     );
 217     $sth->execute($zebraqueue_days) or die $dbh->errstr;
 218     $sth2 = $dbh->prepare(q{ DELETE FROM zebraqueue WHERE id=? });
 219     while ( my $record = $sth->fetchrow_hashref ) {
 220         $sth2->execute( $record->{id} ) or die $dbh->errstr;
 221         $count++;
 222     }
 223     print "$count records were deleted.\nDone with zebraqueue purge.\n" if $verbose;
 224 }
 225
 226 if ($mail) {
 227     print "Mail queue purge triggered for $mail days.\n" if $verbose;
 228     $sth = $dbh->prepare(
 229         q{
 230             DELETE FROM message_queue
 231             WHERE time_queued < date_sub(curdate(), INTERVAL ? DAY)
 232         }
 233     );
 234     $sth->execute($mail) or die $dbh->errstr;
 235     $count = $sth->rows;
 236     $sth->finish;
 237     print "$count messages were deleted from the mail queue.\nDone with message_queue purge.\n" if $verbose;
 238 }
 239
 240 if ($purge_merged) {
 241     print "Purging completed entries from need_merge_authorities.\n" if $verbose;
 242     $sth = $dbh->prepare(q{ DELETE FROM need_merge_authorities WHERE done=1 });
 243     $sth->execute() or die $dbh->errstr;
 244     print "Done with purging need_merge_authorities.\n" if $verbose;
 245 }
 246
 247 if ($pImport) {
 248     print "Purging records from import tables.\n" if $verbose;
 249     PurgeImportTables();
 250     print "Done with purging import tables.\n" if $verbose;
 251 }
 252
 253 if ($pZ3950) {
 254     print "Purging Z39.50 records from import tables.\n" if $verbose;
 255     PurgeZ3950();
 256     print "Done with purging Z39.50 records from import tables.\n" if $verbose;
 257 }
 258
 259 if ($pLogs) {
 260     print "Purging records from action_logs.\n" if $verbose;
 261     $sth = $dbh->prepare(
 262         q{
 263             DELETE FROM action_logs
 264             WHERE timestamp < date_sub(curdate(), INTERVAL ? DAY)
 265         }
 266     );
 267     $sth->execute($pLogs) or die $dbh->errstr;
 268     print "Done with purging action_logs.\n" if $verbose;
 269 }
 270
 271 if ($fees_days) {
 272     print "Purging records from accountlines.\n" if $verbose;
 273     purge_zero_balance_fees( $fees_days );
 274     print "Done purging records from accountlines.\n" if $verbose;
 275 }
 276
 277 if ($pSearchhistory) {
 278     print "Purging records older than $pSearchhistory from search_history.\n" if $verbose;
 279     C4::Search::History::delete({ interval => $pSearchhistory });
 280     print "Done with purging search_history.\n" if $verbose;
 281 }
 282
 283 if ($pListShareInvites) {
 284     print "Purging unaccepted list share invites older than $pListShareInvites days.\n" if $verbose;
 285     $sth = $dbh->prepare(
 286         q{
 287             DELETE FROM virtualshelfshares
 288             WHERE invitekey IS NOT NULL
 289             AND (sharedate + INTERVAL ? DAY) < NOW()
 290         }
 291     );
 292     $sth->execute($pListShareInvites);
 293     print "Done with purging unaccepted list share invites.\n" if $verbose;
 294 }
 295
 296 if ($pDebarments) {
 297     print "Expired patrons restrictions purge triggered for $pDebarments days.\n" if $verbose;
 298     $count = PurgeDebarments($pDebarments);
 299     print "$count restrictions were deleted.\nDone with restrictions purge.\n" if $verbose;
 300 }
 301
 302 if($allDebarments) {
 303     print "All expired patrons restrictions purge triggered.\n" if $verbose;
 304     $count = PurgeDebarments(0);
 305     print "$count restrictions were deleted.\nDone with all restrictions purge.\n" if $verbose;
 306 }
 307
 308 if( $pExpSelfReg ) {
 309     DeleteExpiredSelfRegs();
 310 }
 311 if( $pUnvSelfReg ) {
 312     DeleteUnverifiedSelfRegs( $pUnvSelfReg );
 313 }
 314
 315 if ($special_holidays_days) {
 316     DeleteSpecialHolidays( abs($special_holidays_days) );
 317 }
 318
 319 if( $temp_uploads ) {
 320     # Delete temporary uploads, governed by a pref (unless you override)
 321     print "Purging temporary uploads.\n" if $verbose;
 322     Koha::UploadedFiles->delete_temporary({
 323         defined($temp_uploads_days)
 324             ? ( override_pref => $temp_uploads_days )
 325             : ()
 326     });
 327     print "Done purging temporary uploads.\n" if $verbose;
 328 }
 329
 330 if( defined $uploads_missing ) {
 331     print "Looking for missing uploads\n" if $verbose;
 332     my $keep = $uploads_missing == 1 ? 0 : 1;
 333     my $count = Koha::UploadedFiles->delete_missing({ keep_record => $keep });
 334     if( $keep ) {
 335         print "Counted $count missing uploaded files\n";
 336     } else {
 337         print "Removed $count records for missing uploads\n";
 338     }
 339 }
 340
 341 if ($oauth_tokens) {
 342     require Koha::OAuthAccessTokens;
 343
 344     my $count = int Koha::OAuthAccessTokens->search({ expires => { '<=', time } })->delete;
 345     say "Removed $count expired OAuth2 tokens" if $verbose;
 346 }
 347
 348 exit(0);
 349
 350 sub RemoveOldSessions {
 351     my ( $id, $a_session, $limit, $lasttime );
 352     $limit = time() - 24 * 3600 * $sess_days;
 353
 354     $sth = $dbh->prepare(q{ SELECT id, a_session FROM sessions });
 355     $sth->execute or die $dbh->errstr;
 356     $sth->bind_columns( \$id, \$a_session );
 357     $sth2  = $dbh->prepare(q{ DELETE FROM sessions WHERE id=? });
 358     $count = 0;
 359
 360     while ( $sth->fetch ) {
 361         $lasttime = 0;
 362         if ( $a_session =~ /lasttime:\s+'?(\d+)/ ) {
 363             $lasttime = $1;
 364         }
 365         elsif ( $a_session =~ /(ATIME|CTIME):\s+'?(\d+)/ ) {
 366             $lasttime = $2;
 367         }
 368         if ( $lasttime && $lasttime < $limit ) {
 369             $sth2->execute($id) or die $dbh->errstr;
 370             $count++;
 371         }
 372     }
 373     if ($verbose) {
 374         print "$count sessions were deleted.\n";
 375     }
 376 }
 377
 378 sub PurgeImportTables {
 379
 380     #First purge import_records
 381     #Delete cascades to import_biblios, import_items and import_record_matches
 382     $sth = $dbh->prepare(
 383         q{
 384             DELETE FROM import_records
 385             WHERE upload_timestamp < date_sub(curdate(), INTERVAL ? DAY)
 386         }
 387     );
 388     $sth->execute($pImport) or die $dbh->errstr;
 389
 390     # Now purge import_batches
 391     # Timestamp cannot be used here without care, because records are added
 392     # continuously to batches without updating timestamp (Z39.50 search).
 393     # So we only delete older empty batches.
 394     # This delete will therefore not have a cascading effect.
 395     $sth = $dbh->prepare(
 396         q{
 397             DELETE ba
 398             FROM import_batches ba
 399             LEFT JOIN import_records re ON re.import_batch_id=ba.import_batch_id
 400             WHERE re.import_record_id IS NULL AND
 401             ba.upload_timestamp < date_sub(curdate(), INTERVAL ? DAY)
 402         }
 403     );
 404     $sth->execute($pImport) or die $dbh->errstr;
 405 }
 406
 407 sub PurgeZ3950 {
 408     $sth = $dbh->prepare(
 409         q{
 410             DELETE FROM import_batches
 411             WHERE batch_type = 'z3950'
 412         }
 413     );
 414     $sth->execute() or die $dbh->errstr;
 415 }
 416
 417 sub PurgeDebarments {
 418     require Koha::Patron::Debarments;
 419     my $days = shift;
 420     $count = 0;
 421     $sth   = $dbh->prepare(
 422         q{
 423             SELECT borrower_debarment_id
 424             FROM borrower_debarments
 425             WHERE expiration < date_sub(curdate(), INTERVAL ? DAY)
 426         }
 427     );
 428     $sth->execute($days) or die $dbh->errstr;
 429     while ( my ($borrower_debarment_id) = $sth->fetchrow_array ) {
 430         Koha::Patron::Debarments::DelDebarment($borrower_debarment_id);
 431         $count++;
 432     }
 433     return $count;
 434 }
 435
 436 sub DeleteExpiredSelfRegs {
 437     my $cnt= C4::Members::DeleteExpiredOpacRegistrations();
 438     print "Removed $cnt expired self-registered borrowers\n" if $verbose;
 439 }
 440
 441 sub DeleteUnverifiedSelfRegs {
 442     my $cnt= C4::Members::DeleteUnverifiedOpacRegistrations( $_[0] );
 443     print "Removed $cnt unverified self-registrations\n" if $verbose;
 444 }
 445
 446 sub DeleteSpecialHolidays {
 447     my ( $days ) = @_;
 448
 449     my $sth = $dbh->prepare(q{
 450         DELETE FROM special_holidays
 451         WHERE DATE( CONCAT( year, '-', month, '-', day ) ) < DATE_SUB( CAST(NOW() AS DATE), INTERVAL ? DAY );
 452     });
 453     my $count = $sth->execute( $days ) + 0;
 454     print "Removed $count unique holidays\n" if $verbose;
 455 }