misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43 use C4::Budgets qw(GetCurrency);
  44
  45 =head1 NAME
  46
  47 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  48
  49 =head1 SYNOPSIS
  50
  51 overdue_notices.pl
  52   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  53   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  54   [ -email <email_type> ... ]
  55
  56  Options:
  57    -help                          brief help message
  58    -man                           full documentation
  59    -n                             No email will be sent
  60    -max          <days>           maximum days overdue to deal with
  61    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  62    -csv          <filename>       populate CSV file
  63    -html         <directory>      Output html to a file in the given directory
  64    -itemscontent <list of fields> item information in templates
  65    -borcat       <categorycode>   category code that must be included
  66    -borcatout    <categorycode>   category code that must be excluded
  67    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  68
  69 =head1 OPTIONS
  70
  71 =over 8
  72
  73 =item B<-help>
  74
  75 Print a brief help message and exits.
  76
  77 =item B<-man>
  78
  79 Prints the manual page and exits.
  80
  81 =item B<-v>
  82
  83 Verbose. Without this flag set, only fatal errors are reported.
  84
  85 =item B<-n>
  86
  87 Do not send any email. Overdue notices that would have been sent to
  88 the patrons or to the admin are printed to standard out. CSV data (if
  89 the -csv flag is set) is written to standard out or to any csv
  90 filename given.
  91
  92 =item B<-max>
  93
  94 Items older than max days are assumed to be handled somewhere else,
  95 probably the F<longoverdues.pl> script. They are therefore ignored by
  96 this program. No notices are sent for them, and they are not added to
  97 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  98
  99 =item B<-library>
 100
 101 select overdues for one specific library. Use the value in the
 102 branches.branchcode table. This option can be repeated in order
 103 to select overdues for a group of libraries.
 104
 105 =item B<-csv>
 106
 107 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 108 sent to standard out or to a filename if provided. Otherwise, only
 109 overdues that could not be emailed are sent in CSV format to the admin.
 110
 111 =item B<-html>
 112
 113 Produces html data. if patron does not have a mail address or
 114 -n (no mail) flag is set, an html file is generated in the specified
 115 directory. This can be downloaded or futher processed by library staff.
 116 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 117 specified.
 118
 119 =item B<-itemscontent>
 120
 121 comma separated list of fields that get substituted into templates in
 122 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 123 defaults to due date,title,barcode,author
 124
 125 Other possible values come from fields in the biblios, items and
 126 issues tables.
 127
 128 =item B<-borcat>
 129
 130 Repetable field, that permit to select only few of patrons categories.
 131
 132 =item B<-borcatout>
 133
 134 Repetable field, permis to exclude some patrons categories.
 135
 136 =item B<-t> | B<--triggered>
 137
 138 This option causes a notice to be generated if and only if
 139 an item is overdue by the number of days defined in a notice trigger.
 140
 141 By default, a notice is sent each time the script runs, which is suitable for
 142 less frequent run cron script, but requires syncing notice triggers with
 143 the  cron schedule to ensure proper behavior.
 144 Add the --triggered option for daily cron, at the risk of no notice
 145 being generated if the cron fails to run on time.
 146
 147 =item B<-list-all>
 148
 149 Default items.content lists only those items that fall in the
 150 range of the currently processing notice.
 151 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 152
 153 =item B<-date>
 154
 155 use it in order to send overdues on a specific date and not Now.
 156
 157 =item B<-email>
 158
 159 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 160
 161 =back
 162
 163 =head1 DESCRIPTION
 164
 165 This script is designed to alert patrons and administrators of overdue
 166 items.
 167
 168 =head2 Configuration
 169
 170 This script pays attention to the overdue notice configuration
 171 performed in the "Overdue notice/status triggers" section of the
 172 "Tools" area of the staff interface to Koha. There, you can choose
 173 which letter templates are sent out after a configurable number of
 174 days to patrons of each library. More information about the use of this
 175 section of Koha is available in the Koha manual.
 176
 177 The templates used to craft the emails are defined in the "Tools:
 178 Notices" section of the staff interface to Koha.
 179
 180 =head2 Outgoing emails
 181
 182 Typically, messages are prepared for each patron with overdue
 183 items. Messages for whom there is no email address on file are
 184 collected and sent as attachments in a single email to each library
 185 administrator, or if that is not set, then to the email address in the
 186 C<KohaAdminEmailAddress> system preference.
 187
 188 These emails are staged in the outgoing message queue, as are messages
 189 produced by other features of Koha. This message queue must be
 190 processed regularly by the
 191 F<misc/cronjobs/process_message_queue.pl> program.
 192
 193 In the event that the C<-n> flag is passed to this program, no emails
 194 are sent. Instead, messages are sent on standard output from this
 195 program. They may be redirected to a file if desired.
 196
 197 =head2 Templates
 198
 199 Templates can contain variables enclosed in double angle brackets like
 200 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 201 specific to the overdue items or relevant patron. Available variables
 202 are:
 203
 204 =over
 205
 206 =item E<lt>E<lt>bibE<gt>E<gt>
 207
 208 the name of the library
 209
 210 =item E<lt>E<lt>items.contentE<gt>E<gt>
 211
 212 one line for each item, each line containing a tab separated list of
 213 title, author, barcode, issuedate
 214
 215 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 216
 217 any field from the borrowers table
 218
 219 =item E<lt>E<lt>branches.*E<gt>E<gt>
 220
 221 any field from the branches table
 222
 223 =back
 224
 225 =head2 CSV output
 226
 227 The C<-csv> command line option lets you specify a file to which
 228 overdues data should be output in CSV format.
 229
 230 With the C<-n> flag set, data about all overdues is written to the
 231 file. Without that flag, only information about overdues that were
 232 unable to be sent directly to the patrons will be written. In other
 233 words, this CSV file replaces the data that is typically sent to the
 234 administrator email address.
 235
 236 =head1 USAGE EXAMPLES
 237
 238 C<overdue_notices.pl> - In this most basic usage, with no command line
 239 arguments, all libraries are procesed individually, and notices are
 240 prepared for all patrons with overdue items for whom we have email
 241 addresses. Messages for those patrons for whom we have no email
 242 address are sent in a single attachment to the library administrator's
 243 email address, or to the address in the KohaAdminEmailAddress system
 244 preference.
 245
 246 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 247 populates F</tmp/overdues.csv> with information about all overdue
 248 items.
 249
 250 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 251 overdues in the last 2 weeks for the MAIN library.
 252
 253 =head1 SEE ALSO
 254
 255 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 256 messages to patrons in advance of thier items becoming due, or to
 257 alert them of items that have just become due.
 258
 259 =cut
 260
 261 # These variables are set by command line options.
 262 # They are initially set to default values.
 263 my $dbh = C4::Context->dbh();
 264 my $help    = 0;
 265 my $man     = 0;
 266 my $verbose = 0;
 267 my $nomail  = 0;
 268 my $MAX     = 90;
 269 my @branchcodes; # Branch(es) passed as parameter
 270 my @emails_to_use;    # Emails to use for messaging
 271 my @emails;           # Emails given in command-line parameters
 272 my $csvfilename;
 273 my $htmlfilename;
 274 my $triggered = 0;
 275 my $listall = 0;
 276 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 277 my @myborcat;
 278 my @myborcatout;
 279 my $date;
 280
 281 GetOptions(
 282     'help|?'         => \$help,
 283     'man'            => \$man,
 284     'v'              => \$verbose,
 285     'n'              => \$nomail,
 286     'max=s'          => \$MAX,
 287     'library=s'      => \@branchcodes,
 288     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 289     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 290     'itemscontent=s' => \$itemscontent,
 291     'list-all'       => \$listall,
 292     't|triggered'    => \$triggered,
 293     'date'           => \$date,
 294     'borcat=s'       => \@myborcat,
 295     'borcatout=s'    => \@myborcatout,
 296     'email=s'        => \@emails,
 297 ) or pod2usage(2);
 298 pod2usage(1) if $help;
 299 pod2usage( -verbose => 2 ) if $man;
 300
 301 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 302     warn qq(using "$csvfilename" as filename, that seems odd);
 303 }
 304
 305 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 306 my @branches;                                                                   # Branches passed as parameter with overdue rules
 307 my $branchcount = scalar(@overduebranches);
 308
 309 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 310 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 311
 312 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 313
 314 if ($branchcount) {
 315     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 316 } else {
 317     die 'No branches with active overduerules';
 318 }
 319
 320 if (@branchcodes) {
 321     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 322
 323     # Getting libraries which have overdue rules
 324     my %seen = map { $_ => 1 } @branchcodes;
 325     @branches = grep { $seen{$_} } @overduebranches;
 326
 327
 328     if (@branches) {
 329
 330         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 331         $verbose and warn "$branch_word @branches have overdue rules\n";
 332
 333     } else {
 334
 335         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 336         ( scalar grep { '' eq $_ } @branches )
 337           or die "No active overduerules for DEFAULT either!";
 338         $verbose and warn "Falling back on default rules for @branchcodes\n";
 339         @branches = ('');
 340     }
 341 }
 342
 343 if ($date){
 344     $date=$dbh->quote($date);
 345 }
 346 else {
 347     $date="NOW()";
 348 }
 349
 350 # these are the fields that will be substituted into <<item.content>>
 351 my @item_content_fields = split( /,/, $itemscontent );
 352
 353 binmode( STDOUT, ':encoding(UTF-8)' );
 354
 355
 356 our $csv;       # the Text::CSV_XS object
 357 our $csv_fh;    # the filehandle to the CSV file.
 358 if ( defined $csvfilename ) {
 359     my $sep_char = C4::Context->preference('delimiter') || ',';
 360     $sep_char = "\t" if ($sep_char eq 'tabulation');
 361     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 362     if ( $csvfilename eq '' ) {
 363         $csv_fh = *STDOUT;
 364     } else {
 365         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 366     }
 367     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 368         print $csv_fh $csv->string, "\n";
 369     } else {
 370         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 371     }
 372 }
 373
 374 @branches = @overduebranches unless @branches;
 375 our $html_fh;
 376 if ( defined $htmlfilename ) {
 377   if ( $htmlfilename eq '' ) {
 378     $html_fh = *STDOUT;
 379   } else {
 380     my $today = DateTime->now(time_zone => C4::Context->tz );
 381     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 382   }
 383
 384   print $html_fh "<html>\n";
 385   print $html_fh "<head>\n";
 386   print $html_fh "<style type='text/css'>\n";
 387   print $html_fh "pre {page-break-after: always;}\n";
 388   print $html_fh "pre {white-space: pre-wrap;}\n";
 389   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 390   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 391   print $html_fh "pre {word-wrap: break-work;}\n";
 392   print $html_fh "</style>\n";
 393   print $html_fh "</head>\n";
 394   print $html_fh "<body>\n";
 395 }
 396
 397 foreach my $branchcode (@branches) {
 398
 399     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 400     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 401     my @output_chunks;    # may be sent to mail or stdout or csv file.
 402
 403     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 404
 405     my $sth2 = $dbh->prepare( <<"END_SQL" );
 406 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 407   FROM issues,items,biblio, biblioitems
 408   WHERE items.itemnumber=issues.itemnumber
 409     AND biblio.biblionumber   = items.biblionumber
 410     AND biblio.biblionumber   = biblioitems.biblionumber
 411     AND issues.borrowernumber = ?
 412     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 413 END_SQL
 414
 415     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 416     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 417     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 418
 419     my $rqoverduerules =  $dbh->prepare($query);
 420     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 421
 422     # We get default rules is there is no rule for this branch
 423     if($rqoverduerules->rows == 0){
 424         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 425         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 426         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 427
 428         $rqoverduerules = $dbh->prepare($query);
 429         $rqoverduerules->execute(@myborcat, @myborcatout);
 430     }
 431
 432     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 433     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 434       PERIOD: foreach my $i ( 1 .. 3 ) {
 435
 436             $verbose and warn "branch '$branchcode', pass $i\n";
 437             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 438             my $maxdays = (
 439                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 440                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 441                 : ($MAX)
 442             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 443
 444             if ( !$overdue_rules->{"letter$i"} ) {
 445                 $verbose and warn "No letter$i code for branch '$branchcode'";
 446                 next PERIOD;
 447             }
 448
 449             # $letter->{'content'} is the text of the mail that is sent.
 450             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 451             # The following fields are available :
 452             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 453             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 454
 455             my $borrower_sql = <<'END_SQL';
 456 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email
 457 FROM   issues,borrowers,categories
 458 WHERE  issues.borrowernumber=borrowers.borrowernumber
 459 AND    borrowers.categorycode=categories.categorycode
 460 END_SQL
 461             my @borrower_parameters;
 462             if ($branchcode) {
 463                 $borrower_sql .= ' AND issues.branchcode=? ';
 464                 push @borrower_parameters, $branchcode;
 465             }
 466             if ( $overdue_rules->{categorycode} ) {
 467                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 468                 push @borrower_parameters, $overdue_rules->{categorycode};
 469             }
 470             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 471             if($triggered) {
 472                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 473                 push @borrower_parameters, $mindays;
 474             } else {
 475                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 476                 push @borrower_parameters, $mindays, $maxdays;
 477             }
 478
 479             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 480                 my $sth = $dbh->prepare($borrower_sql);
 481             $sth->execute(@borrower_parameters);
 482             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 483
 484             while ( my $data = $sth->fetchrow_hashref ) {
 485                 my $borrowernumber = $data->{'borrowernumber'};
 486                 my $borr =
 487                     $data->{'firstname'} . ', '
 488                   . $data->{'surname'} . ' ('
 489                   . $borrowernumber . ')';
 490                 $verbose
 491                   and warn "borrower $borr has items triggering level $i.";
 492
 493                 @emails_to_use = ();
 494                 my $notice_email =
 495                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 496                 unless ($nomail) {
 497                     if (@emails) {
 498                         foreach (@emails) {
 499                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 500                         }
 501                     }
 502                     else {
 503                         push @emails_to_use, $notice_email if ($notice_email);
 504                     }
 505                 }
 506
 507                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 508
 509                 unless ($letter) {
 510                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 511
 512                     # might as well skip while PERIOD, no other borrowers are going to work.
 513                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 514                     next PERIOD;
 515                 }
 516
 517                 if ( $overdue_rules->{"debarred$i"} ) {
 518
 519                     #action taken is debarring
 520                     C4::Members::DebarMember($borrowernumber, '9999-12-31');
 521                     $verbose and warn "debarring $borr\n";
 522                 }
 523                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 524                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 525                 $sth2->execute(@params);
 526                 my $itemcount = 0;
 527                 my $titles = "";
 528                 my @items = ();
 529
 530                 my $j = 0;
 531                 my $exceededPrintNoticesMaxLines = 0;
 532                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 533                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 534                       $exceededPrintNoticesMaxLines = 1;
 535                       last;
 536                     }
 537                     $j++;
 538                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 539                     $titles .= join("\t", @item_info) . "\n";
 540                     $itemcount++;
 541                     push @items, $item_info;
 542                 }
 543                 $sth2->finish;
 544
 545                 $letter = parse_letter(
 546                     {   letter_code     => $overdue_rules->{"letter$i"},
 547                         borrowernumber  => $borrowernumber,
 548                         branchcode      => $branchcode,
 549                         items           => \@items,
 550                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 551                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 552                                             'items.content' => $titles,
 553                                             'count'         => $itemcount,
 554                                            }
 555                     }
 556                 );
 557                 unless ($letter) {
 558                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 559
 560                     # might as well skip while PERIOD, no other borrowers are going to work.
 561                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 562                     next PERIOD;
 563                 }
 564
 565                 if ( $exceededPrintNoticesMaxLines ) {
 566                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 567                 }
 568
 569                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 570                 if (@misses) {
 571                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 572                 }
 573                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 574                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 575
 576                 if ( !$nomail && scalar @emails_to_use ) {
 577                     C4::Letters::EnqueueLetter(
 578                         {   letter                 => $letter,
 579                             borrowernumber         => $borrowernumber,
 580                             message_transport_type => 'email',
 581                             from_address           => $admin_email_address,
 582                             to_address             => join(',', @emails_to_use),
 583                         }
 584                     );
 585                 } else {
 586                     # if not sent by email then print
 587                     push @output_chunks,
 588                       prepare_letter_for_printing(
 589                         {   letter         => $letter,
 590                             borrowernumber => $borrowernumber,
 591                             firstname      => $data->{'firstname'},
 592                             lastname       => $data->{'surname'},
 593                             address1       => $data->{'address'},
 594                             address2       => $data->{'address2'},
 595                             city           => $data->{'city'},
 596                             postcode       => $data->{'zipcode'},
 597                             country        => $data->{'country'},
 598                             email          => $notice_email,
 599                             itemcount      => $itemcount,
 600                             titles         => $titles,
 601                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 602                         }
 603                       );
 604                 }
 605             }
 606             $sth->finish;
 607         }
 608     }
 609
 610     if (@output_chunks) {
 611         if ( defined $csvfilename ) {
 612             print $csv_fh @output_chunks;
 613         }
 614         elsif ( defined $htmlfilename ) {
 615             print $html_fh @output_chunks;
 616         }
 617         elsif ($nomail){
 618                 local $, = "\f";    # pagebreak
 619                 print @output_chunks;
 620         }
 621         # Generate the content of the csv with headers
 622         my $content = join(";", qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 623         $content .= join( "\n", @output_chunks );
 624
 625         my $attachment = {
 626             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 627             type => 'text/plain',
 628             content => $content,
 629         };
 630
 631         my $letter = {
 632             title   => 'Overdue Notices',
 633             content => 'These messages were not sent directly to the patrons.',
 634         };
 635         C4::Letters::EnqueueLetter(
 636             {   letter                 => $letter,
 637                 borrowernumber         => undef,
 638                 message_transport_type => 'email',
 639                 attachments            => [$attachment],
 640                 to_address             => $admin_email_address,
 641             }
 642         );
 643     }
 644
 645 }
 646 if ($csvfilename) {
 647     # note that we're not testing on $csv_fh to prevent closing
 648     # STDOUT.
 649     close $csv_fh;
 650 }
 651
 652 if ( defined $htmlfilename ) {
 653   print $html_fh "</body>\n";
 654   print $html_fh "</html>\n";
 655   close $html_fh;
 656 }
 657
 658 =head1 INTERNAL METHODS
 659
 660 These methods are internal to the operation of overdue_notices.pl.
 661
 662 =head2 parse_letter
 663
 664 parses the letter template, replacing the placeholders with data
 665 specific to this patron, biblio, or item
 666
 667 named parameters:
 668   letter - required hashref
 669   borrowernumber - required integer
 670   substitute - optional hashref of other key/value pairs that should
 671     be substituted in the letter content
 672
 673 returns the C<letter> hashref, with the content updated to reflect the
 674 substituted keys and values.
 675
 676
 677 =cut
 678
 679 sub parse_letter {
 680     my $params = shift;
 681     foreach my $required (qw( letter_code borrowernumber )) {
 682         return unless ( exists $params->{$required} && $params->{$required} );
 683     }
 684
 685     my $substitute = $params->{'substitute'} || {};
 686     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 687
 688     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 689     if ( my $p = $params->{'branchcode'} ) {
 690         $tables{'branches'} = $p;
 691     }
 692
 693     my $currencies = GetCurrency();
 694     my $currency_format;
 695     $currency_format = $currencies->{currency} if defined($currencies);
 696
 697     my @item_tables;
 698     if ( my $i = $params->{'items'} ) {
 699         my $item_format = '';
 700         foreach my $item (@$i) {
 701             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 702             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 703                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 704                 $item_format = $1;
 705             }
 706
 707             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 708             # if active currency isn't correct ISO code fallback to sprintf
 709             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 710
 711             push @item_tables, {
 712                 'biblio' => $item->{'biblionumber'},
 713                 'biblioitems' => $item->{'biblionumber'},
 714                 'items' => $item,
 715                 'issues' => $item->{'itemnumber'},
 716             };
 717         }
 718     }
 719
 720     return C4::Letters::GetPreparedLetter (
 721         module => 'circulation',
 722         letter_code => $params->{'letter_code'},
 723         branchcode => $params->{'branchcode'},
 724         tables => \%tables,
 725         substitute => $substitute,
 726         repeat => { item => \@item_tables },
 727     );
 728 }
 729
 730 =head2 prepare_letter_for_printing
 731
 732 returns a string of text appropriate for printing in the event that an
 733 overdue notice will not be sent to the patron's email
 734 address. Depending on the desired output format, this may be a CSV
 735 string, or a human-readable representation of the notice.
 736
 737 required parameters:
 738   letter
 739   borrowernumber
 740
 741 optional parameters:
 742   outputformat
 743
 744 =cut
 745
 746 sub prepare_letter_for_printing {
 747     my $params = shift;
 748
 749     return unless ref $params eq 'HASH';
 750
 751     foreach my $required_parameter (qw( letter borrowernumber )) {
 752         return unless defined $params->{$required_parameter};
 753     }
 754
 755     my $return;
 756     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 757         if ($csv->combine(
 758                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 759                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 760             )
 761           ) {
 762             return $csv->string, "\n";
 763         } else {
 764             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 765         }
 766     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 767       $return = "<pre>\n";
 768       my $content = $params->{'letter'}->{'content'};
 769       $content =~ s/\n/<br \/>/g;
 770       $content =~ s/\r//g;
 771       $return .= "$content\n";
 772       $return .= "\n</pre>\n";
 773     } else {
 774         $return .= "$params->{'letter'}->{'content'}\n";
 775
 776         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 777     }
 778     return $return;
 779 }
 780