misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Text::CSV_XS;
  34 use DateTime;
  35 use DateTime::Duration;
  36
  37 use Koha::Script -cron;
  38 use C4::Context;
  39 use C4::Letters;
  40 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes parse_overdues_letter);
  41 use C4::Log;
  42 use Koha::Patron::Debarments qw(AddUniqueDebarment);
  43 use Koha::DateUtils;
  44 use Koha::Calendar;
  45 use Koha::Libraries;
  46 use Koha::Acquisition::Currencies;
  47 use Koha::Patrons;
  48
  49 =head1 NAME
  50
  51 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  52
  53 =head1 SYNOPSIS
  54
  55 overdue_notices.pl
  56   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  57   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  58   [ -email <email_type> ... ]
  59
  60  Options:
  61    -help                          brief help message
  62    -man                           full documentation
  63    -v                             verbose
  64    -n                             No email will be sent
  65    -max          <days>           maximum days overdue to deal with
  66    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  67    -csv          <filename>       populate CSV file
  68    -html         <directory>      Output html to a file in the given directory
  69    -text         <directory>      Output plain text to a file in the given directory
  70    -itemscontent <list of fields> item information in templates
  71    -borcat       <categorycode>   category code that must be included
  72    -borcatout    <categorycode>   category code that must be excluded
  73    -t                             only include triggered overdues
  74    --test                         Run in test mode. No changes will be made on the DB.
  75    -list-all                      list all overdues
  76    -date         <yyyy-mm-dd>     emulate overdues run for this date
  77    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  78
  79 =head1 OPTIONS
  80
  81 =over 8
  82
  83 =item B<-help>
  84
  85 Print a brief help message and exits.
  86
  87 =item B<-man>
  88
  89 Prints the manual page and exits.
  90
  91 =item B<-v>
  92
  93 Verbose. Without this flag set, only fatal errors are reported.
  94
  95 =item B<-n>
  96
  97 Do not send any email. Overdue notices that would have been sent to
  98 the patrons or to the admin are printed to standard out. CSV data (if
  99 the -csv flag is set) is written to standard out or to any csv
 100 filename given.
 101
 102 =item B<-max>
 103
 104 Items older than max days are assumed to be handled somewhere else,
 105 probably the F<longoverdues.pl> script. They are therefore ignored by
 106 this program. No notices are sent for them, and they are not added to
 107 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 108
 109 =item B<-library>
 110
 111 select overdues for one specific library. Use the value in the
 112 branches.branchcode table. This option can be repeated in order
 113 to select overdues for a group of libraries.
 114
 115 =item B<-csv>
 116
 117 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 118 sent to standard out or to a filename if provided. Otherwise, only
 119 overdues that could not be emailed are sent in CSV format to the admin.
 120
 121 =item B<-html>
 122
 123 Produces html data. If patron does not have an email address or
 124 -n (no mail) flag is set, an HTML file is generated in the specified
 125 directory. This can be downloaded or further processed by library staff.
 126 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 127 specified.
 128
 129 =item B<-text>
 130
 131 Produces plain text data. If patron does not have an email address or
 132 -n (no mail) flag is set, a text file is generated in the specified
 133 directory. This can be downloaded or further processed by library staff.
 134 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 135 specified.
 136
 137 =item B<-itemscontent>
 138
 139 comma separated list of fields that get substituted into templates in
 140 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 141 defaults to due date,title,barcode,author
 142
 143 Other possible values come from fields in the biblios, items and
 144 issues tables.
 145
 146 =item B<-borcat>
 147
 148 Repeatable field, that permits to select only some patron categories.
 149
 150 =item B<-borcatout>
 151
 152 Repeatable field, that permits to exclude some patron categories.
 153
 154 =item B<-t> | B<--triggered>
 155
 156 This option causes a notice to be generated if and only if
 157 an item is overdue by the number of days defined in a notice trigger.
 158
 159 By default, a notice is sent each time the script runs, which is suitable for
 160 less frequent run cron script, but requires syncing notice triggers with
 161 the  cron schedule to ensure proper behavior.
 162 Add the --triggered option for daily cron, at the risk of no notice
 163 being generated if the cron fails to run on time.
 164
 165 =item B<-test>
 166
 167 This option makes the script run in test mode.
 168
 169 In test mode, the script won't make any changes on the DB. This is useful
 170 for debugging configuration.
 171
 172 =item B<-list-all>
 173
 174 Default items.content lists only those items that fall in the
 175 range of the currently processing notice.
 176 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 177
 178 =item B<-date>
 179
 180 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 181
 182 =item B<-email>
 183
 184 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 185
 186 =back
 187
 188 =head1 DESCRIPTION
 189
 190 This script is designed to alert patrons and administrators of overdue
 191 items.
 192
 193 =head2 Configuration
 194
 195 This script pays attention to the overdue notice configuration
 196 performed in the "Overdue notice/status triggers" section of the
 197 "Tools" area of the staff interface to Koha. There, you can choose
 198 which letter templates are sent out after a configurable number of
 199 days to patrons of each library. More information about the use of this
 200 section of Koha is available in the Koha manual.
 201
 202 The templates used to craft the emails are defined in the "Tools:
 203 Notices" section of the staff interface to Koha.
 204
 205 =head2 Outgoing emails
 206
 207 Typically, messages are prepared for each patron with overdue
 208 items. Messages for whom there is no email address on file are
 209 collected and sent as attachments in a single email to each library
 210 administrator, or if that is not set, then to the email address in the
 211 C<KohaAdminEmailAddress> system preference.
 212
 213 These emails are staged in the outgoing message queue, as are messages
 214 produced by other features of Koha. This message queue must be
 215 processed regularly by the
 216 F<misc/cronjobs/process_message_queue.pl> program.
 217
 218 In the event that the C<-n> flag is passed to this program, no emails
 219 are sent. Instead, messages are sent on standard output from this
 220 program. They may be redirected to a file if desired.
 221
 222 =head2 Templates
 223
 224 Templates can contain variables enclosed in double angle brackets like
 225 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 226 specific to the overdue items or relevant patron. Available variables
 227 are:
 228
 229 =over
 230
 231 =item E<lt>E<lt>bibE<gt>E<gt>
 232
 233 the name of the library
 234
 235 =item E<lt>E<lt>items.contentE<gt>E<gt>
 236
 237 one line for each item, each line containing a tab separated list of
 238 title, author, barcode, issuedate
 239
 240 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 241
 242 any field from the borrowers table
 243
 244 =item E<lt>E<lt>branches.*E<gt>E<gt>
 245
 246 any field from the branches table
 247
 248 =back
 249
 250 =head2 CSV output
 251
 252 The C<-csv> command line option lets you specify a file to which
 253 overdues data should be output in CSV format.
 254
 255 With the C<-n> flag set, data about all overdues is written to the
 256 file. Without that flag, only information about overdues that were
 257 unable to be sent directly to the patrons will be written. In other
 258 words, this CSV file replaces the data that is typically sent to the
 259 administrator email address.
 260
 261 =head1 USAGE EXAMPLES
 262
 263 C<overdue_notices.pl> - In this most basic usage, with no command line
 264 arguments, all libraries are processed individually, and notices are
 265 prepared for all patrons with overdue items for whom we have email
 266 addresses. Messages for those patrons for whom we have no email
 267 address are sent in a single attachment to the library administrator's
 268 email address, or to the address in the KohaAdminEmailAddress system
 269 preference.
 270
 271 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 272 populates F</tmp/overdues.csv> with information about all overdue
 273 items.
 274
 275 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 276 overdues in the last 2 weeks for the MAIN library.
 277
 278 =head1 SEE ALSO
 279
 280 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 281 messages to patrons in advance of their items becoming due, or to
 282 alert them of items that have just become due.
 283
 284 =cut
 285
 286 # These variables are set by command line options.
 287 # They are initially set to default values.
 288 my $dbh = C4::Context->dbh();
 289 my $help    = 0;
 290 my $man     = 0;
 291 my $verbose = 0;
 292 my $nomail  = 0;
 293 my $MAX     = 90;
 294 my $test_mode = 0;
 295 my @branchcodes; # Branch(es) passed as parameter
 296 my @emails_to_use;    # Emails to use for messaging
 297 my @emails;           # Emails given in command-line parameters
 298 my $csvfilename;
 299 my $htmlfilename;
 300 my $text_filename;
 301 my $triggered = 0;
 302 my $listall = 0;
 303 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 304 my @myborcat;
 305 my @myborcatout;
 306 my ( $date_input, $today );
 307
 308 GetOptions(
 309     'help|?'         => \$help,
 310     'man'            => \$man,
 311     'v'              => \$verbose,
 312     'n'              => \$nomail,
 313     'max=s'          => \$MAX,
 314     'library=s'      => \@branchcodes,
 315     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 316     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 317     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 318     'itemscontent=s' => \$itemscontent,
 319     'list-all'       => \$listall,
 320     't|triggered'    => \$triggered,
 321     'test'           => \$test_mode,
 322     'date=s'         => \$date_input,
 323     'borcat=s'       => \@myborcat,
 324     'borcatout=s'    => \@myborcatout,
 325     'email=s'        => \@emails,
 326 ) or pod2usage(2);
 327 pod2usage(1) if $help;
 328 pod2usage( -verbose => 2 ) if $man;
 329 cronlogaction() unless $test_mode;
 330
 331 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 332     warn qq(using "$csvfilename" as filename, that seems odd);
 333 }
 334
 335 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 336 my @branches;                                                                   # Branches passed as parameter with overdue rules
 337 my $branchcount = scalar(@overduebranches);
 338
 339 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 340 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 341
 342 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 343
 344 if ($branchcount) {
 345     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 346 } else {
 347     die 'No branches with active overduerules';
 348 }
 349
 350 if (@branchcodes) {
 351     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 352
 353     # Getting libraries which have overdue rules
 354     my %seen = map { $_ => 1 } @branchcodes;
 355     @branches = grep { $seen{$_} } @overduebranches;
 356
 357
 358     if (@branches) {
 359
 360         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 361         $verbose and warn "$branch_word @branches have overdue rules\n";
 362
 363     } else {
 364
 365         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 366         ( scalar grep { '' eq $_ } @branches )
 367           or die "No active overduerules for DEFAULT either!";
 368         $verbose and warn "Falling back on default rules for @branchcodes\n";
 369         @branches = ('');
 370     }
 371 }
 372 my $date_to_run;
 373 my $date;
 374 if ( $date_input ){
 375     eval {
 376         $date_to_run = dt_from_string( $date_input, 'iso' );
 377     };
 378     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 379         if $@ or not $date_to_run;
 380
 381     # It's certainly useless to escape $date_input
 382     # dt_from_string should not return something if $date_input is not correctly set.
 383     $date = $dbh->quote( $date_input );
 384 }
 385 else {
 386     $date="NOW()";
 387     $date_to_run = dt_from_string();
 388 }
 389
 390 # these are the fields that will be substituted into <<item.content>>
 391 my @item_content_fields = split( /,/, $itemscontent );
 392
 393 binmode( STDOUT, ':encoding(UTF-8)' );
 394
 395
 396 our $csv;       # the Text::CSV_XS object
 397 our $csv_fh;    # the filehandle to the CSV file.
 398 if ( defined $csvfilename ) {
 399     my $sep_char = C4::Context->preference('delimiter') || ';';
 400     $sep_char = "\t" if ($sep_char eq 'tabulation');
 401     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 402     if ( $csvfilename eq '' ) {
 403         $csv_fh = *STDOUT;
 404     } else {
 405         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 406     }
 407     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 408         print $csv_fh $csv->string, "\n";
 409     } else {
 410         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 411     }
 412 }
 413
 414 @branches = @overduebranches unless @branches;
 415 our $fh;
 416 if ( defined $htmlfilename ) {
 417   if ( $htmlfilename eq '' ) {
 418     $fh = *STDOUT;
 419   } else {
 420     my $today = DateTime->now(time_zone => C4::Context->tz );
 421     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 422   }
 423
 424   print $fh "<html>\n";
 425   print $fh "<head>\n";
 426   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 427   print $fh "<style type='text/css'>\n";
 428   print $fh "pre {page-break-after: always;}\n";
 429   print $fh "pre {white-space: pre-wrap;}\n";
 430   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 431   print $fh "pre {white-space: -o-pre-wrap;}\n";
 432   print $fh "pre {word-wrap: break-work;}\n";
 433   print $fh "</style>\n";
 434   print $fh "</head>\n";
 435   print $fh "<body>\n";
 436 }
 437 elsif ( defined $text_filename ) {
 438   if ( $text_filename eq '' ) {
 439     $fh = *STDOUT;
 440   } else {
 441     my $today = DateTime->now(time_zone => C4::Context->tz );
 442     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 443   }
 444 }
 445
 446 foreach my $branchcode (@branches) {
 447     my $calendar;
 448     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 449         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 450         if ( $calendar->is_holiday($date_to_run) ) {
 451             next;
 452         }
 453     }
 454
 455     my $library             = Koha::Libraries->find($branchcode);
 456     my $admin_email_address = $library->branchemail
 457       || C4::Context->preference('KohaAdminEmailAddress');
 458     my @output_chunks;    # may be sent to mail or stdout or csv file.
 459
 460     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 461
 462     my $sth2 = $dbh->prepare( <<"END_SQL" );
 463 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 464   FROM issues,items,biblio, biblioitems, branches b
 465   WHERE items.itemnumber=issues.itemnumber
 466     AND biblio.biblionumber   = items.biblionumber
 467     AND b.branchcode = items.homebranch
 468     AND biblio.biblionumber   = biblioitems.biblionumber
 469     AND issues.borrowernumber = ?
 470     AND issues.branchcode = ?
 471     AND items.itemlost = 0
 472     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 473 END_SQL
 474
 475     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 476     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 477     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 478
 479     my $rqoverduerules =  $dbh->prepare($query);
 480     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 481
 482     # We get default rules is there is no rule for this branch
 483     if($rqoverduerules->rows == 0){
 484         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 485         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 486         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 487
 488         $rqoverduerules = $dbh->prepare($query);
 489         $rqoverduerules->execute(@myborcat, @myborcatout);
 490     }
 491
 492     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 493     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 494       PERIOD: foreach my $i ( 1 .. 3 ) {
 495
 496             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 497
 498             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 499             my $maxdays = (
 500                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 501                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 502                 : ($MAX)
 503             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 504
 505             next unless defined $mindays;
 506
 507             if ( !$overdue_rules->{"letter$i"} ) {
 508                 $verbose and warn "No letter$i code for branch '$branchcode'";
 509                 next PERIOD;
 510             }
 511
 512             # $letter->{'content'} is the text of the mail that is sent.
 513             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 514             # The following fields are available :
 515             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 516             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 517
 518             my $borrower_sql = <<"END_SQL";
 519 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 520 FROM   issues,borrowers,categories,items
 521 WHERE  issues.borrowernumber=borrowers.borrowernumber
 522 AND    borrowers.categorycode=categories.categorycode
 523 AND    issues.itemnumber = items.itemnumber
 524 AND    items.itemlost = 0
 525 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 526 END_SQL
 527             my @borrower_parameters;
 528             if ($branchcode) {
 529                 $borrower_sql .= ' AND issues.branchcode=? ';
 530                 push @borrower_parameters, $branchcode;
 531             }
 532             if ( $overdue_rules->{categorycode} ) {
 533                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 534                 push @borrower_parameters, $overdue_rules->{categorycode};
 535             }
 536             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 537
 538             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 539                 my $sth = $dbh->prepare($borrower_sql);
 540             $sth->execute(@borrower_parameters);
 541
 542             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 543             my $borrowernumber;
 544             while ( my $data = $sth->fetchrow_hashref ) {
 545
 546                 # check the borrower has at least one item that matches
 547                 my $days_between;
 548                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 549                 {
 550                     $days_between =
 551                       $calendar->days_between( dt_from_string($data->{date_due}),
 552                         $date_to_run );
 553                 }
 554                 else {
 555                     $days_between =
 556                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 557                 }
 558                 $days_between = $days_between->in_units('days');
 559                 if ($triggered) {
 560                     if ( $mindays != $days_between ) {
 561                         next;
 562                     }
 563                 }
 564                 else {
 565                     unless (   $days_between >= $mindays
 566                         && $days_between <= $maxdays )
 567                     {
 568                         next;
 569                     }
 570                 }
 571                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 572 # we have already dealt with this borrower
 573                     $verbose and warn "already dealt with this borrower $borrowernumber";
 574                     next;
 575                 }
 576                 $borrowernumber = $data->{'borrowernumber'};
 577                 my $borr =
 578                     $data->{'firstname'} . ', '
 579                   . $data->{'surname'} . ' ('
 580                   . $borrowernumber . ')';
 581                 $verbose
 582                   and warn "borrower $borr has items triggering level $i.";
 583
 584                 my $patron = Koha::Patrons->find( $borrowernumber );
 585                 @emails_to_use = ();
 586                 my $notice_email = $patron->notice_email_address;
 587                 unless ($nomail) {
 588                     if (@emails) {
 589                         foreach (@emails) {
 590                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 591                         }
 592                     }
 593                     else {
 594                         push @emails_to_use, $notice_email if ($notice_email);
 595                     }
 596                 }
 597
 598                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 599
 600                 unless ($letter) {
 601                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 602
 603                     # might as well skip while PERIOD, no other borrowers are going to work.
 604                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 605                     next PERIOD;
 606                 }
 607
 608                 if ( $overdue_rules->{"debarred$i"} ) {
 609
 610                     #action taken is debarring
 611                     AddUniqueDebarment(
 612                         {
 613                             borrowernumber => $borrowernumber,
 614                             type           => 'OVERDUES',
 615                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 616                         }
 617                     ) unless $test_mode;
 618                     $verbose and warn "debarring $borr\n";
 619                 }
 620                 my @params = ($borrowernumber,$branchcode);
 621                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 622
 623                 $sth2->execute(@params);
 624                 my $itemcount = 0;
 625                 my $titles = "";
 626                 my @items = ();
 627
 628                 my $j = 0;
 629                 my $exceededPrintNoticesMaxLines = 0;
 630                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 631                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 632                         $days_between =
 633                           $calendar->days_between(
 634                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 635                     }
 636                     else {
 637                         $days_between =
 638                           $date_to_run->delta_days(
 639                             dt_from_string( $item_info->{date_due} ) );
 640                     }
 641                     $days_between = $days_between->in_units('days');
 642                     if ($listall){
 643                         unless ($days_between >= 1 and $days_between <= $MAX){
 644                             next;
 645                         }
 646                     }
 647                     else {
 648                         if ($triggered) {
 649                             if ( $mindays != $days_between ) {
 650                                 next;
 651                             }
 652                         }
 653                         else {
 654                             unless ( $days_between >= $mindays
 655                                 && $days_between <= $maxdays )
 656                             {
 657                                 next;
 658                             }
 659                         }
 660                     }
 661
 662                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 663                       $exceededPrintNoticesMaxLines = 1;
 664                       last;
 665                     }
 666                     $j++;
 667
 668                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 669                     $itemcount++;
 670                     push @items, $item_info;
 671                 }
 672                 $sth2->finish;
 673
 674                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 675                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 676                     unless @message_transport_types;
 677
 678
 679                 my $print_sent = 0; # A print notice is not yet sent for this patron
 680                 for my $mtt ( @message_transport_types ) {
 681                     my $effective_mtt = $mtt;
 682                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 683                         # email or sms is requested but not exist, do a print.
 684                         $effective_mtt = 'print';
 685                     }
 686                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 687                     #catch the case where we are sending a print to someone with an email
 688
 689                     my $letter_exists = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode, $effective_mtt ) ? 1 : 0;
 690                     my $letter = parse_overdues_letter(
 691                         {   letter_code     => $overdue_rules->{"letter$i"},
 692                             borrowernumber  => $borrowernumber,
 693                             branchcode      => $branchcode,
 694                             items           => \@items,
 695                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 696                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 697                                                 'items.content' => $titles,
 698                                                 'count'         => $itemcount,
 699                                                },
 700                             # If there is no template defined for the requested letter
 701                             # Fallback on email
 702                             message_transport_type => $letter_exists ? $effective_mtt : 'email',
 703                         }
 704                     );
 705                     unless ($letter) {
 706                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 707                         # this transport doesn't have a configured notice, so try another
 708                         next;
 709                     }
 710
 711                     if ( $exceededPrintNoticesMaxLines ) {
 712                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 713                     }
 714
 715                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 716                     if (@misses) {
 717                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 718                     }
 719
 720                     if ($nomail) {
 721                         push @output_chunks,
 722                           prepare_letter_for_printing(
 723                           {   letter         => $letter,
 724                               borrowernumber => $borrowernumber,
 725                               firstname      => $data->{'firstname'},
 726                               lastname       => $data->{'surname'},
 727                               address1       => $data->{'address'},
 728                               address2       => $data->{'address2'},
 729                               city           => $data->{'city'},
 730                               phone          => $data->{'phone'},
 731                               cardnumber     => $data->{'cardnumber'},
 732                               branchname     => $library->branchname,
 733                               letternumber   => $i,
 734                               postcode       => $data->{'zipcode'},
 735                               country        => $data->{'country'},
 736                               email          => $notice_email,
 737                               itemcount      => $itemcount,
 738                               titles         => $titles,
 739                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 740                             }
 741                           );
 742                     } else {
 743                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 744                             push @output_chunks,
 745                               prepare_letter_for_printing(
 746                               {   letter         => $letter,
 747                                   borrowernumber => $borrowernumber,
 748                                   firstname      => $data->{'firstname'},
 749                                   lastname       => $data->{'surname'},
 750                                   address1       => $data->{'address'},
 751                                   address2       => $data->{'address2'},
 752                                   city           => $data->{'city'},
 753                                   postcode       => $data->{'zipcode'},
 754                                   country        => $data->{'country'},
 755                                   email          => $notice_email,
 756                                   itemcount      => $itemcount,
 757                                   titles         => $titles,
 758                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 759                                 }
 760                               );
 761                         }
 762                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 763                             # Just sent a print if not already done.
 764                             C4::Letters::EnqueueLetter(
 765                                 {   letter                 => $letter,
 766                                     borrowernumber         => $borrowernumber,
 767                                     message_transport_type => $effective_mtt,
 768                                     from_address           => $admin_email_address,
 769                                     to_address             => join(',', @emails_to_use),
 770                                 }
 771                             ) unless $test_mode;
 772                             # A print notice should be sent only once per overdue level.
 773                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 774                             $print_sent = 1 if $effective_mtt eq 'print';
 775                         }
 776                     }
 777                 }
 778             }
 779             $sth->finish;
 780         }
 781     }
 782
 783     if (@output_chunks) {
 784         if ( defined $csvfilename ) {
 785             print $csv_fh @output_chunks;
 786         }
 787         elsif ( defined $htmlfilename ) {
 788             print $fh @output_chunks;
 789         }
 790         elsif ( defined $text_filename ) {
 791             print $fh @output_chunks;
 792         }
 793         elsif ($nomail){
 794                 local $, = "\f";    # pagebreak
 795                 print @output_chunks;
 796         }
 797         # Generate the content of the csv with headers
 798         my $content;
 799         if ( defined $csvfilename ) {
 800             my $delimiter = C4::Context->preference('delimiter') || ';';
 801             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 802         }
 803         else {
 804             $content = "";
 805         }
 806         $content .= join( "\n", @output_chunks );
 807
 808         my $attachment = {
 809             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 810             type => 'text/plain',
 811             content => $content,
 812         };
 813
 814         my $letter = {
 815             title   => 'Overdue Notices',
 816             content => 'These messages were not sent directly to the patrons.',
 817         };
 818         C4::Letters::EnqueueLetter(
 819             {   letter                 => $letter,
 820                 borrowernumber         => undef,
 821                 message_transport_type => 'email',
 822                 attachments            => [$attachment],
 823                 to_address             => $admin_email_address,
 824             }
 825         ) unless $test_mode;
 826     }
 827
 828 }
 829 if ($csvfilename) {
 830     # note that we're not testing on $csv_fh to prevent closing
 831     # STDOUT.
 832     close $csv_fh;
 833 }
 834
 835 if ( defined $htmlfilename ) {
 836   print $fh "</body>\n";
 837   print $fh "</html>\n";
 838   close $fh;
 839 } elsif ( defined $text_filename ) {
 840   close $fh;
 841 }
 842
 843 =head1 INTERNAL METHODS
 844
 845 These methods are internal to the operation of overdue_notices.pl.
 846
 847 =head2 prepare_letter_for_printing
 848
 849 returns a string of text appropriate for printing in the event that an
 850 overdue notice will not be sent to the patron's email
 851 address. Depending on the desired output format, this may be a CSV
 852 string, or a human-readable representation of the notice.
 853
 854 required parameters:
 855   letter
 856   borrowernumber
 857
 858 optional parameters:
 859   outputformat
 860
 861 =cut
 862
 863 sub prepare_letter_for_printing {
 864     my $params = shift;
 865
 866     return unless ref $params eq 'HASH';
 867
 868     foreach my $required_parameter (qw( letter borrowernumber )) {
 869         return unless defined $params->{$required_parameter};
 870     }
 871
 872     my $return;
 873     chomp $params->{titles};
 874     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 875         if ($csv->combine(
 876                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 877                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 878                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 879             )
 880           ) {
 881             return $csv->string, "\n";
 882         } else {
 883             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 884         }
 885     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 886       $return = "<pre>\n";
 887       $return .= "$params->{'letter'}->{'content'}\n";
 888       $return .= "\n</pre>\n";
 889     } else {
 890         $return .= "$params->{'letter'}->{'content'}\n";
 891
 892         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 893     }
 894     return $return;
 895 }
 896