misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43
  44 =head1 NAME
  45
  46 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  47
  48 =head1 SYNOPSIS
  49
  50 overdue_notices.pl
  51   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  52   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  53   [ -email <email_type> ... ]
  54
  55  Options:
  56    -help                          brief help message
  57    -man                           full documentation
  58    -n                             No email will be sent
  59    -max          <days>           maximum days overdue to deal with
  60    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  61    -csv          <filename>       populate CSV file
  62    -html         <filename>       Output html to file
  63    -itemscontent <list of fields> item information in templates
  64    -borcat       <categorycode>   category code that must be included
  65    -borcatout    <categorycode>   category code that must be excluded
  66    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  67
  68 =head1 OPTIONS
  69
  70 =over 8
  71
  72 =item B<-help>
  73
  74 Print a brief help message and exits.
  75
  76 =item B<-man>
  77
  78 Prints the manual page and exits.
  79
  80 =item B<-v>
  81
  82 Verbose. Without this flag set, only fatal errors are reported.
  83
  84 =item B<-n>
  85
  86 Do not send any email. Overdue notices that would have been sent to
  87 the patrons or to the admin are printed to standard out. CSV data (if
  88 the -csv flag is set) is written to standard out or to any csv
  89 filename given.
  90
  91 =item B<-max>
  92
  93 Items older than max days are assumed to be handled somewhere else,
  94 probably the F<longoverdues.pl> script. They are therefore ignored by
  95 this program. No notices are sent for them, and they are not added to
  96 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  97
  98 =item B<-library>
  99
 100 select overdues for one specific library. Use the value in the
 101 branches.branchcode table. This option can be repeated in order
 102 to select overdues for a group of libraries.
 103
 104 =item B<-csv>
 105
 106 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 107 sent to standard out or to a filename if provided. Otherwise, only
 108 overdues that could not be emailed are sent in CSV format to the admin.
 109
 110 =item B<-html>
 111
 112 Produces html data. if patron does not have a mail address or
 113 -n (no mail) flag is set, an html file is generated in the specified
 114 directory. This can be downloaded or futher processed by library staff.
 115
 116 =item B<-itemscontent>
 117
 118 comma separated list of fields that get substituted into templates in
 119 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 120 defaults to due date,title,barcode,author
 121
 122 Other possible values come from fields in the biblios, items and
 123 issues tables.
 124
 125 =item B<-borcat>
 126
 127 Repetable field, that permit to select only few of patrons categories.
 128
 129 =item B<-borcatout>
 130
 131 Repetable field, permis to exclude some patrons categories.
 132
 133 =item B<-t> | B<--triggered>
 134
 135 This option causes a notice to be generated if and only if
 136 an item is overdue by the number of days defined in a notice trigger.
 137
 138 By default, a notice is sent each time the script runs, which is suitable for
 139 less frequent run cron script, but requires syncing notice triggers with
 140 the  cron schedule to ensure proper behavior.
 141 Add the --triggered option for daily cron, at the risk of no notice
 142 being generated if the cron fails to run on time.
 143
 144 =item B<-list-all>
 145
 146 Default items.content lists only those items that fall in the
 147 range of the currently processing notice.
 148 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 149
 150 =item B<-date>
 151
 152 use it in order to send overdues on a specific date and not Now.
 153
 154 =item B<-email>
 155
 156 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 157
 158 =back
 159
 160 =head1 DESCRIPTION
 161
 162 This script is designed to alert patrons and administrators of overdue
 163 items.
 164
 165 =head2 Configuration
 166
 167 This script pays attention to the overdue notice configuration
 168 performed in the "Overdue notice/status triggers" section of the
 169 "Tools" area of the staff interface to Koha. There, you can choose
 170 which letter templates are sent out after a configurable number of
 171 days to patrons of each library. More information about the use of this
 172 section of Koha is available in the Koha manual.
 173
 174 The templates used to craft the emails are defined in the "Tools:
 175 Notices" section of the staff interface to Koha.
 176
 177 =head2 Outgoing emails
 178
 179 Typically, messages are prepared for each patron with overdue
 180 items. Messages for whom there is no email address on file are
 181 collected and sent as attachments in a single email to each library
 182 administrator, or if that is not set, then to the email address in the
 183 C<KohaAdminEmailAddress> system preference.
 184
 185 These emails are staged in the outgoing message queue, as are messages
 186 produced by other features of Koha. This message queue must be
 187 processed regularly by the
 188 F<misc/cronjobs/process_message_queue.pl> program.
 189
 190 In the event that the C<-n> flag is passed to this program, no emails
 191 are sent. Instead, messages are sent on standard output from this
 192 program. They may be redirected to a file if desired.
 193
 194 =head2 Templates
 195
 196 Templates can contain variables enclosed in double angle brackets like
 197 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 198 specific to the overdue items or relevant patron. Available variables
 199 are:
 200
 201 =over
 202
 203 =item E<lt>E<lt>bibE<gt>E<gt>
 204
 205 the name of the library
 206
 207 =item E<lt>E<lt>items.contentE<gt>E<gt>
 208
 209 one line for each item, each line containing a tab separated list of
 210 title, author, barcode, issuedate
 211
 212 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 213
 214 any field from the borrowers table
 215
 216 =item E<lt>E<lt>branches.*E<gt>E<gt>
 217
 218 any field from the branches table
 219
 220 =back
 221
 222 =head2 CSV output
 223
 224 The C<-csv> command line option lets you specify a file to which
 225 overdues data should be output in CSV format.
 226
 227 With the C<-n> flag set, data about all overdues is written to the
 228 file. Without that flag, only information about overdues that were
 229 unable to be sent directly to the patrons will be written. In other
 230 words, this CSV file replaces the data that is typically sent to the
 231 administrator email address.
 232
 233 =head1 USAGE EXAMPLES
 234
 235 C<overdue_notices.pl> - In this most basic usage, with no command line
 236 arguments, all libraries are procesed individually, and notices are
 237 prepared for all patrons with overdue items for whom we have email
 238 addresses. Messages for those patrons for whom we have no email
 239 address are sent in a single attachment to the library administrator's
 240 email address, or to the address in the KohaAdminEmailAddress system
 241 preference.
 242
 243 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 244 populates F</tmp/overdues.csv> with information about all overdue
 245 items.
 246
 247 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 248 overdues in the last 2 weeks for the MAIN library.
 249
 250 =head1 SEE ALSO
 251
 252 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 253 messages to patrons in advance of thier items becoming due, or to
 254 alert them of items that have just become due.
 255
 256 =cut
 257
 258 # These variables are set by command line options.
 259 # They are initially set to default values.
 260 my $dbh = C4::Context->dbh();
 261 my $help    = 0;
 262 my $man     = 0;
 263 my $verbose = 0;
 264 my $nomail  = 0;
 265 my $MAX     = 90;
 266 my @branchcodes; # Branch(es) passed as parameter
 267 my @emails_to_use;    # Emails to use for messaging
 268 my @emails;           # Emails given in command-line parameters
 269 my $csvfilename;
 270 my $htmlfilename;
 271 my $triggered = 0;
 272 my $listall = 0;
 273 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 274 my @myborcat;
 275 my @myborcatout;
 276 my $date;
 277
 278 GetOptions(
 279     'help|?'         => \$help,
 280     'man'            => \$man,
 281     'v'              => \$verbose,
 282     'n'              => \$nomail,
 283     'max=s'          => \$MAX,
 284     'library=s'      => \@branchcodes,
 285     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 286     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 287     'itemscontent=s' => \$itemscontent,
 288     'list-all'       => \$listall,
 289     't|triggered'    => \$triggered,
 290     'date'           => \$date,
 291     'borcat=s'       => \@myborcat,
 292     'borcatout=s'    => \@myborcatout,
 293     'email=s'        => \@emails,
 294 ) or pod2usage(2);
 295 pod2usage(1) if $help;
 296 pod2usage( -verbose => 2 ) if $man;
 297
 298 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 299     warn qq(using "$csvfilename" as filename, that seems odd);
 300 }
 301
 302 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 303 my @branches;                                                                   # Branches passed as parameter with overdue rules
 304 my $branchcount = scalar(@overduebranches);
 305
 306 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 307 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 308
 309 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 310
 311 if ($branchcount) {
 312     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 313 } else {
 314     die 'No branches with active overduerules';
 315 }
 316
 317 if (@branchcodes) {
 318     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 319
 320     # Getting libraries which have overdue rules
 321     my %seen = map { $_ => 1 } @branchcodes;
 322     @branches = grep { $seen{$_} } @overduebranches;
 323
 324
 325     if (@branches) {
 326
 327         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 328         $verbose and warn "$branch_word @branches have overdue rules\n";
 329
 330     } else {
 331
 332         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 333         ( scalar grep { '' eq $_ } @branches )
 334           or die "No active overduerules for DEFAULT either!";
 335         $verbose and warn "Falling back on default rules for @branchcodes\n";
 336         @branches = ('');
 337     }
 338 }
 339
 340 if ($date){
 341     $date=$dbh->quote($date);
 342 }
 343 else {
 344     $date="NOW()";
 345 }
 346
 347 # these are the fields that will be substituted into <<item.content>>
 348 my @item_content_fields = split( /,/, $itemscontent );
 349
 350 binmode( STDOUT, ':encoding(UTF-8)' );
 351
 352
 353 our $csv;       # the Text::CSV_XS object
 354 our $csv_fh;    # the filehandle to the CSV file.
 355 if ( defined $csvfilename ) {
 356     my $sep_char = C4::Context->preference('delimiter') || ',';
 357     $sep_char = "\t" if ($sep_char eq 'tabulation');
 358     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 359     if ( $csvfilename eq '' ) {
 360         $csv_fh = *STDOUT;
 361     } else {
 362         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 363     }
 364     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 365         print $csv_fh $csv->string, "\n";
 366     } else {
 367         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 368     }
 369 }
 370
 371 @branches = @overduebranches unless @branches;
 372 our $html_fh;
 373 if ( defined $htmlfilename ) {
 374   if ( $htmlfilename eq '' ) {
 375     $html_fh = *STDOUT;
 376   } else {
 377     my $today = DateTime->now(time_zone => C4::Context->tz );
 378     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 379   }
 380
 381   print $html_fh "<html>\n";
 382   print $html_fh "<head>\n";
 383   print $html_fh "<style type='text/css'>\n";
 384   print $html_fh "pre {page-break-after: always;}\n";
 385   print $html_fh "pre {white-space: pre-wrap;}\n";
 386   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 387   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 388   print $html_fh "pre {word-wrap: break-work;}\n";
 389   print $html_fh "</style>\n";
 390   print $html_fh "</head>\n";
 391   print $html_fh "<body>\n";
 392 }
 393
 394 foreach my $branchcode (@branches) {
 395
 396     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 397     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 398     my @output_chunks;    # may be sent to mail or stdout or csv file.
 399
 400     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 401
 402     my $sth2 = $dbh->prepare( <<"END_SQL" );
 403 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 404   FROM issues,items,biblio, biblioitems
 405   WHERE items.itemnumber=issues.itemnumber
 406     AND biblio.biblionumber   = items.biblionumber
 407     AND biblio.biblionumber   = biblioitems.biblionumber
 408     AND issues.borrowernumber = ?
 409     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 410 END_SQL
 411
 412     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 413     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 414     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 415
 416     my $rqoverduerules =  $dbh->prepare($query);
 417     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 418
 419     # We get default rules is there is no rule for this branch
 420     if($rqoverduerules->rows == 0){
 421         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 422         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 423         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 424
 425         $rqoverduerules = $dbh->prepare($query);
 426         $rqoverduerules->execute(@myborcat, @myborcatout);
 427     }
 428
 429     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 430     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 431       PERIOD: foreach my $i ( 1 .. 3 ) {
 432
 433             $verbose and warn "branch '$branchcode', pass $i\n";
 434             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 435             my $maxdays = (
 436                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 437                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 438                 : ($MAX)
 439             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 440
 441             if ( !$overdue_rules->{"letter$i"} ) {
 442                 $verbose and warn "No letter$i code for branch '$branchcode'";
 443                 next PERIOD;
 444             }
 445
 446             # $letter->{'content'} is the text of the mail that is sent.
 447             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 448             # The following fields are available :
 449             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 450             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 451
 452             my $borrower_sql = <<'END_SQL';
 453 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email
 454 FROM   issues,borrowers,categories
 455 WHERE  issues.borrowernumber=borrowers.borrowernumber
 456 AND    borrowers.categorycode=categories.categorycode
 457 END_SQL
 458             my @borrower_parameters;
 459             if ($branchcode) {
 460                 $borrower_sql .= ' AND issues.branchcode=? ';
 461                 push @borrower_parameters, $branchcode;
 462             }
 463             if ( $overdue_rules->{categorycode} ) {
 464                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 465                 push @borrower_parameters, $overdue_rules->{categorycode};
 466             }
 467             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 468             if($triggered) {
 469                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 470                 push @borrower_parameters, $mindays;
 471             } else {
 472                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 473                 push @borrower_parameters, $mindays, $maxdays;
 474             }
 475
 476             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 477                 my $sth = $dbh->prepare($borrower_sql);
 478             $sth->execute(@borrower_parameters);
 479             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 480
 481             while ( my $data = $sth->fetchrow_hashref ) {
 482                 my $borrowernumber = $data->{'borrowernumber'};
 483                 my $borr =
 484                     $data->{'firstname'} . ', '
 485                   . $data->{'surname'} . ' ('
 486                   . $borrowernumber . ')';
 487                 $verbose
 488                   and warn "borrower $borr has items triggering level $i.";
 489
 490                 @emails_to_use = ();
 491                 my $notice_email =
 492                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 493                 unless ($nomail) {
 494                     if (@emails) {
 495                         foreach (@emails) {
 496                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 497                         }
 498                     }
 499                     else {
 500                         push @emails_to_use, $notice_email if ($notice_email);
 501                     }
 502                 }
 503
 504                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 505
 506                 unless ($letter) {
 507                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 508
 509                     # might as well skip while PERIOD, no other borrowers are going to work.
 510                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 511                     next PERIOD;
 512                 }
 513
 514                 if ( $overdue_rules->{"debarred$i"} ) {
 515
 516                     #action taken is debarring
 517                     C4::Members::DebarMember($borrowernumber, '9999-12-31');
 518                     $verbose and warn "debarring $borr\n";
 519                 }
 520                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 521                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 522                 $sth2->execute(@params);
 523                 my $itemcount = 0;
 524                 my $titles = "";
 525                 my @items = ();
 526
 527                 my $j = 0;
 528                 my $exceededPrintNoticesMaxLines = 0;
 529                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 530                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 531                       $exceededPrintNoticesMaxLines = 1;
 532                       last;
 533                     }
 534                     $j++;
 535                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 536                     $titles .= join("\t", @item_info) . "\n";
 537                     $itemcount++;
 538                     push @items, $item_info;
 539                 }
 540                 $sth2->finish;
 541
 542                 $letter = parse_letter(
 543                     {   letter_code     => $overdue_rules->{"letter$i"},
 544                         borrowernumber  => $borrowernumber,
 545                         branchcode      => $branchcode,
 546                         items           => \@items,
 547                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 548                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 549                                             'items.content' => $titles,
 550                                             'count'         => $itemcount,
 551                                            }
 552                     }
 553                 );
 554                 unless ($letter) {
 555                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 556
 557                     # might as well skip while PERIOD, no other borrowers are going to work.
 558                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 559                     next PERIOD;
 560                 }
 561
 562                 if ( $exceededPrintNoticesMaxLines ) {
 563                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 564                 }
 565
 566                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 567                 if (@misses) {
 568                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 569                 }
 570                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 571                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 572
 573                 if ( !$nomail && scalar @emails_to_use ) {
 574                     C4::Letters::EnqueueLetter(
 575                         {   letter                 => $letter,
 576                             borrowernumber         => $borrowernumber,
 577                             message_transport_type => 'email',
 578                             from_address           => $admin_email_address,
 579                             to_address             => join(',', @emails_to_use),
 580                         }
 581                     );
 582                 } else {
 583                     # if not sent by email then print
 584                     push @output_chunks,
 585                       prepare_letter_for_printing(
 586                         {   letter         => $letter,
 587                             borrowernumber => $borrowernumber,
 588                             firstname      => $data->{'firstname'},
 589                             lastname       => $data->{'surname'},
 590                             address1       => $data->{'address'},
 591                             address2       => $data->{'address2'},
 592                             city           => $data->{'city'},
 593                             postcode       => $data->{'zipcode'},
 594                             country        => $data->{'country'},
 595                             email          => $notice_email,
 596                             itemcount      => $itemcount,
 597                             titles         => $titles,
 598                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 599                         }
 600                       );
 601                 }
 602             }
 603             $sth->finish;
 604         }
 605     }
 606
 607     if (@output_chunks) {
 608         if ( defined $csvfilename ) {
 609             print $csv_fh @output_chunks;
 610         }
 611         elsif ( defined $htmlfilename ) {
 612             print $html_fh @output_chunks;
 613         }
 614         elsif ($nomail){
 615                 local $, = "\f";    # pagebreak
 616                 print @output_chunks;
 617         }
 618         # Generate the content of the csv with headers
 619         my $content = join(";", qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 620         $content .= join( "\n", @output_chunks );
 621
 622         my $attachment = {
 623             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 624             type => 'text/plain',
 625             content => $content,
 626         };
 627
 628         my $letter = {
 629             title   => 'Overdue Notices',
 630             content => 'These messages were not sent directly to the patrons.',
 631         };
 632         C4::Letters::EnqueueLetter(
 633             {   letter                 => $letter,
 634                 borrowernumber         => undef,
 635                 message_transport_type => 'email',
 636                 attachments            => [$attachment],
 637                 to_address             => $admin_email_address,
 638             }
 639         );
 640     }
 641
 642 }
 643 if ($csvfilename) {
 644     # note that we're not testing on $csv_fh to prevent closing
 645     # STDOUT.
 646     close $csv_fh;
 647 }
 648
 649 if ( defined $htmlfilename ) {
 650   print $html_fh "</body>\n";
 651   print $html_fh "</html>\n";
 652   close $html_fh;
 653 }
 654
 655 =head1 INTERNAL METHODS
 656
 657 These methods are internal to the operation of overdue_notices.pl.
 658
 659 =head2 parse_letter
 660
 661 parses the letter template, replacing the placeholders with data
 662 specific to this patron, biblio, or item
 663
 664 named parameters:
 665   letter - required hashref
 666   borrowernumber - required integer
 667   substitute - optional hashref of other key/value pairs that should
 668     be substituted in the letter content
 669
 670 returns the C<letter> hashref, with the content updated to reflect the
 671 substituted keys and values.
 672
 673
 674 =cut
 675
 676 sub parse_letter {
 677     my $params = shift;
 678     foreach my $required (qw( letter_code borrowernumber )) {
 679         return unless ( exists $params->{$required} && $params->{$required} );
 680     }
 681
 682     my $substitute = $params->{'substitute'} || {};
 683     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 684
 685     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 686     if ( my $p = $params->{'branchcode'} ) {
 687         $tables{'branches'} = $p;
 688     }
 689
 690     my $currency_format;
 691     if ( defined $params->{'letter'}->{'content'}
 692         and $params->{'letter'}->{'content'} =~ m/<fine>(.*)<\/fine>/o )
 693     {    # process any fine tags...
 694         $currency_format = $1;
 695         $params->{'letter'}->{'content'} =~ s/<fine>.*<\/fine>/<<item.fine>>/o;
 696     }
 697
 698     my @item_tables;
 699     if ( my $i = $params->{'items'} ) {
 700         my $item_format = '';
 701         foreach my $item (@$i) {
 702             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 703             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 704                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 705                 $item_format = $1;
 706             }
 707
 708             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL)
 709               if $currency_format;
 710
 711             push @item_tables, {
 712                 'biblio' => $item->{'biblionumber'},
 713                 'biblioitems' => $item->{'biblionumber'},
 714                 'items' => $item,
 715                 'issues' => $item->{'itemnumber'},
 716             };
 717         }
 718     }
 719
 720     return C4::Letters::GetPreparedLetter (
 721         module => 'circulation',
 722         letter_code => $params->{'letter_code'},
 723         branchcode => $params->{'branchcode'},
 724         tables => \%tables,
 725         substitute => $substitute,
 726         repeat => { item => \@item_tables },
 727     );
 728 }
 729
 730 =head2 prepare_letter_for_printing
 731
 732 returns a string of text appropriate for printing in the event that an
 733 overdue notice will not be sent to the patron's email
 734 address. Depending on the desired output format, this may be a CSV
 735 string, or a human-readable representation of the notice.
 736
 737 required parameters:
 738   letter
 739   borrowernumber
 740
 741 optional parameters:
 742   outputformat
 743
 744 =cut
 745
 746 sub prepare_letter_for_printing {
 747     my $params = shift;
 748
 749     return unless ref $params eq 'HASH';
 750
 751     foreach my $required_parameter (qw( letter borrowernumber )) {
 752         return unless defined $params->{$required_parameter};
 753     }
 754
 755     my $return;
 756     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 757         if ($csv->combine(
 758                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 759                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 760             )
 761           ) {
 762             return $csv->string, "\n";
 763         } else {
 764             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 765         }
 766     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 767       $return = "<pre>\n";
 768       $return .= "$params->{'letter'}->{'content'}\n";
 769       $return .= "\n</pre>\n";
 770     } else {
 771         $return .= "$params->{'letter'}->{'content'}\n";
 772
 773         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 774     }
 775     return $return;
 776 }
 777