misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43 use C4::Budgets qw(GetCurrency);
  44
  45 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  46 use Koha::DateUtils;
  47
  48 =head1 NAME
  49
  50 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  51
  52 =head1 SYNOPSIS
  53
  54 overdue_notices.pl
  55   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  56   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  57   [ -email <email_type> ... ]
  58
  59  Options:
  60    -help                          brief help message
  61    -man                           full documentation
  62    -n                             No email will be sent
  63    -max          <days>           maximum days overdue to deal with
  64    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  65    -csv          <filename>       populate CSV file
  66    -html         <directory>      Output html to a file in the given directory
  67    -itemscontent <list of fields> item information in templates
  68    -borcat       <categorycode>   category code that must be included
  69    -borcatout    <categorycode>   category code that must be excluded
  70    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  71
  72 =head1 OPTIONS
  73
  74 =over 8
  75
  76 =item B<-help>
  77
  78 Print a brief help message and exits.
  79
  80 =item B<-man>
  81
  82 Prints the manual page and exits.
  83
  84 =item B<-v>
  85
  86 Verbose. Without this flag set, only fatal errors are reported.
  87
  88 =item B<-n>
  89
  90 Do not send any email. Overdue notices that would have been sent to
  91 the patrons or to the admin are printed to standard out. CSV data (if
  92 the -csv flag is set) is written to standard out or to any csv
  93 filename given.
  94
  95 =item B<-max>
  96
  97 Items older than max days are assumed to be handled somewhere else,
  98 probably the F<longoverdues.pl> script. They are therefore ignored by
  99 this program. No notices are sent for them, and they are not added to
 100 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 101
 102 =item B<-library>
 103
 104 select overdues for one specific library. Use the value in the
 105 branches.branchcode table. This option can be repeated in order
 106 to select overdues for a group of libraries.
 107
 108 =item B<-csv>
 109
 110 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 111 sent to standard out or to a filename if provided. Otherwise, only
 112 overdues that could not be emailed are sent in CSV format to the admin.
 113
 114 =item B<-html>
 115
 116 Produces html data. if patron does not have a mail address or
 117 -n (no mail) flag is set, an html file is generated in the specified
 118 directory. This can be downloaded or futher processed by library staff.
 119 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 120 specified.
 121
 122 =item B<-itemscontent>
 123
 124 comma separated list of fields that get substituted into templates in
 125 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 126 defaults to due date,title,barcode,author
 127
 128 Other possible values come from fields in the biblios, items and
 129 issues tables.
 130
 131 =item B<-borcat>
 132
 133 Repetable field, that permit to select only few of patrons categories.
 134
 135 =item B<-borcatout>
 136
 137 Repetable field, permis to exclude some patrons categories.
 138
 139 =item B<-t> | B<--triggered>
 140
 141 This option causes a notice to be generated if and only if
 142 an item is overdue by the number of days defined in a notice trigger.
 143
 144 By default, a notice is sent each time the script runs, which is suitable for
 145 less frequent run cron script, but requires syncing notice triggers with
 146 the  cron schedule to ensure proper behavior.
 147 Add the --triggered option for daily cron, at the risk of no notice
 148 being generated if the cron fails to run on time.
 149
 150 =item B<-list-all>
 151
 152 Default items.content lists only those items that fall in the
 153 range of the currently processing notice.
 154 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 155
 156 =item B<-date>
 157
 158 use it in order to send overdues on a specific date and not Now.
 159
 160 =item B<-email>
 161
 162 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 163
 164 =back
 165
 166 =head1 DESCRIPTION
 167
 168 This script is designed to alert patrons and administrators of overdue
 169 items.
 170
 171 =head2 Configuration
 172
 173 This script pays attention to the overdue notice configuration
 174 performed in the "Overdue notice/status triggers" section of the
 175 "Tools" area of the staff interface to Koha. There, you can choose
 176 which letter templates are sent out after a configurable number of
 177 days to patrons of each library. More information about the use of this
 178 section of Koha is available in the Koha manual.
 179
 180 The templates used to craft the emails are defined in the "Tools:
 181 Notices" section of the staff interface to Koha.
 182
 183 =head2 Outgoing emails
 184
 185 Typically, messages are prepared for each patron with overdue
 186 items. Messages for whom there is no email address on file are
 187 collected and sent as attachments in a single email to each library
 188 administrator, or if that is not set, then to the email address in the
 189 C<KohaAdminEmailAddress> system preference.
 190
 191 These emails are staged in the outgoing message queue, as are messages
 192 produced by other features of Koha. This message queue must be
 193 processed regularly by the
 194 F<misc/cronjobs/process_message_queue.pl> program.
 195
 196 In the event that the C<-n> flag is passed to this program, no emails
 197 are sent. Instead, messages are sent on standard output from this
 198 program. They may be redirected to a file if desired.
 199
 200 =head2 Templates
 201
 202 Templates can contain variables enclosed in double angle brackets like
 203 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 204 specific to the overdue items or relevant patron. Available variables
 205 are:
 206
 207 =over
 208
 209 =item E<lt>E<lt>bibE<gt>E<gt>
 210
 211 the name of the library
 212
 213 =item E<lt>E<lt>items.contentE<gt>E<gt>
 214
 215 one line for each item, each line containing a tab separated list of
 216 title, author, barcode, issuedate
 217
 218 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 219
 220 any field from the borrowers table
 221
 222 =item E<lt>E<lt>branches.*E<gt>E<gt>
 223
 224 any field from the branches table
 225
 226 =back
 227
 228 =head2 CSV output
 229
 230 The C<-csv> command line option lets you specify a file to which
 231 overdues data should be output in CSV format.
 232
 233 With the C<-n> flag set, data about all overdues is written to the
 234 file. Without that flag, only information about overdues that were
 235 unable to be sent directly to the patrons will be written. In other
 236 words, this CSV file replaces the data that is typically sent to the
 237 administrator email address.
 238
 239 =head1 USAGE EXAMPLES
 240
 241 C<overdue_notices.pl> - In this most basic usage, with no command line
 242 arguments, all libraries are procesed individually, and notices are
 243 prepared for all patrons with overdue items for whom we have email
 244 addresses. Messages for those patrons for whom we have no email
 245 address are sent in a single attachment to the library administrator's
 246 email address, or to the address in the KohaAdminEmailAddress system
 247 preference.
 248
 249 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 250 populates F</tmp/overdues.csv> with information about all overdue
 251 items.
 252
 253 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 254 overdues in the last 2 weeks for the MAIN library.
 255
 256 =head1 SEE ALSO
 257
 258 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 259 messages to patrons in advance of thier items becoming due, or to
 260 alert them of items that have just become due.
 261
 262 =cut
 263
 264 # These variables are set by command line options.
 265 # They are initially set to default values.
 266 my $dbh = C4::Context->dbh();
 267 my $help    = 0;
 268 my $man     = 0;
 269 my $verbose = 0;
 270 my $nomail  = 0;
 271 my $MAX     = 90;
 272 my @branchcodes; # Branch(es) passed as parameter
 273 my @emails_to_use;    # Emails to use for messaging
 274 my @emails;           # Emails given in command-line parameters
 275 my $csvfilename;
 276 my $htmlfilename;
 277 my $triggered = 0;
 278 my $listall = 0;
 279 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 280 my @myborcat;
 281 my @myborcatout;
 282 my $date;
 283
 284 GetOptions(
 285     'help|?'         => \$help,
 286     'man'            => \$man,
 287     'v'              => \$verbose,
 288     'n'              => \$nomail,
 289     'max=s'          => \$MAX,
 290     'library=s'      => \@branchcodes,
 291     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 292     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 293     'itemscontent=s' => \$itemscontent,
 294     'list-all'       => \$listall,
 295     't|triggered'    => \$triggered,
 296     'date'           => \$date,
 297     'borcat=s'       => \@myborcat,
 298     'borcatout=s'    => \@myborcatout,
 299     'email=s'        => \@emails,
 300 ) or pod2usage(2);
 301 pod2usage(1) if $help;
 302 pod2usage( -verbose => 2 ) if $man;
 303
 304 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 305     warn qq(using "$csvfilename" as filename, that seems odd);
 306 }
 307
 308 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 309 my @branches;                                                                   # Branches passed as parameter with overdue rules
 310 my $branchcount = scalar(@overduebranches);
 311
 312 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 313 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 314
 315 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 316
 317 if ($branchcount) {
 318     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 319 } else {
 320     die 'No branches with active overduerules';
 321 }
 322
 323 if (@branchcodes) {
 324     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 325
 326     # Getting libraries which have overdue rules
 327     my %seen = map { $_ => 1 } @branchcodes;
 328     @branches = grep { $seen{$_} } @overduebranches;
 329
 330
 331     if (@branches) {
 332
 333         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 334         $verbose and warn "$branch_word @branches have overdue rules\n";
 335
 336     } else {
 337
 338         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 339         ( scalar grep { '' eq $_ } @branches )
 340           or die "No active overduerules for DEFAULT either!";
 341         $verbose and warn "Falling back on default rules for @branchcodes\n";
 342         @branches = ('');
 343     }
 344 }
 345
 346 if ($date){
 347     $date=$dbh->quote($date);
 348 }
 349 else {
 350     $date="NOW()";
 351 }
 352
 353 # these are the fields that will be substituted into <<item.content>>
 354 my @item_content_fields = split( /,/, $itemscontent );
 355
 356 binmode( STDOUT, ':encoding(UTF-8)' );
 357
 358
 359 our $csv;       # the Text::CSV_XS object
 360 our $csv_fh;    # the filehandle to the CSV file.
 361 if ( defined $csvfilename ) {
 362     my $sep_char = C4::Context->preference('delimiter') || ',';
 363     $sep_char = "\t" if ($sep_char eq 'tabulation');
 364     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 365     if ( $csvfilename eq '' ) {
 366         $csv_fh = *STDOUT;
 367     } else {
 368         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 369     }
 370     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 371         print $csv_fh $csv->string, "\n";
 372     } else {
 373         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 374     }
 375 }
 376
 377 @branches = @overduebranches unless @branches;
 378 our $html_fh;
 379 if ( defined $htmlfilename ) {
 380   if ( $htmlfilename eq '' ) {
 381     $html_fh = *STDOUT;
 382   } else {
 383     my $today = DateTime->now(time_zone => C4::Context->tz );
 384     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 385   }
 386
 387   print $html_fh "<html>\n";
 388   print $html_fh "<head>\n";
 389   print $html_fh "<style type='text/css'>\n";
 390   print $html_fh "pre {page-break-after: always;}\n";
 391   print $html_fh "pre {white-space: pre-wrap;}\n";
 392   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 393   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 394   print $html_fh "pre {word-wrap: break-work;}\n";
 395   print $html_fh "</style>\n";
 396   print $html_fh "</head>\n";
 397   print $html_fh "<body>\n";
 398 }
 399
 400 foreach my $branchcode (@branches) {
 401
 402     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 403     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 404     my @output_chunks;    # may be sent to mail or stdout or csv file.
 405
 406     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 407
 408     my $sth2 = $dbh->prepare( <<"END_SQL" );
 409 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 410   FROM issues,items,biblio, biblioitems
 411   WHERE items.itemnumber=issues.itemnumber
 412     AND biblio.biblionumber   = items.biblionumber
 413     AND biblio.biblionumber   = biblioitems.biblionumber
 414     AND issues.borrowernumber = ?
 415     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 416 END_SQL
 417
 418     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 419     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 420     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 421
 422     my $rqoverduerules =  $dbh->prepare($query);
 423     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 424
 425     # We get default rules is there is no rule for this branch
 426     if($rqoverduerules->rows == 0){
 427         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 428         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 429         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 430
 431         $rqoverduerules = $dbh->prepare($query);
 432         $rqoverduerules->execute(@myborcat, @myborcatout);
 433     }
 434
 435     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 436     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 437       PERIOD: foreach my $i ( 1 .. 3 ) {
 438
 439             $verbose and warn "branch '$branchcode', pass $i\n";
 440             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 441             my $maxdays = (
 442                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 443                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 444                 : ($MAX)
 445             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 446
 447             if ( !$overdue_rules->{"letter$i"} ) {
 448                 $verbose and warn "No letter$i code for branch '$branchcode'";
 449                 next PERIOD;
 450             }
 451
 452             # $letter->{'content'} is the text of the mail that is sent.
 453             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 454             # The following fields are available :
 455             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 456             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 457
 458             my $borrower_sql = <<'END_SQL';
 459 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email
 460 FROM   issues,borrowers,categories
 461 WHERE  issues.borrowernumber=borrowers.borrowernumber
 462 AND    borrowers.categorycode=categories.categorycode
 463 END_SQL
 464             my @borrower_parameters;
 465             if ($branchcode) {
 466                 $borrower_sql .= ' AND issues.branchcode=? ';
 467                 push @borrower_parameters, $branchcode;
 468             }
 469             if ( $overdue_rules->{categorycode} ) {
 470                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 471                 push @borrower_parameters, $overdue_rules->{categorycode};
 472             }
 473             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 474             if($triggered) {
 475                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 476                 push @borrower_parameters, $mindays;
 477             } else {
 478                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 479                 push @borrower_parameters, $mindays, $maxdays;
 480             }
 481
 482             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 483                 my $sth = $dbh->prepare($borrower_sql);
 484             $sth->execute(@borrower_parameters);
 485             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 486
 487             while ( my $data = $sth->fetchrow_hashref ) {
 488                 my $borrowernumber = $data->{'borrowernumber'};
 489                 my $borr =
 490                     $data->{'firstname'} . ', '
 491                   . $data->{'surname'} . ' ('
 492                   . $borrowernumber . ')';
 493                 $verbose
 494                   and warn "borrower $borr has items triggering level $i.";
 495
 496                 @emails_to_use = ();
 497                 my $notice_email =
 498                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 499                 unless ($nomail) {
 500                     if (@emails) {
 501                         foreach (@emails) {
 502                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 503                         }
 504                     }
 505                     else {
 506                         push @emails_to_use, $notice_email if ($notice_email);
 507                     }
 508                 }
 509
 510                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 511
 512                 unless ($letter) {
 513                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 514
 515                     # might as well skip while PERIOD, no other borrowers are going to work.
 516                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 517                     next PERIOD;
 518                 }
 519
 520                 if ( $overdue_rules->{"debarred$i"} ) {
 521
 522                     #action taken is debarring
 523                     AddUniqueDebarment(
 524                         {
 525                             borrowernumber => $borrowernumber,
 526                             type           => 'OVERDUES',
 527                             comment => "Restriction added by overdues process "
 528                               . output_pref( dt_from_string() ),
 529                         }
 530                     );
 531                     $verbose and warn "debarring $borr\n";
 532                 }
 533                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 534                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 535                 $sth2->execute(@params);
 536                 my $itemcount = 0;
 537                 my $titles = "";
 538                 my @items = ();
 539
 540                 my $j = 0;
 541                 my $exceededPrintNoticesMaxLines = 0;
 542                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 543                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 544                       $exceededPrintNoticesMaxLines = 1;
 545                       last;
 546                     }
 547                     $j++;
 548                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 549                     $titles .= join("\t", @item_info) . "\n";
 550                     $itemcount++;
 551                     push @items, $item_info;
 552                 }
 553                 $sth2->finish;
 554
 555                 $letter = parse_letter(
 556                     {   letter_code     => $overdue_rules->{"letter$i"},
 557                         borrowernumber  => $borrowernumber,
 558                         branchcode      => $branchcode,
 559                         items           => \@items,
 560                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 561                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 562                                             'items.content' => $titles,
 563                                             'count'         => $itemcount,
 564                                            }
 565                     }
 566                 );
 567                 unless ($letter) {
 568                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 569
 570                     # might as well skip while PERIOD, no other borrowers are going to work.
 571                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 572                     next PERIOD;
 573                 }
 574
 575                 if ( $exceededPrintNoticesMaxLines ) {
 576                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 577                 }
 578
 579                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 580                 if (@misses) {
 581                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 582                 }
 583
 584                 if ( !$nomail && scalar @emails_to_use ) {
 585                     C4::Letters::EnqueueLetter(
 586                         {   letter                 => $letter,
 587                             borrowernumber         => $borrowernumber,
 588                             message_transport_type => 'email',
 589                             from_address           => $admin_email_address,
 590                             to_address             => join(',', @emails_to_use),
 591                         }
 592                     );
 593                 } else {
 594                     # if not sent by email then print
 595                     push @output_chunks,
 596                       prepare_letter_for_printing(
 597                         {   letter         => $letter,
 598                             borrowernumber => $borrowernumber,
 599                             firstname      => $data->{'firstname'},
 600                             lastname       => $data->{'surname'},
 601                             address1       => $data->{'address'},
 602                             address2       => $data->{'address2'},
 603                             city           => $data->{'city'},
 604                             postcode       => $data->{'zipcode'},
 605                             country        => $data->{'country'},
 606                             email          => $notice_email,
 607                             itemcount      => $itemcount,
 608                             titles         => $titles,
 609                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 610                         }
 611                       );
 612                 }
 613             }
 614             $sth->finish;
 615         }
 616     }
 617
 618     if (@output_chunks) {
 619         if ( defined $csvfilename ) {
 620             print $csv_fh @output_chunks;
 621         }
 622         elsif ( defined $htmlfilename ) {
 623             print $html_fh @output_chunks;
 624         }
 625         elsif ($nomail){
 626                 local $, = "\f";    # pagebreak
 627                 print @output_chunks;
 628         }
 629         # Generate the content of the csv with headers
 630         my $content = join(";", qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 631         $content .= join( "\n", @output_chunks );
 632
 633         my $attachment = {
 634             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 635             type => 'text/plain',
 636             content => $content,
 637         };
 638
 639         my $letter = {
 640             title   => 'Overdue Notices',
 641             content => 'These messages were not sent directly to the patrons.',
 642         };
 643         C4::Letters::EnqueueLetter(
 644             {   letter                 => $letter,
 645                 borrowernumber         => undef,
 646                 message_transport_type => 'email',
 647                 attachments            => [$attachment],
 648                 to_address             => $admin_email_address,
 649             }
 650         );
 651     }
 652
 653 }
 654 if ($csvfilename) {
 655     # note that we're not testing on $csv_fh to prevent closing
 656     # STDOUT.
 657     close $csv_fh;
 658 }
 659
 660 if ( defined $htmlfilename ) {
 661   print $html_fh "</body>\n";
 662   print $html_fh "</html>\n";
 663   close $html_fh;
 664 }
 665
 666 =head1 INTERNAL METHODS
 667
 668 These methods are internal to the operation of overdue_notices.pl.
 669
 670 =head2 parse_letter
 671
 672 parses the letter template, replacing the placeholders with data
 673 specific to this patron, biblio, or item
 674
 675 named parameters:
 676   letter - required hashref
 677   borrowernumber - required integer
 678   substitute - optional hashref of other key/value pairs that should
 679     be substituted in the letter content
 680
 681 returns the C<letter> hashref, with the content updated to reflect the
 682 substituted keys and values.
 683
 684
 685 =cut
 686
 687 sub parse_letter {
 688     my $params = shift;
 689     foreach my $required (qw( letter_code borrowernumber )) {
 690         return unless ( exists $params->{$required} && $params->{$required} );
 691     }
 692
 693     my $substitute = $params->{'substitute'} || {};
 694     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 695
 696     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 697     if ( my $p = $params->{'branchcode'} ) {
 698         $tables{'branches'} = $p;
 699     }
 700
 701     my $currencies = GetCurrency();
 702     my $currency_format;
 703     $currency_format = $currencies->{currency} if defined($currencies);
 704
 705     my @item_tables;
 706     if ( my $i = $params->{'items'} ) {
 707         my $item_format = '';
 708         foreach my $item (@$i) {
 709             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 710             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 711                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 712                 $item_format = $1;
 713             }
 714
 715             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 716             # if active currency isn't correct ISO code fallback to sprintf
 717             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 718
 719             push @item_tables, {
 720                 'biblio' => $item->{'biblionumber'},
 721                 'biblioitems' => $item->{'biblionumber'},
 722                 'items' => $item,
 723                 'issues' => $item->{'itemnumber'},
 724             };
 725         }
 726     }
 727
 728     return C4::Letters::GetPreparedLetter (
 729         module => 'circulation',
 730         letter_code => $params->{'letter_code'},
 731         branchcode => $params->{'branchcode'},
 732         tables => \%tables,
 733         substitute => $substitute,
 734         repeat => { item => \@item_tables },
 735     );
 736 }
 737
 738 =head2 prepare_letter_for_printing
 739
 740 returns a string of text appropriate for printing in the event that an
 741 overdue notice will not be sent to the patron's email
 742 address. Depending on the desired output format, this may be a CSV
 743 string, or a human-readable representation of the notice.
 744
 745 required parameters:
 746   letter
 747   borrowernumber
 748
 749 optional parameters:
 750   outputformat
 751
 752 =cut
 753
 754 sub prepare_letter_for_printing {
 755     my $params = shift;
 756
 757     return unless ref $params eq 'HASH';
 758
 759     foreach my $required_parameter (qw( letter borrowernumber )) {
 760         return unless defined $params->{$required_parameter};
 761     }
 762
 763     my $return;
 764     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 765         if ($csv->combine(
 766                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 767                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 768             )
 769           ) {
 770             return $csv->string, "\n";
 771         } else {
 772             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 773         }
 774     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 775       $return = "<pre>\n";
 776       my $content = $params->{'letter'}->{'content'};
 777       $content =~ s/\n/<br \/>/g;
 778       $content =~ s/\r//g;
 779       $return .= "$content\n";
 780       $return .= "\n</pre>\n";
 781     } else {
 782         $return .= "$params->{'letter'}->{'content'}\n";
 783
 784         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 785     }
 786     return $return;
 787 }
 788