misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43
  44 =head1 NAME
  45
  46 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  47
  48 =head1 SYNOPSIS
  49
  50 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -library <branchcode>...] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  51
  52  Options:
  53    -help                          brief help message
  54    -man                           full documentation
  55    -n                             No email will be sent
  56    -max          <days>           maximum days overdue to deal with
  57    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  58    -csv          <filename>       populate CSV file
  59    -html         <filename>       Output html to file
  60    -itemscontent <list of fields> item information in templates
  61    -borcat       <categorycode>   category code that must be included
  62    -borcatout    <categorycode>   category code that must be excluded
  63
  64 =head1 OPTIONS
  65
  66 =over 8
  67
  68 =item B<-help>
  69
  70 Print a brief help message and exits.
  71
  72 =item B<-man>
  73
  74 Prints the manual page and exits.
  75
  76 =item B<-v>
  77
  78 Verbose. Without this flag set, only fatal errors are reported.
  79
  80 =item B<-n>
  81
  82 Do not send any email. Overdue notices that would have been sent to
  83 the patrons or to the admin are printed to standard out. CSV data (if
  84 the -csv flag is set) is written to standard out or to any csv
  85 filename given.
  86
  87 =item B<-max>
  88
  89 Items older than max days are assumed to be handled somewhere else,
  90 probably the F<longoverdues.pl> script. They are therefore ignored by
  91 this program. No notices are sent for them, and they are not added to
  92 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  93
  94 =item B<-library>
  95
  96 select overdues for one specific library. Use the value in the
  97 branches.branchcode table. This option can be repeated in order
  98 to select overdues for a group of libraries.
  99
 100 =item B<-csv>
 101
 102 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 103 sent to standard out or to a filename if provided. Otherwise, only
 104 overdues that could not be emailed are sent in CSV format to the admin.
 105
 106 =item B<-html>
 107
 108 Produces html data. if patron does not have a mail address or
 109 -n (no mail) flag is set, an html file is generated in the specified
 110 directory. This can be downloaded or futher processed by library staff.
 111
 112 =item B<-itemscontent>
 113
 114 comma separated list of fields that get substituted into templates in
 115 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 116 defaults to due date,title,barcode,author
 117
 118 Other possible values come from fields in the biblios, items and
 119 issues tables.
 120
 121 =item B<-borcat>
 122
 123 Repetable field, that permit to select only few of patrons categories.
 124
 125 =item B<-borcatout>
 126
 127 Repetable field, permis to exclude some patrons categories.
 128
 129 =item B<-t> | B<--triggered>
 130
 131 This option causes a notice to be generated if and only if
 132 an item is overdue by the number of days defined in a notice trigger.
 133
 134 By default, a notice is sent each time the script runs, which is suitable for
 135 less frequent run cron script, but requires syncing notice triggers with
 136 the  cron schedule to ensure proper behavior.
 137 Add the --triggered option for daily cron, at the risk of no notice
 138 being generated if the cron fails to run on time.
 139
 140 =item B<-list-all>
 141
 142 Default items.content lists only those items that fall in the
 143 range of the currently processing notice.
 144 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 145
 146 =item B<-date>
 147
 148 use it in order to send overdues on a specific date and not Now.
 149
 150 =back
 151
 152 =head1 DESCRIPTION
 153
 154 This script is designed to alert patrons and administrators of overdue
 155 items.
 156
 157 =head2 Configuration
 158
 159 This script pays attention to the overdue notice configuration
 160 performed in the "Overdue notice/status triggers" section of the
 161 "Tools" area of the staff interface to Koha. There, you can choose
 162 which letter templates are sent out after a configurable number of
 163 days to patrons of each library. More information about the use of this
 164 section of Koha is available in the Koha manual.
 165
 166 The templates used to craft the emails are defined in the "Tools:
 167 Notices" section of the staff interface to Koha.
 168
 169 =head2 Outgoing emails
 170
 171 Typically, messages are prepared for each patron with overdue
 172 items. Messages for whom there is no email address on file are
 173 collected and sent as attachments in a single email to each library
 174 administrator, or if that is not set, then to the email address in the
 175 C<KohaAdminEmailAddress> system preference.
 176
 177 These emails are staged in the outgoing message queue, as are messages
 178 produced by other features of Koha. This message queue must be
 179 processed regularly by the
 180 F<misc/cronjobs/process_message_queue.pl> program.
 181
 182 In the event that the C<-n> flag is passed to this program, no emails
 183 are sent. Instead, messages are sent on standard output from this
 184 program. They may be redirected to a file if desired.
 185
 186 =head2 Templates
 187
 188 Templates can contain variables enclosed in double angle brackets like
 189 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 190 specific to the overdue items or relevant patron. Available variables
 191 are:
 192
 193 =over
 194
 195 =item E<lt>E<lt>bibE<gt>E<gt>
 196
 197 the name of the library
 198
 199 =item E<lt>E<lt>items.contentE<gt>E<gt>
 200
 201 one line for each item, each line containing a tab separated list of
 202 title, author, barcode, issuedate
 203
 204 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 205
 206 any field from the borrowers table
 207
 208 =item E<lt>E<lt>branches.*E<gt>E<gt>
 209
 210 any field from the branches table
 211
 212 =back
 213
 214 =head2 CSV output
 215
 216 The C<-csv> command line option lets you specify a file to which
 217 overdues data should be output in CSV format.
 218
 219 With the C<-n> flag set, data about all overdues is written to the
 220 file. Without that flag, only information about overdues that were
 221 unable to be sent directly to the patrons will be written. In other
 222 words, this CSV file replaces the data that is typically sent to the
 223 administrator email address.
 224
 225 =head1 USAGE EXAMPLES
 226
 227 C<overdue_notices.pl> - In this most basic usage, with no command line
 228 arguments, all libraries are procesed individually, and notices are
 229 prepared for all patrons with overdue items for whom we have email
 230 addresses. Messages for those patrons for whom we have no email
 231 address are sent in a single attachment to the library administrator's
 232 email address, or to the address in the KohaAdminEmailAddress system
 233 preference.
 234
 235 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 236 populates F</tmp/overdues.csv> with information about all overdue
 237 items.
 238
 239 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 240 overdues in the last 2 weeks for the MAIN library.
 241
 242 =head1 SEE ALSO
 243
 244 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 245 messages to patrons in advance of thier items becoming due, or to
 246 alert them of items that have just become due.
 247
 248 =cut
 249
 250 # These variables are set by command line options.
 251 # They are initially set to default values.
 252 my $dbh = C4::Context->dbh();
 253 my $help    = 0;
 254 my $man     = 0;
 255 my $verbose = 0;
 256 my $nomail  = 0;
 257 my $MAX     = 90;
 258 my @branchcodes; # Branch(es) passed as parameter
 259 my $csvfilename;
 260 my $htmlfilename;
 261 my $triggered = 0;
 262 my $listall = 0;
 263 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 264 my @myborcat;
 265 my @myborcatout;
 266 my $date;
 267
 268 GetOptions(
 269     'help|?'         => \$help,
 270     'man'            => \$man,
 271     'v'              => \$verbose,
 272     'n'              => \$nomail,
 273     'max=s'          => \$MAX,
 274     'library=s'      => \@branchcodes,
 275     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 276     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 277     'itemscontent=s' => \$itemscontent,
 278     'list-all'       => \$listall,
 279     't|triggered'    => \$triggered,
 280     'date'           => \$date,
 281     'borcat=s'       => \@myborcat,
 282     'borcatout=s'    => \@myborcatout,
 283 ) or pod2usage(2);
 284 pod2usage(1) if $help;
 285 pod2usage( -verbose => 2 ) if $man;
 286
 287 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 288     warn qq(using "$csvfilename" as filename, that seems odd);
 289 }
 290
 291 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 292 my @branches;                                                                   # Branches passed as parameter with overdue rules
 293 my $branchcount = scalar(@overduebranches);
 294
 295 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 296 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 297
 298 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 299
 300 if ($branchcount) {
 301     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 302 } else {
 303     die 'No branches with active overduerules';
 304 }
 305
 306 if (@branchcodes) {
 307     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 308
 309     # Getting libraries which have overdue rules
 310     my %seen = map { $_ => 1 } @branchcodes;
 311     @branches = grep { $seen{$_} } @overduebranches;
 312
 313
 314     if (@branches) {
 315
 316         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 317         $verbose and warn "$branch_word @branches have overdue rules\n";
 318
 319     } else {
 320
 321         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 322         ( scalar grep { '' eq $_ } @branches )
 323           or die "No active overduerules for DEFAULT either!";
 324         $verbose and warn "Falling back on default rules for @branchcodes\n";
 325         @branches = ('');
 326     }
 327 }
 328
 329 if ($date){
 330     $date=$dbh->quote($date);
 331 }
 332 else {
 333     $date="NOW()";
 334 }
 335
 336 # these are the fields that will be substituted into <<item.content>>
 337 my @item_content_fields = split( /,/, $itemscontent );
 338
 339 binmode( STDOUT, ':encoding(UTF-8)' );
 340
 341
 342 our $csv;       # the Text::CSV_XS object
 343 our $csv_fh;    # the filehandle to the CSV file.
 344 if ( defined $csvfilename ) {
 345     my $sep_char = C4::Context->preference('delimiter') || ',';
 346     $sep_char = "\t" if ($sep_char eq 'tabulation');
 347     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 348     if ( $csvfilename eq '' ) {
 349         $csv_fh = *STDOUT;
 350     } else {
 351         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 352     }
 353     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 354         print $csv_fh $csv->string, "\n";
 355     } else {
 356         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 357     }
 358 }
 359
 360 @branches = @overduebranches unless @branches;
 361 our $html_fh;
 362 if ( defined $htmlfilename ) {
 363   if ( $htmlfilename eq '' ) {
 364     $html_fh = *STDOUT;
 365   } else {
 366     my $today = DateTime->now(time_zone => C4::Context->tz );
 367     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 368   }
 369
 370   print $html_fh "<html>\n";
 371   print $html_fh "<head>\n";
 372   print $html_fh "<style type='text/css'>\n";
 373   print $html_fh "pre {page-break-after: always;}\n";
 374   print $html_fh "pre {white-space: pre-wrap;}\n";
 375   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 376   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 377   print $html_fh "pre {word-wrap: break-work;}\n";
 378   print $html_fh "</style>\n";
 379   print $html_fh "</head>\n";
 380   print $html_fh "<body>\n";
 381 }
 382
 383 foreach my $branchcode (@branches) {
 384
 385     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 386     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 387     my @output_chunks;    # may be sent to mail or stdout or csv file.
 388
 389     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 390
 391     my $sth2 = $dbh->prepare( <<"END_SQL" );
 392 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 393   FROM issues,items,biblio, biblioitems
 394   WHERE items.itemnumber=issues.itemnumber
 395     AND biblio.biblionumber   = items.biblionumber
 396     AND biblio.biblionumber   = biblioitems.biblionumber
 397     AND issues.borrowernumber = ?
 398     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 399 END_SQL
 400
 401     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 402     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 403     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 404
 405     my $rqoverduerules =  $dbh->prepare($query);
 406     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 407
 408     # We get default rules is there is no rule for this branch
 409     if($rqoverduerules->rows == 0){
 410         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 411         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 412         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 413
 414         $rqoverduerules = $dbh->prepare($query);
 415         $rqoverduerules->execute(@myborcat, @myborcatout);
 416     }
 417
 418     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 419     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 420       PERIOD: foreach my $i ( 1 .. 3 ) {
 421
 422             $verbose and warn "branch '$branchcode', pass $i\n";
 423             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 424             my $maxdays = (
 425                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 426                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 427                 : ($MAX)
 428             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 429
 430             if ( !$overdue_rules->{"letter$i"} ) {
 431                 $verbose and warn "No letter$i code for branch '$branchcode'";
 432                 next PERIOD;
 433             }
 434
 435             my $letter_template = C4::Letters::GetLetter (
 436                 module => 'circulation',
 437                 letter_code => $overdue_rules->{"letter$i"},
 438                 branchcode => $branchcode
 439             );
 440
 441             # $letter->{'content'} is the text of the mail that is sent.
 442             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 443             # The following fields are available :
 444             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 445             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 446
 447             my $borrower_sql = <<'END_SQL';
 448 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email
 449 FROM   issues,borrowers,categories
 450 WHERE  issues.borrowernumber=borrowers.borrowernumber
 451 AND    borrowers.categorycode=categories.categorycode
 452 END_SQL
 453             my @borrower_parameters;
 454             if ($branchcode) {
 455                 $borrower_sql .= ' AND issues.branchcode=? ';
 456                 push @borrower_parameters, $branchcode;
 457             }
 458             if ( $overdue_rules->{categorycode} ) {
 459                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 460                 push @borrower_parameters, $overdue_rules->{categorycode};
 461             }
 462             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 463             if($triggered) {
 464                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 465                 push @borrower_parameters, $mindays;
 466             } else {
 467                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 468                 push @borrower_parameters, $mindays, $maxdays;
 469             }
 470
 471             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 472                 my $sth = $dbh->prepare($borrower_sql);
 473             $sth->execute(@borrower_parameters);
 474             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 475
 476             while ( my ( $borrowernumber, $firstname, $lastname,
 477                     $address1, $address2, $city, $postcode, $country, $email
 478                     ) = $sth->fetchrow )
 479             {
 480                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has items triggering level $i.";
 481
 482                 if ( $overdue_rules->{"debarred$i"} ) {
 483
 484                     #action taken is debarring
 485                     C4::Members::DebarMember($borrowernumber, '9999-12-31');
 486                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 487                 }
 488                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 489                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 490                 $sth2->execute(@params);
 491                 my $itemcount = 0;
 492                 my $titles = "";
 493                 my @items = ();
 494
 495                 my $j = 0;
 496                 my $exceededPrintNoticesMaxLines = 0;
 497                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 498                     if ( ( !$email || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 499                       $exceededPrintNoticesMaxLines = 1;
 500                       last;
 501                     }
 502                     $j++;
 503                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 504                     $titles .= join("\t", @item_info) . "\n";
 505                     $itemcount++;
 506                     push @items, $item_info;
 507                 }
 508                 $sth2->finish;
 509
 510                 my $letter = parse_letter(
 511                     {   letter_code     => $overdue_rules->{"letter$i"},
 512                         letter          => $letter_template,
 513                         borrowernumber  => $borrowernumber,
 514                         branchcode      => $branchcode,
 515                         items           => \@items,
 516                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 517                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 518                                             'items.content' => $titles,
 519                                             'count'         => $itemcount,
 520                                            }
 521                     }
 522                 );
 523                 unless ($letter) {
 524                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 525
 526                     # might as well skip while PERIOD, no other borrowers are going to work.
 527                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 528                     next PERIOD;
 529                 }
 530
 531                 if ( $exceededPrintNoticesMaxLines ) {
 532                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 533                 }
 534
 535                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 536                 if (@misses) {
 537                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 538                 }
 539                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 540                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 541
 542                 if ($nomail) {
 543
 544                     push @output_chunks,
 545                       prepare_letter_for_printing(
 546                         {   letter         => $letter,
 547                             borrowernumber => $borrowernumber,
 548                             firstname      => $firstname,
 549                             lastname       => $lastname,
 550                             address1       => $address1,
 551                             address2       => $address2,
 552                             city           => $city,
 553                             postcode       => $postcode,
 554                             email          => $email,
 555                             itemcount      => $itemcount,
 556                             titles         => $titles,
 557                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 558                         }
 559                       );
 560                 } else {
 561                     if ($email) {
 562                         C4::Letters::EnqueueLetter(
 563                             {   letter                 => $letter,
 564                                 borrowernumber         => $borrowernumber,
 565                                 message_transport_type => 'email',
 566                                 from_address           => $admin_email_address,
 567                             }
 568                         );
 569                     } else {
 570
 571                         # If we don't have an email address for this patron, send it to the admin to deal with.
 572                         push @output_chunks,
 573                           prepare_letter_for_printing(
 574                             {   letter         => $letter,
 575                                 borrowernumber => $borrowernumber,
 576                                 firstname      => $firstname,
 577                                 lastname       => $lastname,
 578                                 address1       => $address1,
 579                                 address2       => $address2,
 580                                 city           => $city,
 581                                 postcode       => $postcode,
 582                                 email          => $email,
 583                                 itemcount      => $itemcount,
 584                                 titles         => $titles,
 585                                 outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 586                             }
 587                           );
 588                     }
 589                 }
 590             }
 591             $sth->finish;
 592         }
 593     }
 594
 595     if (@output_chunks) {
 596         if ( defined $csvfilename ) {
 597             print $csv_fh @output_chunks;
 598         }
 599         elsif ( defined $htmlfilename ) {
 600             print $html_fh @output_chunks;
 601         }
 602         elsif ($nomail){
 603                 local $, = "\f";    # pagebreak
 604                 print @output_chunks;
 605         }
 606         # Generate the content of the csv with headers
 607         my $content = join(";", qw(title name surname address1 address2 zipcode city email itemcount itemsinfo due_date issue_date)) . "\n";
 608         $content .= join( "\n", @output_chunks );
 609
 610         my $attachment = {
 611             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 612             type => 'text/plain; charset="utf-8"',
 613             content => $content,
 614         };
 615
 616         my $letter = {
 617             'content-type' => 'text/plain; charset="utf-8"',
 618             title   => 'Overdue Notices',
 619             content => 'These messages were not sent directly to the patrons.',
 620         };
 621         C4::Letters::EnqueueLetter(
 622             {   letter                 => $letter,
 623                 borrowernumber         => undef,
 624                 message_transport_type => 'email',
 625                 attachments            => [$attachment],
 626                 to_address             => $admin_email_address,
 627             }
 628         );
 629     }
 630
 631 }
 632 if ($csvfilename) {
 633     # note that we're not testing on $csv_fh to prevent closing
 634     # STDOUT.
 635     close $csv_fh;
 636 }
 637
 638 if ( defined $htmlfilename ) {
 639   print $html_fh "</body>\n";
 640   print $html_fh "</html>\n";
 641   close $html_fh;
 642 }
 643
 644 =head1 INTERNAL METHODS
 645
 646 These methods are internal to the operation of overdue_notices.pl.
 647
 648 =head2 parse_letter
 649
 650 parses the letter template, replacing the placeholders with data
 651 specific to this patron, biblio, or item
 652
 653 named parameters:
 654   letter - required hashref
 655   borrowernumber - required integer
 656   substitute - optional hashref of other key/value pairs that should
 657     be substituted in the letter content
 658
 659 returns the C<letter> hashref, with the content updated to reflect the
 660 substituted keys and values.
 661
 662
 663 =cut
 664
 665 sub parse_letter {
 666     my $params = shift;
 667     foreach my $required (qw( letter_code borrowernumber )) {
 668         return unless ( exists $params->{$required} && $params->{$required} );
 669     }
 670
 671     my $substitute = $params->{'substitute'} || {};
 672     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 673
 674     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 675     if ( my $p = $params->{'branchcode'} ) {
 676         $tables{'branches'} = $p;
 677     }
 678
 679     my $currency_format;
 680     if ($params->{'letter'}->{'content'} =~ m/<fine>(.*)<\/fine>/o) { # process any fine tags...
 681         $currency_format = $1;
 682         $params->{'letter'}->{'content'} =~ s/<fine>.*<\/fine>/<<items.fine>>/o;
 683     }
 684
 685     my @item_tables;
 686     if ( my $i = $params->{'items'} ) {
 687         my $item_format = '';
 688         foreach my $item (@$i) {
 689             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 690             if (!$item_format) {
 691                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 692                 $item_format = $1;
 693             }
 694
 695             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL)
 696               if $currency_format;
 697
 698             push @item_tables, {
 699                 'biblio' => $item->{'biblionumber'},
 700                 'biblioitems' => $item->{'biblionumber'},
 701                 'items' => $item,
 702                 'issues' => $item->{'itemnumber'},
 703             };
 704         }
 705     }
 706
 707     return C4::Letters::GetProcessedLetter (
 708         module => 'circulation',
 709         letter_code => $params->{'letter_code'},
 710         letter => $params->{'letter'},
 711         branchcode => $params->{'branchcode'},
 712         tables => \%tables,
 713         substitute => $substitute,
 714         repeat => { item => \@item_tables }
 715     );
 716 }
 717
 718 =head2 prepare_letter_for_printing
 719
 720 returns a string of text appropriate for printing in the event that an
 721 overdue notice will not be sent to the patron's email
 722 address. Depending on the desired output format, this may be a CSV
 723 string, or a human-readable representation of the notice.
 724
 725 required parameters:
 726   letter
 727   borrowernumber
 728
 729 optional parameters:
 730   outputformat
 731
 732 =cut
 733
 734 sub prepare_letter_for_printing {
 735     my $params = shift;
 736
 737     return unless ref $params eq 'HASH';
 738
 739     foreach my $required_parameter (qw( letter borrowernumber )) {
 740         return unless defined $params->{$required_parameter};
 741     }
 742
 743     my $return;
 744     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 745         if ($csv->combine(
 746                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 747                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 748             )
 749           ) {
 750             return $csv->string, "\n";
 751         } else {
 752             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 753         }
 754     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 755       $return = "<pre>\n";
 756       $return .= "$params->{'letter'}->{'content'}\n";
 757       $return .= "\n</pre>\n";
 758     } else {
 759         $return .= "$params->{'letter'}->{'content'}\n";
 760
 761         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 762     }
 763     return $return;
 764 }
 765