misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37 use DateTime;
  38 use DateTime::Duration;
  39
  40 use C4::Context;
  41 use C4::Dates qw/format_date/;
  42 use C4::Debug;
  43 use C4::Letters;
  44 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes);
  45 use C4::Budgets qw(GetCurrency);
  46 use C4::Log;
  47 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  48 use Koha::DateUtils;
  49 use Koha::Calendar;
  50
  51 =head1 NAME
  52
  53 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  54
  55 =head1 SYNOPSIS
  56
  57 overdue_notices.pl
  58   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  59   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  60   [ -email <email_type> ... ]
  61
  62  Options:
  63    -help                          brief help message
  64    -man                           full documentation
  65    -n                             No email will be sent
  66    -max          <days>           maximum days overdue to deal with
  67    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  68    -csv          <filename>       populate CSV file
  69    -html         <directory>      Output html to a file in the given directory
  70    -text         <directory>      Output plain text to a file in the given directory
  71    -itemscontent <list of fields> item information in templates
  72    -borcat       <categorycode>   category code that must be included
  73    -borcatout    <categorycode>   category code that must be excluded
  74    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  75
  76 =head1 OPTIONS
  77
  78 =over 8
  79
  80 =item B<-help>
  81
  82 Print a brief help message and exits.
  83
  84 =item B<-man>
  85
  86 Prints the manual page and exits.
  87
  88 =item B<-v>
  89
  90 Verbose. Without this flag set, only fatal errors are reported.
  91
  92 =item B<-n>
  93
  94 Do not send any email. Overdue notices that would have been sent to
  95 the patrons or to the admin are printed to standard out. CSV data (if
  96 the -csv flag is set) is written to standard out or to any csv
  97 filename given.
  98
  99 =item B<-max>
 100
 101 Items older than max days are assumed to be handled somewhere else,
 102 probably the F<longoverdues.pl> script. They are therefore ignored by
 103 this program. No notices are sent for them, and they are not added to
 104 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 105
 106 =item B<-library>
 107
 108 select overdues for one specific library. Use the value in the
 109 branches.branchcode table. This option can be repeated in order
 110 to select overdues for a group of libraries.
 111
 112 =item B<-csv>
 113
 114 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 115 sent to standard out or to a filename if provided. Otherwise, only
 116 overdues that could not be emailed are sent in CSV format to the admin.
 117
 118 =item B<-html>
 119
 120 Produces html data. If patron does not have an email address or
 121 -n (no mail) flag is set, an HTML file is generated in the specified
 122 directory. This can be downloaded or further processed by library staff.
 123 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 124 specified.
 125
 126 =item B<-text>
 127
 128 Produces plain text data. If patron does not have an email address or
 129 -n (no mail) flag is set, a text file is generated in the specified
 130 directory. This can be downloaded or further processed by library staff.
 131 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 132 specified.
 133
 134 =item B<-itemscontent>
 135
 136 comma separated list of fields that get substituted into templates in
 137 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 138 defaults to due date,title,barcode,author
 139
 140 Other possible values come from fields in the biblios, items and
 141 issues tables.
 142
 143 =item B<-borcat>
 144
 145 Repetable field, that permit to select only few of patrons categories.
 146
 147 =item B<-borcatout>
 148
 149 Repetable field, permis to exclude some patrons categories.
 150
 151 =item B<-t> | B<--triggered>
 152
 153 This option causes a notice to be generated if and only if
 154 an item is overdue by the number of days defined in a notice trigger.
 155
 156 By default, a notice is sent each time the script runs, which is suitable for
 157 less frequent run cron script, but requires syncing notice triggers with
 158 the  cron schedule to ensure proper behavior.
 159 Add the --triggered option for daily cron, at the risk of no notice
 160 being generated if the cron fails to run on time.
 161
 162 =item B<-list-all>
 163
 164 Default items.content lists only those items that fall in the
 165 range of the currently processing notice.
 166 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 167
 168 =item B<-date>
 169
 170 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 171
 172 =item B<-email>
 173
 174 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 175
 176 =back
 177
 178 =head1 DESCRIPTION
 179
 180 This script is designed to alert patrons and administrators of overdue
 181 items.
 182
 183 =head2 Configuration
 184
 185 This script pays attention to the overdue notice configuration
 186 performed in the "Overdue notice/status triggers" section of the
 187 "Tools" area of the staff interface to Koha. There, you can choose
 188 which letter templates are sent out after a configurable number of
 189 days to patrons of each library. More information about the use of this
 190 section of Koha is available in the Koha manual.
 191
 192 The templates used to craft the emails are defined in the "Tools:
 193 Notices" section of the staff interface to Koha.
 194
 195 =head2 Outgoing emails
 196
 197 Typically, messages are prepared for each patron with overdue
 198 items. Messages for whom there is no email address on file are
 199 collected and sent as attachments in a single email to each library
 200 administrator, or if that is not set, then to the email address in the
 201 C<KohaAdminEmailAddress> system preference.
 202
 203 These emails are staged in the outgoing message queue, as are messages
 204 produced by other features of Koha. This message queue must be
 205 processed regularly by the
 206 F<misc/cronjobs/process_message_queue.pl> program.
 207
 208 In the event that the C<-n> flag is passed to this program, no emails
 209 are sent. Instead, messages are sent on standard output from this
 210 program. They may be redirected to a file if desired.
 211
 212 =head2 Templates
 213
 214 Templates can contain variables enclosed in double angle brackets like
 215 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 216 specific to the overdue items or relevant patron. Available variables
 217 are:
 218
 219 =over
 220
 221 =item E<lt>E<lt>bibE<gt>E<gt>
 222
 223 the name of the library
 224
 225 =item E<lt>E<lt>items.contentE<gt>E<gt>
 226
 227 one line for each item, each line containing a tab separated list of
 228 title, author, barcode, issuedate
 229
 230 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 231
 232 any field from the borrowers table
 233
 234 =item E<lt>E<lt>branches.*E<gt>E<gt>
 235
 236 any field from the branches table
 237
 238 =back
 239
 240 =head2 CSV output
 241
 242 The C<-csv> command line option lets you specify a file to which
 243 overdues data should be output in CSV format.
 244
 245 With the C<-n> flag set, data about all overdues is written to the
 246 file. Without that flag, only information about overdues that were
 247 unable to be sent directly to the patrons will be written. In other
 248 words, this CSV file replaces the data that is typically sent to the
 249 administrator email address.
 250
 251 =head1 USAGE EXAMPLES
 252
 253 C<overdue_notices.pl> - In this most basic usage, with no command line
 254 arguments, all libraries are procesed individually, and notices are
 255 prepared for all patrons with overdue items for whom we have email
 256 addresses. Messages for those patrons for whom we have no email
 257 address are sent in a single attachment to the library administrator's
 258 email address, or to the address in the KohaAdminEmailAddress system
 259 preference.
 260
 261 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 262 populates F</tmp/overdues.csv> with information about all overdue
 263 items.
 264
 265 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 266 overdues in the last 2 weeks for the MAIN library.
 267
 268 =head1 SEE ALSO
 269
 270 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 271 messages to patrons in advance of their items becoming due, or to
 272 alert them of items that have just become due.
 273
 274 =cut
 275
 276 # These variables are set by command line options.
 277 # They are initially set to default values.
 278 my $dbh = C4::Context->dbh();
 279 my $help    = 0;
 280 my $man     = 0;
 281 my $verbose = 0;
 282 my $nomail  = 0;
 283 my $MAX     = 90;
 284 my @branchcodes; # Branch(es) passed as parameter
 285 my @emails_to_use;    # Emails to use for messaging
 286 my @emails;           # Emails given in command-line parameters
 287 my $csvfilename;
 288 my $htmlfilename;
 289 my $text_filename;
 290 my $triggered = 0;
 291 my $listall = 0;
 292 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 293 my @myborcat;
 294 my @myborcatout;
 295 my ( $date_input, $today );
 296
 297 GetOptions(
 298     'help|?'         => \$help,
 299     'man'            => \$man,
 300     'v'              => \$verbose,
 301     'n'              => \$nomail,
 302     'max=s'          => \$MAX,
 303     'library=s'      => \@branchcodes,
 304     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 305     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 306     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 307     'itemscontent=s' => \$itemscontent,
 308     'list-all'       => \$listall,
 309     't|triggered'    => \$triggered,
 310     'date=s'         => \$date_input,
 311     'borcat=s'       => \@myborcat,
 312     'borcatout=s'    => \@myborcatout,
 313     'email=s'        => \@emails,
 314 ) or pod2usage(2);
 315 pod2usage(1) if $help;
 316 pod2usage( -verbose => 2 ) if $man;
 317
 318 cronlogaction();
 319
 320 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 321     warn qq(using "$csvfilename" as filename, that seems odd);
 322 }
 323
 324 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 325 my @branches;                                                                   # Branches passed as parameter with overdue rules
 326 my $branchcount = scalar(@overduebranches);
 327
 328 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 329 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 330
 331 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 332
 333 if ($branchcount) {
 334     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 335 } else {
 336     die 'No branches with active overduerules';
 337 }
 338
 339 if (@branchcodes) {
 340     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 341
 342     # Getting libraries which have overdue rules
 343     my %seen = map { $_ => 1 } @branchcodes;
 344     @branches = grep { $seen{$_} } @overduebranches;
 345
 346
 347     if (@branches) {
 348
 349         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 350         $verbose and warn "$branch_word @branches have overdue rules\n";
 351
 352     } else {
 353
 354         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 355         ( scalar grep { '' eq $_ } @branches )
 356           or die "No active overduerules for DEFAULT either!";
 357         $verbose and warn "Falling back on default rules for @branchcodes\n";
 358         @branches = ('');
 359     }
 360 }
 361 my $date_to_run;
 362 my $date;
 363 if ( $date_input ){
 364     eval {
 365         $date_to_run = dt_from_string( $date_input, 'iso' );
 366     };
 367     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 368         if $@ or not $date_to_run;
 369
 370     # It's certainly useless to escape $date_input
 371     # dt_from_string should not return something if $date_input is not correctly set.
 372     $date = $dbh->quote( $date_input );
 373 }
 374 else {
 375     $date="NOW()";
 376     $date_to_run = dt_from_string();
 377 }
 378
 379 # these are the fields that will be substituted into <<item.content>>
 380 my @item_content_fields = split( /,/, $itemscontent );
 381
 382 binmode( STDOUT, ':encoding(UTF-8)' );
 383
 384
 385 our $csv;       # the Text::CSV_XS object
 386 our $csv_fh;    # the filehandle to the CSV file.
 387 if ( defined $csvfilename ) {
 388     my $sep_char = C4::Context->preference('delimiter') || ';';
 389     $sep_char = "\t" if ($sep_char eq 'tabulation');
 390     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 391     if ( $csvfilename eq '' ) {
 392         $csv_fh = *STDOUT;
 393     } else {
 394         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 395     }
 396     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 397         print $csv_fh $csv->string, "\n";
 398     } else {
 399         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 400     }
 401 }
 402
 403 @branches = @overduebranches unless @branches;
 404 our $fh;
 405 if ( defined $htmlfilename ) {
 406   if ( $htmlfilename eq '' ) {
 407     $fh = *STDOUT;
 408   } else {
 409     my $today = DateTime->now(time_zone => C4::Context->tz );
 410     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 411   }
 412
 413   print $fh "<html>\n";
 414   print $fh "<head>\n";
 415   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 416   print $fh "<style type='text/css'>\n";
 417   print $fh "pre {page-break-after: always;}\n";
 418   print $fh "pre {white-space: pre-wrap;}\n";
 419   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 420   print $fh "pre {white-space: -o-pre-wrap;}\n";
 421   print $fh "pre {word-wrap: break-work;}\n";
 422   print $fh "</style>\n";
 423   print $fh "</head>\n";
 424   print $fh "<body>\n";
 425 }
 426 elsif ( defined $text_filename ) {
 427   if ( $text_filename eq '' ) {
 428     $fh = *STDOUT;
 429   } else {
 430     my $today = DateTime->now(time_zone => C4::Context->tz );
 431     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 432   }
 433 }
 434
 435 foreach my $branchcode (@branches) {
 436     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 437         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 438         if ( $calendar->is_holiday($date_to_run) ) {
 439             next;
 440         }
 441     }
 442
 443     my $branch_details      = C4::Branch::GetBranchDetail($branchcode);
 444     my $admin_email_address = $branch_details->{'branchemail'}
 445       || C4::Context->preference('KohaAdminEmailAddress');
 446     my @output_chunks;    # may be sent to mail or stdout or csv file.
 447
 448     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 449
 450     my $sth2 = $dbh->prepare( <<"END_SQL" );
 451 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue, branchname
 452   FROM issues,items,biblio, biblioitems, branches b
 453   WHERE items.itemnumber=issues.itemnumber
 454     AND biblio.biblionumber   = items.biblionumber
 455     AND b.branchcode = items.homebranch
 456     AND biblio.biblionumber   = biblioitems.biblionumber
 457     AND issues.borrowernumber = ?
 458 END_SQL
 459
 460     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 461     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 462     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 463
 464     my $rqoverduerules =  $dbh->prepare($query);
 465     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 466
 467     # We get default rules is there is no rule for this branch
 468     if($rqoverduerules->rows == 0){
 469         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 470         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 471         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 472
 473         $rqoverduerules = $dbh->prepare($query);
 474         $rqoverduerules->execute(@myborcat, @myborcatout);
 475     }
 476
 477     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 478     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 479       PERIOD: foreach my $i ( 1 .. 3 ) {
 480
 481             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 482
 483             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 484             my $maxdays = (
 485                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 486                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 487                 : ($MAX)
 488             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 489
 490             next unless defined $mindays;
 491
 492             if ( !$overdue_rules->{"letter$i"} ) {
 493                 $verbose and warn "No letter$i code for branch '$branchcode'";
 494                 next PERIOD;
 495             }
 496
 497             # $letter->{'content'} is the text of the mail that is sent.
 498             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 499             # The following fields are available :
 500             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 501             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 502
 503             my $borrower_sql = <<'END_SQL';
 504 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber,
 505 TO_DAYS(?)-TO_DAYS(date_due) as difference, date_due
 506 FROM   issues,borrowers,categories
 507 WHERE  issues.borrowernumber=borrowers.borrowernumber
 508 AND    borrowers.categorycode=categories.categorycode
 509 END_SQL
 510             my @borrower_parameters;
 511             push @borrower_parameters, $date_to_run->datetime();
 512             if ($branchcode) {
 513                 $borrower_sql .= ' AND issues.branchcode=? ';
 514                 push @borrower_parameters, $branchcode;
 515             }
 516             if ( $overdue_rules->{categorycode} ) {
 517                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 518                 push @borrower_parameters, $overdue_rules->{categorycode};
 519             }
 520             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 521
 522             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 523                 my $sth = $dbh->prepare($borrower_sql);
 524             $sth->execute(@borrower_parameters);
 525
 526             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 527             my $borrowernumber;
 528             while ( my $data = $sth->fetchrow_hashref ) {
 529
 530                 next unless ( DateTime->compare( $date_to_run,  dt_from_string($data->{date_due})) ) == 1;
 531
 532                 # check the borrower has at least one item that matches
 533                 my $days_between;
 534                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 535                 {
 536                     my $calendar =
 537                       Koha::Calendar->new( branchcode => $branchcode );
 538                     $days_between =
 539                       $calendar->days_between(  dt_from_string($data->{date_due}),
 540                         $date_to_run );
 541                 }
 542                 else {
 543                     $days_between =
 544                       $date_to_run->delta_days(  dt_from_string($data->{date_due}) );
 545                 }
 546                 $days_between = $days_between->in_units('days');
 547                 if ($triggered) {
 548                     if ( $mindays != $days_between ) {
 549                         next;
 550                     }
 551                 }
 552                 else {
 553                     unless (   $days_between >= $mindays
 554                         && $days_between <= $maxdays )
 555                     {
 556                         next;
 557                     }
 558                 }
 559                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 560 # we have already dealt with this borrower
 561                     $verbose and warn "already dealt with this borrower $borrowernumber";
 562                     next;
 563                 }
 564                 $borrowernumber = $data->{'borrowernumber'};
 565                 my $borr =
 566                     $data->{'firstname'} . ', '
 567                   . $data->{'surname'} . ' ('
 568                   . $borrowernumber . ')';
 569                 $verbose
 570                   and warn "borrower $borr has items triggering level $i.";
 571
 572                 @emails_to_use = ();
 573                 my $notice_email =
 574                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 575                 unless ($nomail) {
 576                     if (@emails) {
 577                         foreach (@emails) {
 578                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 579                         }
 580                     }
 581                     else {
 582                         push @emails_to_use, $notice_email if ($notice_email);
 583                     }
 584                 }
 585
 586                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 587
 588                 unless ($letter) {
 589                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 590
 591                     # might as well skip while PERIOD, no other borrowers are going to work.
 592                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 593                     next PERIOD;
 594                 }
 595
 596                 if ( $overdue_rules->{"debarred$i"} ) {
 597
 598                     #action taken is debarring
 599                     AddUniqueDebarment(
 600                         {
 601                             borrowernumber => $borrowernumber,
 602                             type           => 'OVERDUES',
 603                             comment => "Restriction added by overdues process "
 604                               . output_pref( dt_from_string() ),
 605                         }
 606                     );
 607                     $verbose and warn "debarring $borr\n";
 608                 }
 609                 my @params = ($borrowernumber);
 610                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 611
 612                 $sth2->execute(@params);
 613                 my $itemcount = 0;
 614                 my $titles = "";
 615                 my @items = ();
 616
 617                 my $j = 0;
 618                 my $exceededPrintNoticesMaxLines = 0;
 619                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 620                     next unless ( DateTime->compare( $date_to_run,  dt_from_string($item_info->{date_due})) ) == 1;
 621
 622                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 623                         my $calendar =
 624                           Koha::Calendar->new( branchcode => $branchcode );
 625                         $days_between =
 626                           $calendar->days_between(
 627                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 628                     }
 629                     else {
 630                         $days_between =
 631                           $date_to_run->delta_days(
 632                             dt_from_string( $item_info->{date_due} ) );
 633                     }
 634                     $days_between = $days_between->in_units('days');
 635                     if ($listall){
 636                         unless ($days_between >= 1 and $days_between <= $MAX){
 637                             next;
 638                         }
 639                     }
 640                     else {
 641                         if ($triggered) {
 642                             if ( $mindays != $days_between ) {
 643                                 next;
 644                             }
 645                         }
 646                         else {
 647                             unless ( $days_between >= $mindays
 648                                 && $days_between <= $maxdays )
 649                             {
 650                                 next;
 651                             }
 652                         }
 653                     }
 654
 655                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 656                       $exceededPrintNoticesMaxLines = 1;
 657                       last;
 658                     }
 659                     $j++;
 660                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 661                     $titles .= join("\t", @item_info) . "\n";
 662                     $itemcount++;
 663                     push @items, $item_info;
 664                 }
 665                 $sth2->finish;
 666
 667                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 668                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 669                     unless @message_transport_types;
 670
 671
 672                 my $print_sent = 0; # A print notice is not yet sent for this patron
 673                 for my $mtt ( @message_transport_types ) {
 674
 675                     my $letter = parse_letter(
 676                         {   letter_code     => $overdue_rules->{"letter$i"},
 677                             borrowernumber  => $borrowernumber,
 678                             branchcode      => $branchcode,
 679                             items           => \@items,
 680                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 681                                                 bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 682                                                 'items.content' => $titles,
 683                                                 'count'         => $itemcount,
 684                                                },
 685                             message_transport_type => $mtt,
 686                         }
 687                     );
 688                     unless ($letter) {
 689                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 690                         # this transport doesn't have a configured notice, so try another
 691                         next;
 692                     }
 693
 694                     if ( $exceededPrintNoticesMaxLines ) {
 695                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 696                     }
 697
 698                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 699                     if (@misses) {
 700                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 701                     }
 702
 703                     if ($nomail) {
 704                         push @output_chunks,
 705                           prepare_letter_for_printing(
 706                           {   letter         => $letter,
 707                               borrowernumber => $borrowernumber,
 708                               firstname      => $data->{'firstname'},
 709                               lastname       => $data->{'surname'},
 710                               address1       => $data->{'address'},
 711                               address2       => $data->{'address2'},
 712                               city           => $data->{'city'},
 713                               phone          => $data->{'phone'},
 714                               cardnumber     => $data->{'cardnumber'},
 715                               branchname     => $branch_details->{'branchname'},
 716                               letternumber   => $i,
 717                               postcode       => $data->{'zipcode'},
 718                               country        => $data->{'country'},
 719                               email          => $notice_email,
 720                               itemcount      => $itemcount,
 721                               titles         => $titles,
 722                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 723                             }
 724                           );
 725                     } else {
 726                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 727                             # email or sms is requested but not exist, do a print.
 728                             $mtt = 'print';
 729                             push @output_chunks,
 730                               prepare_letter_for_printing(
 731                               {   letter         => $letter,
 732                                   borrowernumber => $borrowernumber,
 733                                   firstname      => $data->{'firstname'},
 734                                   lastname       => $data->{'surname'},
 735                                   address1       => $data->{'address'},
 736                                   address2       => $data->{'address2'},
 737                                   city           => $data->{'city'},
 738                                   postcode       => $data->{'zipcode'},
 739                                   country        => $data->{'country'},
 740                                   email          => $notice_email,
 741                                   itemcount      => $itemcount,
 742                                   titles         => $titles,
 743                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 744                                 }
 745                               );
 746                         }
 747                         unless ( $mtt eq 'print' and $print_sent == 1 ) {
 748                             # Just sent a print if not already done.
 749                             C4::Letters::EnqueueLetter(
 750                                 {   letter                 => $letter,
 751                                     borrowernumber         => $borrowernumber,
 752                                     message_transport_type => $mtt,
 753                                     from_address           => $admin_email_address,
 754                                     to_address             => join(',', @emails_to_use),
 755                                 }
 756                             );
 757                             # A print notice should be sent only once per overdue level.
 758                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 759                             $print_sent = 1 if $mtt eq 'print';
 760                         }
 761                     }
 762                 }
 763             }
 764             $sth->finish;
 765         }
 766     }
 767
 768     if (@output_chunks) {
 769         if ( defined $csvfilename ) {
 770             print $csv_fh @output_chunks;
 771         }
 772         elsif ( defined $htmlfilename ) {
 773             print $fh @output_chunks;
 774         }
 775         elsif ( defined $text_filename ) {
 776             print $fh @output_chunks;
 777         }
 778         elsif ($nomail){
 779                 local $, = "\f";    # pagebreak
 780                 print @output_chunks;
 781         }
 782         # Generate the content of the csv with headers
 783         my $content;
 784         if ( defined $csvfilename ) {
 785             my $delimiter = C4::Context->preference('delimiter') || ';';
 786             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 787         }
 788         else {
 789             $content = "";
 790         }
 791         $content .= join( "\n", @output_chunks );
 792
 793         my $attachment = {
 794             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 795             type => 'text/plain',
 796             content => $content,
 797         };
 798
 799         my $letter = {
 800             title   => 'Overdue Notices',
 801             content => 'These messages were not sent directly to the patrons.',
 802         };
 803         C4::Letters::EnqueueLetter(
 804             {   letter                 => $letter,
 805                 borrowernumber         => undef,
 806                 message_transport_type => 'email',
 807                 attachments            => [$attachment],
 808                 to_address             => $admin_email_address,
 809             }
 810         );
 811     }
 812
 813 }
 814 if ($csvfilename) {
 815     # note that we're not testing on $csv_fh to prevent closing
 816     # STDOUT.
 817     close $csv_fh;
 818 }
 819
 820 if ( defined $htmlfilename ) {
 821   print $fh "</body>\n";
 822   print $fh "</html>\n";
 823   close $fh;
 824 } elsif ( defined $text_filename ) {
 825   close $fh;
 826 }
 827
 828 =head1 INTERNAL METHODS
 829
 830 These methods are internal to the operation of overdue_notices.pl.
 831
 832 =head2 prepare_letter_for_printing
 833
 834 returns a string of text appropriate for printing in the event that an
 835 overdue notice will not be sent to the patron's email
 836 address. Depending on the desired output format, this may be a CSV
 837 string, or a human-readable representation of the notice.
 838
 839 required parameters:
 840   letter
 841   borrowernumber
 842
 843 optional parameters:
 844   outputformat
 845
 846 =cut
 847
 848 sub prepare_letter_for_printing {
 849     my $params = shift;
 850
 851     return unless ref $params eq 'HASH';
 852
 853     foreach my $required_parameter (qw( letter borrowernumber )) {
 854         return unless defined $params->{$required_parameter};
 855     }
 856
 857     my $return;
 858     chomp $params->{titles};
 859     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 860         if ($csv->combine(
 861                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 862                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 863                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 864             )
 865           ) {
 866             return $csv->string, "\n";
 867         } else {
 868             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 869         }
 870     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 871       $return = "<pre>\n";
 872       $return .= "$params->{'letter'}->{'content'}\n";
 873       $return .= "\n</pre>\n";
 874     } else {
 875         $return .= "$params->{'letter'}->{'content'}\n";
 876
 877         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 878     }
 879     return $return;
 880 }
 881