opac/opac-idref.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2014 BibLibre
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI;
  23 use LWP::UserAgent;
  24 use HTTP::Request::Common;
  25 use JSON;
  26 use Encode;
  27
  28 use C4::Auth;
  29 use C4::Context;
  30 use C4::Search;
  31 use C4::Output;
  32
  33 my $cgi = new CGI;
  34 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  35     {
  36         template_name   => "opac-idref.tt",
  37         query           => $cgi,
  38         type            => "opac",
  39         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  40     }
  41 );
  42
  43 my $ua = LWP::UserAgent->new;
  44
  45 # See http://documentation.abes.fr/aideidrefdeveloppeur/index.html#MicroWebBiblio
  46 my $base = 'http://www.idref.fr/services/biblio/';
  47 my $unimarc3 = $cgi->param('unimarc3');
  48
  49 my $request = HTTP::Request->new(
  50     'GET',
  51     $base . $unimarc3 . ".json",
  52 );
  53 $request->protocol('HTTP/1.1');
  54 my $response = $ua->request($request);
  55 if ( not $response->is_success) {
  56     $template->param(error => $base.$unimarc3.'.json');
  57     output_html_with_http_headers $cgi, $cookie, $template->output;
  58     exit;
  59 }
  60
  61 my $content = Encode::decode("utf8", $response->content);
  62 my $json = from_json( $content );
  63 my $r;
  64 my @results = ref $json->{sudoc}{result} eq "ARRAY"
  65             ? @{ $json->{sudoc}{result} }
  66             : ($json->{sudoc}{result});
  67
  68 for my $result (@results) {
  69     my $role_node = $result->{'role'};
  70     my @roles =
  71       ref $role_node eq "ARRAY"
  72       ? @$role_node
  73       : ($role_node);
  74     for my $role (@roles) {
  75         my @docs = ref $role->{doc} eq "ARRAY"
  76             ? @{ $role->{doc} }
  77             : $role->{doc};
  78         push @$r,
  79           {
  80             role_name => $role->{roleName},
  81             count     => $role->{count},
  82             docs      => \@docs,
  83           };
  84     }
  85 }
  86
  87 $template->param(
  88     content => $r,
  89     unimarc3 => $unimarc3,
  90 );
  91
  92 output_html_with_http_headers $cgi, $cookie, $template->output;