tools/inventory.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2009 Biblibre S.A
   4 #                                         John Soros <john.soros@biblibre.com>
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23
  24 #need to open cgi and get the fh before anything else opens a new cgi context (see C4::Auth)
  25 use CGI qw ( -utf8 );
  26 my $input = CGI->new;
  27 my $uploadbarcodes = $input->param('uploadbarcodes');
  28
  29 use C4::Auth;
  30 use C4::Context;
  31 use C4::Output;
  32 use C4::Biblio;
  33 use C4::Items;
  34 use C4::Koha;
  35 use C4::Branch; # GetBranches
  36 use C4::Circulation;
  37 use C4::Reports::Guided;    #_get_column_defs
  38 use C4::Charset;
  39 use Koha::DateUtils;
  40 use List::MoreUtils qw( none );
  41
  42
  43 my $minlocation=$input->param('minlocation') || '';
  44 my $maxlocation=$input->param('maxlocation');
  45 $maxlocation=$minlocation.'Z' unless ( $maxlocation || ! $minlocation );
  46 my $location=$input->param('location') || '';
  47 my $itemtype=$input->param('itemtype'); # FIXME note, template does not currently supply this
  48 my $ignoreissued=$input->param('ignoreissued');
  49 my $datelastseen = $input->param('datelastseen');
  50 my $markseen = $input->param('markseen');
  51 my $branchcode = $input->param('branchcode') || '';
  52 my $branch     = $input->param('branch');
  53 my $op         = $input->param('op');
  54 my $compareinv2barcd = $input->param('compareinv2barcd');
  55
  56 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  57     {   template_name   => "tools/inventory.tt",
  58         query           => $input,
  59         type            => "intranet",
  60         authnotrequired => 0,
  61         flagsrequired   => { tools => 'inventory' },
  62         debug           => 1,
  63     }
  64 );
  65
  66
  67 my $branches = GetBranches();
  68 my @branch_loop;
  69 for my $branch_hash (keys %$branches) {
  70     push @branch_loop, {value => "$branch_hash",
  71                        branchname => $branches->{$branch_hash}->{'branchname'},
  72                        selected => ($branch_hash eq $branchcode?1:0)};
  73 }
  74
  75 @branch_loop = sort {$a->{branchname} cmp $b->{branchname}} @branch_loop;
  76 my @authorised_value_list;
  77 my $authorisedvalue_categories = '';
  78
  79 my $frameworks = getframeworks();
  80 $frameworks->{''} = {frameworkcode => ''}; # Add the default framework
  81
  82 for my $fwk (keys %$frameworks){
  83   my $fwkcode = $frameworks->{$fwk}->{'frameworkcode'};
  84   my $authcode = GetAuthValCode('items.location', $fwkcode);
  85     if ($authcode && $authorisedvalue_categories!~/\b$authcode\W/){
  86       $authorisedvalue_categories.="$authcode ";
  87       my $data=GetAuthorisedValues($authcode);
  88       foreach my $value (@$data){
  89         $value->{selected}=1 if ($value->{authorised_value} eq ($location));
  90       }
  91       push @authorised_value_list,@$data;
  92     }
  93 }
  94
  95 my $statuses = [];
  96 for my $statfield (qw/items.notforloan items.itemlost items.withdrawn items.damaged/){
  97     my $hash = {};
  98     $hash->{fieldname} = $statfield;
  99     $hash->{authcode} = GetAuthValCode($statfield);
 100     if ($hash->{authcode}){
 101         my $arr = GetAuthorisedValues($hash->{authcode});
 102         $hash->{values} = $arr;
 103         push @$statuses, $hash;
 104     }
 105 }
 106
 107
 108 $template->param( statuses => $statuses );
 109 my $staton = {};                                #authorized values that are ticked
 110 for my $authvfield (@$statuses) {
 111     $staton->{$authvfield->{fieldname}} = [];
 112     for my $authval (@{$authvfield->{values}}){
 113         if ( defined $input->param('status-' . $authvfield->{fieldname} . '-' . $authval->{authorised_value}) && $input->param('status-' . $authvfield->{fieldname} . '-' . $authval->{authorised_value}) eq 'on' ){
 114             push @{$staton->{$authvfield->{fieldname}}}, $authval->{authorised_value};
 115         }
 116     }
 117 }
 118
 119 my $notforloanlist;
 120 my $statussth = '';
 121 for my $authvfield (@$statuses) {
 122     if ( scalar @{$staton->{$authvfield->{fieldname}}} > 0 ){
 123         my $joinedvals = join ',', @{$staton->{$authvfield->{fieldname}}};
 124         $statussth .= "$authvfield->{fieldname} in ($joinedvals) and ";
 125         $notforloanlist = $joinedvals if ($authvfield->{fieldname} eq "items.notforloan");
 126     }
 127 }
 128 $statussth =~ s, and $,,g;
 129 $template->param(
 130     branchloop               => \@branch_loop,
 131     authorised_values        => \@authorised_value_list,
 132     today                    => dt_from_string,
 133     minlocation              => $minlocation,
 134     maxlocation              => $maxlocation,
 135     location                 => $location,
 136     ignoreissued             => $ignoreissued,
 137     branchcode               => $branchcode,
 138     branch                   => $branch,
 139     datelastseen             => $datelastseen,
 140     compareinv2barcd         => $compareinv2barcd,
 141     notforloanlist           => $notforloanlist
 142 );
 143
 144 my @notforloans;
 145 if (defined $notforloanlist) {
 146     @notforloans = split(/,/, $notforloanlist);
 147 }
 148
 149 my @scanned_items;
 150 my @errorloop;
 151 if ( $uploadbarcodes && length($uploadbarcodes) > 0 ) {
 152     my $dbh = C4::Context->dbh;
 153     my $date = dt_from_string( $input->param('setdate') );
 154     $date = output_pref ( { dt => $date, dateformat => 'iso' } );
 155
 156     my $strsth  = "select * from issues, items where items.itemnumber=issues.itemnumber and items.barcode =?";
 157     my $qonloan = $dbh->prepare($strsth);
 158     $strsth="select * from items where items.barcode =? and items.withdrawn = 1";
 159     my $qwithdrawn = $dbh->prepare($strsth);
 160
 161     my $count = 0;
 162
 163     my @barcodes;
 164
 165     my $sth = $dbh->column_info(undef,undef,"items","barcode");
 166     my $barcode_def = $sth->fetchall_hashref('COLUMN_NAME');
 167     my $barcode_size = $barcode_def->{barcode}->{COLUMN_SIZE};
 168     my $err_length=0;
 169     my $err_data=0;
 170     my $lines_read=0;
 171     binmode($uploadbarcodes, ":encoding(UTF-8)");
 172     while (my $barcode=<$uploadbarcodes>){
 173         $barcode =~ s/\r?\n$//;
 174         next unless $barcode;
 175         ++$lines_read;
 176         if (length($barcode)>$barcode_size) {
 177             $err_length += 1;
 178         }
 179         my $check_barcode = $barcode;
 180         $check_barcode =~ s/\p{Print}//g;
 181         if (length($check_barcode)>0) { # Only printable unicode characters allowed.
 182             $err_data += 1;
 183         }
 184         next if length($barcode)>$barcode_size;
 185         next if ( length($check_barcode)>0 );
 186         push @barcodes,$barcode;
 187     }
 188     $template->param( LinesRead => $lines_read );
 189     if (! @barcodes) {
 190         push @errorloop, {'barcode'=>'No valid barcodes!'};
 191         $op=''; # force the initial inventory screen again.
 192     }
 193     else {
 194         $template->param( err_length => $err_length,
 195                           err_data   => $err_data );
 196     }
 197     foreach my $barcode (@barcodes) {
 198         if ( $qwithdrawn->execute($barcode) && $qwithdrawn->rows ) {
 199             push @errorloop, { 'barcode' => $barcode, 'ERR_WTHDRAWN' => 1 };
 200         } else {
 201             my $item = GetItem( '', $barcode );
 202             if ( defined $item && $item->{'itemnumber'} ) {
 203                 ModItem( { datelastseen => $date }, undef, $item->{'itemnumber'} );
 204                 push @scanned_items, $item;
 205                 $count++;
 206                 $qonloan->execute($barcode);
 207                 if ($qonloan->rows){
 208                     my $data = $qonloan->fetchrow_hashref;
 209                     my ($doreturn, $messages, $iteminformation, $borrower) =AddReturn($barcode, $data->{homebranch});
 210                     if ($doreturn){
 211                         push @errorloop, {'barcode'=>$barcode,'ERR_ONLOAN_RET'=>1}
 212                     } else {
 213                         push @errorloop, {'barcode'=>$barcode,'ERR_ONLOAN_NOT_RET'=>1}
 214                     }
 215                 }
 216             } else {
 217                 push @errorloop, {'barcode'=>$barcode,'ERR_BARCODE'=>1};
 218             }
 219         }
 220
 221     }
 222
 223     $template->param( date => $date, Number => $count );
 224     $template->param( errorloop => \@errorloop ) if (@errorloop);
 225 }
 226
 227 # now build the result list: inventoried items if requested, and mis-placed items -always-
 228 my $inventorylist;
 229 my $wrongplacelist;
 230 my @items_with_problems;
 231 if ( $markseen or $op ) {
 232     # retrieve all items in this range.
 233     my $totalrecords;
 234
 235     # We use datelastseen only when comparing the results to the barcode file.
 236     my $paramdatelastseen = ($compareinv2barcd) ? $datelastseen : '';
 237     ($inventorylist, $totalrecords) = GetItemsForInventory( {
 238       minlocation  => $minlocation,
 239       maxlocation  => $maxlocation,
 240       location     => $location,
 241       itemtype     => $itemtype,
 242       ignoreissued => $ignoreissued,
 243       datelastseen => $paramdatelastseen,
 244       branchcode   => $branchcode,
 245       branch       => $branch,
 246       offset       => 0,
 247       size         => undef,
 248       statushash   => $staton,
 249       interface    => 'staff',
 250     } );
 251
 252     # For the items that may be marked as "wrong place", we only check the location (callnumbers, location and branch)
 253     ($wrongplacelist, $totalrecords) = GetItemsForInventory( {
 254       minlocation  => $minlocation,
 255       maxlocation  => $maxlocation,
 256       location     => $location,
 257       itemtype     => undef,
 258       ignoreissued => undef,
 259       datelastseen => undef,
 260       branchcode   => $branchcode,
 261       branch       => $branch,
 262       offset       => 0,
 263       size         => undef,
 264       statushash   => undef,
 265       interface    => 'staff',
 266     } );
 267
 268 }
 269
 270 # If "compare barcodes list to results" has been checked, we want to alert for missing items
 271 if ( $compareinv2barcd ) {
 272     # set "missing" flags for all items with a datelastseen (dls) before the choosen datelastseen (cdls)
 273     my $dls = output_pref( { dt => dt_from_string( $datelastseen ),
 274                              dateformat => 'iso' } );
 275     foreach my $item ( @$inventorylist ) {
 276         my $cdls = output_pref( { dt => dt_from_string( $_->{datelastseen} ),
 277                                   dateformat => 'iso' } );
 278         if ( $cdls lt $dls ) {
 279             $item->{problem} = 'missingitem';
 280             # We have to push a copy of the item, not the reference
 281             push @items_with_problems, { %$item };
 282         }
 283     }
 284 }
 285
 286
 287
 288 # insert "wrongplace" to all scanned items that are not supposed to be in this range
 289 # note this list is always displayed, whatever the librarian has choosen for comparison
 290 my $moddatecount = 0;
 291 foreach my $item ( @scanned_items ) {
 292
 293   # Saving notforloan code before it's replaced by it's authorised value for later comparison
 294   $item->{notforloancode} = $item->{notforloan};
 295
 296   # Populating with authorised values
 297   foreach my $field ( keys %$item ) {
 298         # If the koha field is mapped to a marc field
 299         my $fc = $item->{'frameworkcode'} || '';
 300         my ($f, $sf) = GetMarcFromKohaField("items.$field", $fc);
 301         if ($f and $sf) {
 302             # We replace the code with it's description
 303             my $authvals = C4::Koha::GetKohaAuthorisedValuesFromField($f, $sf, $fc);
 304             if ($authvals and defined $item->{$field} and defined $authvals->{$item->{$field}}) {
 305               $item->{$field} = $authvals->{$item->{$field}};
 306             }
 307         }
 308     }
 309
 310     next if $item->{onloan}; # skip checked out items
 311
 312     # If we have scanned items with a non-matching notforloan value
 313     if (none { $item->{'notforloancode'} eq $_ } @notforloans) {
 314         $item->{problem} = 'changestatus';
 315         push @items_with_problems, { %$item };
 316     }
 317     if (none { $item->{barcode} eq $_->{barcode} && !$_->{'onloan'} } @$wrongplacelist) {
 318         $item->{problem} = 'wrongplace';
 319         push @items_with_problems, { %$item };
 320     }
 321
 322     # Modify date last seen for scanned items
 323     ModDateLastSeen($_->{'itemnumber'});
 324     $moddatecount++;
 325 }
 326
 327 if ( $compareinv2barcd ) {
 328     my @scanned_barcodes = map {$_->{barcode}} @scanned_items;
 329     for my $should_be_scanned ( @$inventorylist ) {
 330         my $barcode = $should_be_scanned->{barcode};
 331         unless ( grep /^$barcode$/, @scanned_barcodes ) {
 332             $should_be_scanned->{problem} = 'not_scanned';
 333             push @items_with_problems, { %$should_be_scanned };
 334         }
 335     }
 336 }
 337
 338 for my $item ( @items_with_problems ) {
 339     my $biblio = C4::Biblio::GetBiblioData($item->{biblionumber});
 340     $item->{title} = $biblio->{title};
 341     $item->{author} = $biblio->{author};
 342 }
 343
 344 # If a barcode file is given, we want to show problems, else all items
 345 my @results;
 346 @results = $uploadbarcodes
 347             ? @items_with_problems
 348             : $op
 349                 ? @$inventorylist
 350                 : ();
 351
 352 $template->param(
 353     moddatecount => $moddatecount,
 354     loop       => \@results,
 355     op         => $op
 356 );
 357
 358 if (defined $input->param('CSVexport') && $input->param('CSVexport') eq 'on'){
 359     eval {use Text::CSV};
 360     my $csv = Text::CSV->new or
 361             die Text::CSV->error_diag ();
 362     binmode STDOUT, ":encoding(UTF-8)";
 363     print $input->header(
 364         -type       => 'text/csv',
 365         -attachment => 'inventory.csv',
 366     );
 367
 368     my $columns_def_hashref = C4::Reports::Guided::_get_column_defs($input);
 369     foreach my $key ( keys %$columns_def_hashref ) {
 370         my $initkey = $key;
 371         $key =~ s/[^\.]*\.//;
 372         $columns_def_hashref->{$initkey}=NormalizeString($columns_def_hashref->{$initkey} // '');
 373         $columns_def_hashref->{$key} = $columns_def_hashref->{$initkey};
 374     }
 375
 376     my @translated_keys;
 377     for my $key (qw / biblioitems.title    biblio.author
 378                       items.barcode        items.itemnumber
 379                       items.homebranch     items.location
 380                       items.itemcallnumber items.notforloan
 381                       items.itemlost       items.damaged
 382                       items.withdrawn      items.stocknumber
 383                       / ) {
 384        push @translated_keys, $columns_def_hashref->{$key};
 385     }
 386     push @translated_keys, 'problem' if $uploadbarcodes;
 387
 388     $csv->combine(@translated_keys);
 389     print $csv->string, "\n";
 390
 391     my @keys = qw / title author barcode itemnumber homebranch location itemcallnumber notforloan lost damaged withdrawn stocknumber /;
 392     for my $item ( @results ) {
 393         my @line;
 394         for my $key (@keys) {
 395             push @line, $item->{$key};
 396         }
 397         if ( defined $item->{problem} ) {
 398             if ( $item->{problem} eq 'wrongplace' ) {
 399                 push @line, "wrong place";
 400             } elsif ( $item->{problem} eq 'missingitem' ) {
 401                 push @line, "missing item";
 402             } elsif ( $item->{problem} eq 'changestatus' ) {
 403                 push @line, "change item status";
 404             } elsif ($item->{problem} eq 'not_scanned' ) {
 405                 push @line, "item not scanned";
 406             }
 407         }
 408         $csv->combine(@line);
 409         print $csv->string, "\n";
 410     }
 411     # Adding not found barcodes
 412     foreach my $error (@errorloop) {
 413         my @line;
 414         if ($error->{'ERR_BARCODE'}) {
 415             push @line, map { $_ eq 'barcode' ? $error->{'barcode'} : ''} @keys;
 416             push @line, "barcode not found";
 417             $csv->combine(@line);
 418             print $csv->string, "\n";
 419         }
 420     }
 421     exit;
 422 }
 423
 424 output_html_with_http_headers $input, $cookie, $template->output;