Koha/ElasticSearch/Indexer.pm

   1 package Koha::ElasticSearch::Indexer;
   2
   3 # Copyright 2013 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Carp;
  21 use Modern::Perl;
  22 use base qw(Koha::ElasticSearch);
  23 use Data::Dumper;
  24
  25 # For now just marc, but we can do anything here really
  26 use Catmandu::Importer::MARC;
  27 use Catmandu::Store::ElasticSearch;
  28
  29 Koha::ElasticSearch::Indexer->mk_accessors(qw( store ));
  30
  31 =head1 NAME
  32
  33 Koha::ElasticSearch::Indexer - handles adding new records to the index
  34
  35 =head1 SYNOPSIS
  36
  37     my $indexer = Koha::ElasticSearch::Indexer->new(
  38         { index => Koha::SearchEngine::BIBLIOS_INDEX } );
  39     $indexer->drop_index();
  40     $indexer->update_index(\@biblionumbers, \@records);
  41
  42 =head1 FUNCTIONS
  43
  44 =cut
  45
  46 =head2 $indexer->update_index($biblionums, $records);
  47
  48 C<$biblionums> is an arrayref containing the biblionumbers for the records.
  49
  50 C<$records> is an arrayref containing the L<MARC::Record>s themselves.
  51
  52 The values in the arrays must match up, and the 999$c value in the MARC record
  53 will be rewritten using the values in C<$biblionums> to ensure they are correct.
  54 If C<$biblionums> is C<undef>, this won't happen, but you should be sure that
  55 999$c is correct on your own then.
  56
  57 Note that this will modify the original record if C<$biblionums> is supplied.
  58 If that's a problem, clone them first.
  59
  60 =cut
  61
  62 sub update_index {
  63     my ($self, $biblionums, $records) = @_;
  64
  65     # TODO should have a separate path for dealing with a large number
  66     # of records at once where we use the bulk update functions in ES.
  67     if ($biblionums) {
  68         $self->_sanitise_records($biblionums, $records);
  69     }
  70
  71     my $from    = $self->_convert_marc_to_json($records);
  72     if ( !$self->store ) {
  73         my $params  = $self->get_elasticsearch_params();
  74         $self->store(
  75             Catmandu::Store::ElasticSearch->new(
  76                 %$params,
  77                 index_settings => $self->get_elasticsearch_settings(),
  78                 index_mappings => $self->get_elasticsearch_mappings(),
  79             )
  80         );
  81     }
  82     $self->store->bag->add_many($from);
  83     $self->store->bag->commit;
  84     return 1;
  85 }
  86
  87 =head2 $indexer->update_index_background($biblionums, $records)
  88
  89 This has exactly the same API as C<update_index_background> however it'll
  90 return immediately. It'll start a background process that does the adding.
  91
  92 If it fails to add to Elasticsearch then it'll add to a queue that will cause
  93 it to be updated by a regular index cron job in the future.
  94
  95 # TODO implement in the future - I don't know the best way of doing this yet.
  96 # If fork: make sure process group is changed so apache doesn't wait for us.
  97
  98 =cut
  99
 100 sub update_index_background {
 101     my $self = shift;
 102     $self->update_index(@_);
 103 }
 104
 105 =head2 $indexer->delete_index($biblionums)
 106
 107 C<$biblionums> is an arrayref of biblionumbers to delete from the index.
 108
 109 =cut
 110
 111 sub delete_index {
 112     my ($self, $biblionums) = @_;
 113
 114     if ( !$self->store ) {
 115         my $params  = $self->get_elasticsearch_params();
 116         $self->store(
 117             Catmandu::Store::ElasticSearch->new(
 118                 %$params,
 119                 index_settings => $self->get_elasticsearch_settings(),
 120                 index_mappings => $self->get_elasticsearch_mappings(),
 121             )
 122         );
 123     }
 124     $self->store->bag->delete($_) foreach @$biblionums;
 125     $self->store->bag->commit;
 126 }
 127
 128 =head2 $indexer->delete_index_background($biblionums)
 129
 130 Identical to L<delete_index>, this will return immediately and start a
 131 background process to do the actual deleting.
 132
 133 =cut
 134
 135 # TODO implement in the future
 136
 137 sub delete_index_background {
 138     my $self = shift;
 139     $self->delete_index(@_);
 140 }
 141 =head2 $indexer->drop_index();
 142
 143 Drops the index from the elasticsearch server. Calling C<update_index>
 144 after this will recreate it again.
 145
 146 =cut
 147
 148 sub drop_index {
 149     my ($self) = @_;
 150
 151     if (!$self->store) {
 152         # If this index doesn't exist, this will create it. Then it'll be
 153         # deleted. That's not the end of the world however.
 154         my $params  = $self->get_elasticsearch_params();
 155         $self->store(
 156             Catmandu::Store::ElasticSearch->new(
 157                 %$params,
 158                 index_settings => $self->get_elasticsearch_settings(),
 159                 index_mappings => $self->get_elasticsearch_mappings(),
 160             )
 161         );
 162     }
 163     $self->store->drop();
 164     $self->store(undef);
 165 }
 166
 167 sub _sanitise_records {
 168     my ($self, $biblionums, $records) = @_;
 169
 170     confess "Unequal number of values in \$biblionums and \$records." if (@$biblionums != @$records);
 171
 172     my $c = @$biblionums;
 173     for (my $i=0; $i<$c; $i++) {
 174         my $bibnum = $biblionums->[$i];
 175         my $rec = $records->[$i];
 176         # I've seen things you people wouldn't believe. Attack ships on fire
 177         # off the shoulder of Orion. I watched C-beams glitter in the dark near
 178         # the Tannhauser gate. MARC records where 999$c doesn't match the
 179         # biblionumber column. All those moments will be lost in time... like
 180         # tears in rain...
 181         $rec->delete_fields($rec->field('999'));
 182         $rec->append_fields(MARC::Field->new('999','','','c' => $bibnum, 'd' => $bibnum));
 183     }
 184 }
 185
 186 sub _convert_marc_to_json {
 187     my $self    = shift;
 188     my $records = shift;
 189     my $importer =
 190       Catmandu::Importer::MARC->new( records => $records, id => '999c' );
 191     my $fixer = Catmandu::Fix->new( fixes => $self->get_fixer_rules() );
 192     $importer = $fixer->fix($importer);
 193     return $importer;
 194 }
 195
 196 1;
 197
 198 __END__
 199
 200 =head1 AUTHOR
 201
 202 =over 4
 203
 204 =item Chris Cormack C<< <chrisc@catalyst.net.nz> >>
 205
 206 =item Robin Sheat C<< <robin@catalyst.net.nz> >>
 207
 208 =back
 209
 210 =cut